LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
dgges3.f
Go to the documentation of this file.
1 *> \brief <b> DGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices (blocked algorithm)</b>
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DGGES3 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgges3.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgges3.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgges3.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DGGES3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB,
22 * SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL, VSR,
23 * LDVSR, WORK, LWORK, BWORK, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER JOBVSL, JOBVSR, SORT
27 * INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
28 * ..
29 * .. Array Arguments ..
30 * LOGICAL BWORK( * )
31 * DOUBLE PRECISION A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
32 * $ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
33 * $ VSR( LDVSR, * ), WORK( * )
34 * ..
35 * .. Function Arguments ..
36 * LOGICAL SELCTG
37 * EXTERNAL SELCTG
38 * ..
39 *
40 *
41 *> \par Purpose:
42 * =============
43 *>
44 *> \verbatim
45 *>
46 *> DGGES3 computes for a pair of N-by-N real nonsymmetric matrices (A,B),
47 *> the generalized eigenvalues, the generalized real Schur form (S,T),
48 *> optionally, the left and/or right matrices of Schur vectors (VSL and
49 *> VSR). This gives the generalized Schur factorization
50 *>
51 *> (A,B) = ( (VSL)*S*(VSR)**T, (VSL)*T*(VSR)**T )
52 *>
53 *> Optionally, it also orders the eigenvalues so that a selected cluster
54 *> of eigenvalues appears in the leading diagonal blocks of the upper
55 *> quasi-triangular matrix S and the upper triangular matrix T.The
56 *> leading columns of VSL and VSR then form an orthonormal basis for the
57 *> corresponding left and right eigenspaces (deflating subspaces).
58 *>
59 *> (If only the generalized eigenvalues are needed, use the driver
60 *> DGGEV instead, which is faster.)
61 *>
62 *> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
63 *> or a ratio alpha/beta = w, such that A - w*B is singular. It is
64 *> usually represented as the pair (alpha,beta), as there is a
65 *> reasonable interpretation for beta=0 or both being zero.
66 *>
67 *> A pair of matrices (S,T) is in generalized real Schur form if T is
68 *> upper triangular with non-negative diagonal and S is block upper
69 *> triangular with 1-by-1 and 2-by-2 blocks. 1-by-1 blocks correspond
70 *> to real generalized eigenvalues, while 2-by-2 blocks of S will be
71 *> "standardized" by making the corresponding elements of T have the
72 *> form:
73 *> [ a 0 ]
74 *> [ 0 b ]
75 *>
76 *> and the pair of corresponding 2-by-2 blocks in S and T will have a
77 *> complex conjugate pair of generalized eigenvalues.
78 *>
79 *> \endverbatim
80 *
81 * Arguments:
82 * ==========
83 *
84 *> \param[in] JOBVSL
85 *> \verbatim
86 *> JOBVSL is CHARACTER*1
87 *> = 'N': do not compute the left Schur vectors;
88 *> = 'V': compute the left Schur vectors.
89 *> \endverbatim
90 *>
91 *> \param[in] JOBVSR
92 *> \verbatim
93 *> JOBVSR is CHARACTER*1
94 *> = 'N': do not compute the right Schur vectors;
95 *> = 'V': compute the right Schur vectors.
96 *> \endverbatim
97 *>
98 *> \param[in] SORT
99 *> \verbatim
100 *> SORT is CHARACTER*1
101 *> Specifies whether or not to order the eigenvalues on the
102 *> diagonal of the generalized Schur form.
103 *> = 'N': Eigenvalues are not ordered;
104 *> = 'S': Eigenvalues are ordered (see SELCTG);
105 *> \endverbatim
106 *>
107 *> \param[in] SELCTG
108 *> \verbatim
109 *> SELCTG is a LOGICAL FUNCTION of three DOUBLE PRECISION arguments
110 *> SELCTG must be declared EXTERNAL in the calling subroutine.
111 *> If SORT = 'N', SELCTG is not referenced.
112 *> If SORT = 'S', SELCTG is used to select eigenvalues to sort
113 *> to the top left of the Schur form.
114 *> An eigenvalue (ALPHAR(j)+ALPHAI(j))/BETA(j) is selected if
115 *> SELCTG(ALPHAR(j),ALPHAI(j),BETA(j)) is true; i.e. if either
116 *> one of a complex conjugate pair of eigenvalues is selected,
117 *> then both complex eigenvalues are selected.
118 *>
119 *> Note that in the ill-conditioned case, a selected complex
120 *> eigenvalue may no longer satisfy SELCTG(ALPHAR(j),ALPHAI(j),
121 *> BETA(j)) = .TRUE. after ordering. INFO is to be set to N+2
122 *> in this case.
123 *> \endverbatim
124 *>
125 *> \param[in] N
126 *> \verbatim
127 *> N is INTEGER
128 *> The order of the matrices A, B, VSL, and VSR. N >= 0.
129 *> \endverbatim
130 *>
131 *> \param[in,out] A
132 *> \verbatim
133 *> A is DOUBLE PRECISION array, dimension (LDA, N)
134 *> On entry, the first of the pair of matrices.
135 *> On exit, A has been overwritten by its generalized Schur
136 *> form S.
137 *> \endverbatim
138 *>
139 *> \param[in] LDA
140 *> \verbatim
141 *> LDA is INTEGER
142 *> The leading dimension of A. LDA >= max(1,N).
143 *> \endverbatim
144 *>
145 *> \param[in,out] B
146 *> \verbatim
147 *> B is DOUBLE PRECISION array, dimension (LDB, N)
148 *> On entry, the second of the pair of matrices.
149 *> On exit, B has been overwritten by its generalized Schur
150 *> form T.
151 *> \endverbatim
152 *>
153 *> \param[in] LDB
154 *> \verbatim
155 *> LDB is INTEGER
156 *> The leading dimension of B. LDB >= max(1,N).
157 *> \endverbatim
158 *>
159 *> \param[out] SDIM
160 *> \verbatim
161 *> SDIM is INTEGER
162 *> If SORT = 'N', SDIM = 0.
163 *> If SORT = 'S', SDIM = number of eigenvalues (after sorting)
164 *> for which SELCTG is true. (Complex conjugate pairs for which
165 *> SELCTG is true for either eigenvalue count as 2.)
166 *> \endverbatim
167 *>
168 *> \param[out] ALPHAR
169 *> \verbatim
170 *> ALPHAR is DOUBLE PRECISION array, dimension (N)
171 *> \endverbatim
172 *>
173 *> \param[out] ALPHAI
174 *> \verbatim
175 *> ALPHAI is DOUBLE PRECISION array, dimension (N)
176 *> \endverbatim
177 *>
178 *> \param[out] BETA
179 *> \verbatim
180 *> BETA is DOUBLE PRECISION array, dimension (N)
181 *> On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will
182 *> be the generalized eigenvalues. ALPHAR(j) + ALPHAI(j)*i,
183 *> and BETA(j),j=1,...,N are the diagonals of the complex Schur
184 *> form (S,T) that would result if the 2-by-2 diagonal blocks of
185 *> the real Schur form of (A,B) were further reduced to
186 *> triangular form using 2-by-2 complex unitary transformations.
187 *> If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
188 *> positive, then the j-th and (j+1)-st eigenvalues are a
189 *> complex conjugate pair, with ALPHAI(j+1) negative.
190 *>
191 *> Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j)
192 *> may easily over- or underflow, and BETA(j) may even be zero.
193 *> Thus, the user should avoid naively computing the ratio.
194 *> However, ALPHAR and ALPHAI will be always less than and
195 *> usually comparable with norm(A) in magnitude, and BETA always
196 *> less than and usually comparable with norm(B).
197 *> \endverbatim
198 *>
199 *> \param[out] VSL
200 *> \verbatim
201 *> VSL is DOUBLE PRECISION array, dimension (LDVSL,N)
202 *> If JOBVSL = 'V', VSL will contain the left Schur vectors.
203 *> Not referenced if JOBVSL = 'N'.
204 *> \endverbatim
205 *>
206 *> \param[in] LDVSL
207 *> \verbatim
208 *> LDVSL is INTEGER
209 *> The leading dimension of the matrix VSL. LDVSL >=1, and
210 *> if JOBVSL = 'V', LDVSL >= N.
211 *> \endverbatim
212 *>
213 *> \param[out] VSR
214 *> \verbatim
215 *> VSR is DOUBLE PRECISION array, dimension (LDVSR,N)
216 *> If JOBVSR = 'V', VSR will contain the right Schur vectors.
217 *> Not referenced if JOBVSR = 'N'.
218 *> \endverbatim
219 *>
220 *> \param[in] LDVSR
221 *> \verbatim
222 *> LDVSR is INTEGER
223 *> The leading dimension of the matrix VSR. LDVSR >= 1, and
224 *> if JOBVSR = 'V', LDVSR >= N.
225 *> \endverbatim
226 *>
227 *> \param[out] WORK
228 *> \verbatim
229 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
230 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
231 *> \endverbatim
232 *>
233 *> \param[in] LWORK
234 *> \verbatim
235 *> LWORK is INTEGER
236 *> The dimension of the array WORK.
237 *>
238 *> If LWORK = -1, then a workspace query is assumed; the routine
239 *> only calculates the optimal size of the WORK array, returns
240 *> this value as the first entry of the WORK array, and no error
241 *> message related to LWORK is issued by XERBLA.
242 *> \endverbatim
243 *>
244 *> \param[out] BWORK
245 *> \verbatim
246 *> BWORK is LOGICAL array, dimension (N)
247 *> Not referenced if SORT = 'N'.
248 *> \endverbatim
249 *>
250 *> \param[out] INFO
251 *> \verbatim
252 *> INFO is INTEGER
253 *> = 0: successful exit
254 *> < 0: if INFO = -i, the i-th argument had an illegal value.
255 *> = 1,...,N:
256 *> The QZ iteration failed. (A,B) are not in Schur
257 *> form, but ALPHAR(j), ALPHAI(j), and BETA(j) should
258 *> be correct for j=INFO+1,...,N.
259 *> > N: =N+1: other than QZ iteration failed in DLAQZ0.
260 *> =N+2: after reordering, roundoff changed values of
261 *> some complex eigenvalues so that leading
262 *> eigenvalues in the Generalized Schur form no
263 *> longer satisfy SELCTG=.TRUE. This could also
264 *> be caused due to scaling.
265 *> =N+3: reordering failed in DTGSEN.
266 *> \endverbatim
267 *
268 * Authors:
269 * ========
270 *
271 *> \author Univ. of Tennessee
272 *> \author Univ. of California Berkeley
273 *> \author Univ. of Colorado Denver
274 *> \author NAG Ltd.
275 *
276 *> \ingroup doubleGEeigen
277 *
278 * =====================================================================
279  SUBROUTINE dgges3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B,
280  $ LDB, SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL,
281  $ VSR, LDVSR, WORK, LWORK, BWORK, INFO )
282 *
283 * -- LAPACK driver routine --
284 * -- LAPACK is a software package provided by Univ. of Tennessee, --
285 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
286 *
287 * .. Scalar Arguments ..
288  CHARACTER JOBVSL, JOBVSR, SORT
289  INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
290 * ..
291 * .. Array Arguments ..
292  LOGICAL BWORK( * )
293  DOUBLE PRECISION A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
294  $ b( ldb, * ), beta( * ), vsl( ldvsl, * ),
295  $ vsr( ldvsr, * ), work( * )
296 * ..
297 * .. Function Arguments ..
298  LOGICAL SELCTG
299  EXTERNAL SELCTG
300 * ..
301 *
302 * =====================================================================
303 *
304 * .. Parameters ..
305  DOUBLE PRECISION ZERO, ONE
306  PARAMETER ( ZERO = 0.0d+0, one = 1.0d+0 )
307 * ..
308 * .. Local Scalars ..
309  LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
310  $ LQUERY, LST2SL, WANTST
311  INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
312  $ ILO, IP, IRIGHT, IROWS, ITAU, IWRK, LWKOPT
313  DOUBLE PRECISION ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
314  $ PVSR, SAFMAX, SAFMIN, SMLNUM
315 * ..
316 * .. Local Arrays ..
317  INTEGER IDUM( 1 )
318  DOUBLE PRECISION DIF( 2 )
319 * ..
320 * .. External Subroutines ..
321  EXTERNAL dgeqrf, dggbak, dggbal, dgghd3, dlaqz0, dlabad,
323  $ xerbla
324 * ..
325 * .. External Functions ..
326  LOGICAL LSAME
327  DOUBLE PRECISION DLAMCH, DLANGE
328  EXTERNAL lsame, dlamch, dlange
329 * ..
330 * .. Intrinsic Functions ..
331  INTRINSIC abs, max, sqrt
332 * ..
333 * .. Executable Statements ..
334 *
335 * Decode the input arguments
336 *
337  IF( lsame( jobvsl, 'N' ) ) THEN
338  ijobvl = 1
339  ilvsl = .false.
340  ELSE IF( lsame( jobvsl, 'V' ) ) THEN
341  ijobvl = 2
342  ilvsl = .true.
343  ELSE
344  ijobvl = -1
345  ilvsl = .false.
346  END IF
347 *
348  IF( lsame( jobvsr, 'N' ) ) THEN
349  ijobvr = 1
350  ilvsr = .false.
351  ELSE IF( lsame( jobvsr, 'V' ) ) THEN
352  ijobvr = 2
353  ilvsr = .true.
354  ELSE
355  ijobvr = -1
356  ilvsr = .false.
357  END IF
358 *
359  wantst = lsame( sort, 'S' )
360 *
361 * Test the input arguments
362 *
363  info = 0
364  lquery = ( lwork.EQ.-1 )
365  IF( ijobvl.LE.0 ) THEN
366  info = -1
367  ELSE IF( ijobvr.LE.0 ) THEN
368  info = -2
369  ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
370  info = -3
371  ELSE IF( n.LT.0 ) THEN
372  info = -5
373  ELSE IF( lda.LT.max( 1, n ) ) THEN
374  info = -7
375  ELSE IF( ldb.LT.max( 1, n ) ) THEN
376  info = -9
377  ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
378  info = -15
379  ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
380  info = -17
381  ELSE IF( lwork.LT.6*n+16 .AND. .NOT.lquery ) THEN
382  info = -19
383  END IF
384 *
385 * Compute workspace
386 *
387  IF( info.EQ.0 ) THEN
388  CALL dgeqrf( n, n, b, ldb, work, work, -1, ierr )
389  lwkopt = max( 6*n+16, 3*n+int( work( 1 ) ) )
390  CALL dormqr( 'L', 'T', n, n, n, b, ldb, work, a, lda, work,
391  $ -1, ierr )
392  lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
393  IF( ilvsl ) THEN
394  CALL dorgqr( n, n, n, vsl, ldvsl, work, work, -1, ierr )
395  lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
396  END IF
397  CALL dgghd3( jobvsl, jobvsr, n, 1, n, a, lda, b, ldb, vsl,
398  $ ldvsl, vsr, ldvsr, work, -1, ierr )
399  lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
400  CALL dlaqz0( 'S', jobvsl, jobvsr, n, 1, n, a, lda, b, ldb,
401  $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
402  $ work, -1, 0, ierr )
403  lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
404  IF( wantst ) THEN
405  CALL dtgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
406  $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
407  $ sdim, pvsl, pvsr, dif, work, -1, idum, 1,
408  $ ierr )
409  lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
410  END IF
411  work( 1 ) = lwkopt
412  END IF
413 *
414  IF( info.NE.0 ) THEN
415  CALL xerbla( 'DGGES3 ', -info )
416  RETURN
417  ELSE IF( lquery ) THEN
418  RETURN
419  END IF
420 *
421 * Quick return if possible
422 *
423  IF( n.EQ.0 ) THEN
424  sdim = 0
425  RETURN
426  END IF
427 *
428 * Get machine constants
429 *
430  eps = dlamch( 'P' )
431  safmin = dlamch( 'S' )
432  safmax = one / safmin
433  CALL dlabad( safmin, safmax )
434  smlnum = sqrt( safmin ) / eps
435  bignum = one / smlnum
436 *
437 * Scale A if max element outside range [SMLNUM,BIGNUM]
438 *
439  anrm = dlange( 'M', n, n, a, lda, work )
440  ilascl = .false.
441  IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
442  anrmto = smlnum
443  ilascl = .true.
444  ELSE IF( anrm.GT.bignum ) THEN
445  anrmto = bignum
446  ilascl = .true.
447  END IF
448  IF( ilascl )
449  $ CALL dlascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
450 *
451 * Scale B if max element outside range [SMLNUM,BIGNUM]
452 *
453  bnrm = dlange( 'M', n, n, b, ldb, work )
454  ilbscl = .false.
455  IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
456  bnrmto = smlnum
457  ilbscl = .true.
458  ELSE IF( bnrm.GT.bignum ) THEN
459  bnrmto = bignum
460  ilbscl = .true.
461  END IF
462  IF( ilbscl )
463  $ CALL dlascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
464 *
465 * Permute the matrix to make it more nearly triangular
466 *
467  ileft = 1
468  iright = n + 1
469  iwrk = iright + n
470  CALL dggbal( 'P', n, a, lda, b, ldb, ilo, ihi, work( ileft ),
471  $ work( iright ), work( iwrk ), ierr )
472 *
473 * Reduce B to triangular form (QR decomposition of B)
474 *
475  irows = ihi + 1 - ilo
476  icols = n + 1 - ilo
477  itau = iwrk
478  iwrk = itau + irows
479  CALL dgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
480  $ work( iwrk ), lwork+1-iwrk, ierr )
481 *
482 * Apply the orthogonal transformation to matrix A
483 *
484  CALL dormqr( 'L', 'T', irows, icols, irows, b( ilo, ilo ), ldb,
485  $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
486  $ lwork+1-iwrk, ierr )
487 *
488 * Initialize VSL
489 *
490  IF( ilvsl ) THEN
491  CALL dlaset( 'Full', n, n, zero, one, vsl, ldvsl )
492  IF( irows.GT.1 ) THEN
493  CALL dlacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
494  $ vsl( ilo+1, ilo ), ldvsl )
495  END IF
496  CALL dorgqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
497  $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
498  END IF
499 *
500 * Initialize VSR
501 *
502  IF( ilvsr )
503  $ CALL dlaset( 'Full', n, n, zero, one, vsr, ldvsr )
504 *
505 * Reduce to generalized Hessenberg form
506 *
507  CALL dgghd3( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
508  $ ldvsl, vsr, ldvsr, work( iwrk ), lwork+1-iwrk,
509  $ ierr )
510 *
511 * Perform QZ algorithm, computing Schur vectors if desired
512 *
513  iwrk = itau
514  CALL dlaqz0( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
515  $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
516  $ work( iwrk ), lwork+1-iwrk, 0, ierr )
517  IF( ierr.NE.0 ) THEN
518  IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
519  info = ierr
520  ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
521  info = ierr - n
522  ELSE
523  info = n + 1
524  END IF
525  GO TO 50
526  END IF
527 *
528 * Sort eigenvalues ALPHA/BETA if desired
529 *
530  sdim = 0
531  IF( wantst ) THEN
532 *
533 * Undo scaling on eigenvalues before SELCTGing
534 *
535  IF( ilascl ) THEN
536  CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n,
537  $ ierr )
538  CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n,
539  $ ierr )
540  END IF
541  IF( ilbscl )
542  $ CALL dlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
543 *
544 * Select eigenvalues
545 *
546  DO 10 i = 1, n
547  bwork( i ) = selctg( alphar( i ), alphai( i ), beta( i ) )
548  10 CONTINUE
549 *
550  CALL dtgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alphar,
551  $ alphai, beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl,
552  $ pvsr, dif, work( iwrk ), lwork-iwrk+1, idum, 1,
553  $ ierr )
554  IF( ierr.EQ.1 )
555  $ info = n + 3
556 *
557  END IF
558 *
559 * Apply back-permutation to VSL and VSR
560 *
561  IF( ilvsl )
562  $ CALL dggbak( 'P', 'L', n, ilo, ihi, work( ileft ),
563  $ work( iright ), n, vsl, ldvsl, ierr )
564 *
565  IF( ilvsr )
566  $ CALL dggbak( 'P', 'R', n, ilo, ihi, work( ileft ),
567  $ work( iright ), n, vsr, ldvsr, ierr )
568 *
569 * Check if unscaling would cause over/underflow, if so, rescale
570 * (ALPHAR(I),ALPHAI(I),BETA(I)) so BETA(I) is on the order of
571 * B(I,I) and ALPHAR(I) and ALPHAI(I) are on the order of A(I,I)
572 *
573  IF( ilascl ) THEN
574  DO 20 i = 1, n
575  IF( alphai( i ).NE.zero ) THEN
576  IF( ( alphar( i ) / safmax ).GT.( anrmto / anrm ) .OR.
577  $ ( safmin / alphar( i ) ).GT.( anrm / anrmto ) ) THEN
578  work( 1 ) = abs( a( i, i ) / alphar( i ) )
579  beta( i ) = beta( i )*work( 1 )
580  alphar( i ) = alphar( i )*work( 1 )
581  alphai( i ) = alphai( i )*work( 1 )
582  ELSE IF( ( alphai( i ) / safmax ).GT.
583  $ ( anrmto / anrm ) .OR.
584  $ ( safmin / alphai( i ) ).GT.( anrm / anrmto ) )
585  $ THEN
586  work( 1 ) = abs( a( i, i+1 ) / alphai( i ) )
587  beta( i ) = beta( i )*work( 1 )
588  alphar( i ) = alphar( i )*work( 1 )
589  alphai( i ) = alphai( i )*work( 1 )
590  END IF
591  END IF
592  20 CONTINUE
593  END IF
594 *
595  IF( ilbscl ) THEN
596  DO 30 i = 1, n
597  IF( alphai( i ).NE.zero ) THEN
598  IF( ( beta( i ) / safmax ).GT.( bnrmto / bnrm ) .OR.
599  $ ( safmin / beta( i ) ).GT.( bnrm / bnrmto ) ) THEN
600  work( 1 ) = abs( b( i, i ) / beta( i ) )
601  beta( i ) = beta( i )*work( 1 )
602  alphar( i ) = alphar( i )*work( 1 )
603  alphai( i ) = alphai( i )*work( 1 )
604  END IF
605  END IF
606  30 CONTINUE
607  END IF
608 *
609 * Undo scaling
610 *
611  IF( ilascl ) THEN
612  CALL dlascl( 'H', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
613  CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n, ierr )
614  CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n, ierr )
615  END IF
616 *
617  IF( ilbscl ) THEN
618  CALL dlascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
619  CALL dlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
620  END IF
621 *
622  IF( wantst ) THEN
623 *
624 * Check if reordering is correct
625 *
626  lastsl = .true.
627  lst2sl = .true.
628  sdim = 0
629  ip = 0
630  DO 40 i = 1, n
631  cursl = selctg( alphar( i ), alphai( i ), beta( i ) )
632  IF( alphai( i ).EQ.zero ) THEN
633  IF( cursl )
634  $ sdim = sdim + 1
635  ip = 0
636  IF( cursl .AND. .NOT.lastsl )
637  $ info = n + 2
638  ELSE
639  IF( ip.EQ.1 ) THEN
640 *
641 * Last eigenvalue of conjugate pair
642 *
643  cursl = cursl .OR. lastsl
644  lastsl = cursl
645  IF( cursl )
646  $ sdim = sdim + 2
647  ip = -1
648  IF( cursl .AND. .NOT.lst2sl )
649  $ info = n + 2
650  ELSE
651 *
652 * First eigenvalue of conjugate pair
653 *
654  ip = 1
655  END IF
656  END IF
657  lst2sl = lastsl
658  lastsl = cursl
659  40 CONTINUE
660 *
661  END IF
662 *
663  50 CONTINUE
664 *
665  work( 1 ) = lwkopt
666 *
667  RETURN
668 *
669 * End of DGGES3
670 *
671  END
subroutine dlabad(SMALL, LARGE)
DLABAD
Definition: dlabad.f:74
subroutine dlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: dlascl.f:143
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:103
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: dlaset.f:110
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine dggbak(JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V, LDV, INFO)
DGGBAK
Definition: dggbak.f:147
subroutine dggbal(JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE, RSCALE, WORK, INFO)
DGGBAL
Definition: dggbal.f:177
subroutine dgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
DGEQRF
Definition: dgeqrf.f:146
recursive subroutine dlaqz0(WANTS, WANTQ, WANTZ, N, ILO, IHI, A, LDA, B, LDB, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, WORK, LWORK, REC, INFO)
DLAQZ0
Definition: dlaqz0.f:306
subroutine dgges3(JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB, SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL, VSR, LDVSR, WORK, LWORK, BWORK, INFO)
DGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE ...
Definition: dgges3.f:282
subroutine dorgqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
DORGQR
Definition: dorgqr.f:128
subroutine dormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
DORMQR
Definition: dormqr.f:167
subroutine dgghd3(COMPQ, COMPZ, N, ILO, IHI, A, LDA, B, LDB, Q, LDQ, Z, LDZ, WORK, LWORK, INFO)
DGGHD3
Definition: dgghd3.f:230
subroutine dtgsen(IJOB, WANTQ, WANTZ, SELECT, N, A, LDA, B, LDB, ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, M, PL, PR, DIF, WORK, LWORK, IWORK, LIWORK, INFO)
DTGSEN
Definition: dtgsen.f:451