LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cpocon()

subroutine cpocon ( character  UPLO,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
real  ANORM,
real  RCOND,
complex, dimension( * )  WORK,
real, dimension( * )  RWORK,
integer  INFO 
)

CPOCON

Download CPOCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CPOCON estimates the reciprocal of the condition number (in the
 1-norm) of a complex Hermitian positive definite matrix using the
 Cholesky factorization A = U**H*U or A = L*L**H computed by CPOTRF.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]A
          A is COMPLEX array, dimension (LDA,N)
          The triangular factor U or L from the Cholesky factorization
          A = U**H*U or A = L*L**H, as computed by CPOTRF.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in]ANORM
          ANORM is REAL
          The 1-norm (or infinity-norm) of the Hermitian matrix A.
[out]RCOND
          RCOND is REAL
          The reciprocal of the condition number of the matrix A,
          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
          estimate of the 1-norm of inv(A) computed in this routine.
[out]WORK
          WORK is COMPLEX array, dimension (2*N)
[out]RWORK
          RWORK is REAL array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 123 of file cpocon.f.

123 *
124 * -- LAPACK computational routine (version 3.7.0) --
125 * -- LAPACK is a software package provided by Univ. of Tennessee, --
126 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
127 * December 2016
128 *
129 * .. Scalar Arguments ..
130  CHARACTER uplo
131  INTEGER info, lda, n
132  REAL anorm, rcond
133 * ..
134 * .. Array Arguments ..
135  REAL rwork( * )
136  COMPLEX a( lda, * ), work( * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  REAL one, zero
143  parameter( one = 1.0e+0, zero = 0.0e+0 )
144 * ..
145 * .. Local Scalars ..
146  LOGICAL upper
147  CHARACTER normin
148  INTEGER ix, kase
149  REAL ainvnm, scale, scalel, scaleu, smlnum
150  COMPLEX zdum
151 * ..
152 * .. Local Arrays ..
153  INTEGER isave( 3 )
154 * ..
155 * .. External Functions ..
156  LOGICAL lsame
157  INTEGER icamax
158  REAL slamch
159  EXTERNAL lsame, icamax, slamch
160 * ..
161 * .. External Subroutines ..
162  EXTERNAL clacn2, clatrs, csrscl, xerbla
163 * ..
164 * .. Intrinsic Functions ..
165  INTRINSIC abs, aimag, max, real
166 * ..
167 * .. Statement Functions ..
168  REAL cabs1
169 * ..
170 * .. Statement Function definitions ..
171  cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( aimag( zdum ) )
172 * ..
173 * .. Executable Statements ..
174 *
175 * Test the input parameters.
176 *
177  info = 0
178  upper = lsame( uplo, 'U' )
179  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
180  info = -1
181  ELSE IF( n.LT.0 ) THEN
182  info = -2
183  ELSE IF( lda.LT.max( 1, n ) ) THEN
184  info = -4
185  ELSE IF( anorm.LT.zero ) THEN
186  info = -5
187  END IF
188  IF( info.NE.0 ) THEN
189  CALL xerbla( 'CPOCON', -info )
190  RETURN
191  END IF
192 *
193 * Quick return if possible
194 *
195  rcond = zero
196  IF( n.EQ.0 ) THEN
197  rcond = one
198  RETURN
199  ELSE IF( anorm.EQ.zero ) THEN
200  RETURN
201  END IF
202 *
203  smlnum = slamch( 'Safe minimum' )
204 *
205 * Estimate the 1-norm of inv(A).
206 *
207  kase = 0
208  normin = 'N'
209  10 CONTINUE
210  CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
211  IF( kase.NE.0 ) THEN
212  IF( upper ) THEN
213 *
214 * Multiply by inv(U**H).
215 *
216  CALL clatrs( 'Upper', 'Conjugate transpose', 'Non-unit',
217  $ normin, n, a, lda, work, scalel, rwork, info )
218  normin = 'Y'
219 *
220 * Multiply by inv(U).
221 *
222  CALL clatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
223  $ a, lda, work, scaleu, rwork, info )
224  ELSE
225 *
226 * Multiply by inv(L).
227 *
228  CALL clatrs( 'Lower', 'No transpose', 'Non-unit', normin, n,
229  $ a, lda, work, scalel, rwork, info )
230  normin = 'Y'
231 *
232 * Multiply by inv(L**H).
233 *
234  CALL clatrs( 'Lower', 'Conjugate transpose', 'Non-unit',
235  $ normin, n, a, lda, work, scaleu, rwork, info )
236  END IF
237 *
238 * Multiply by 1/SCALE if doing so will not cause overflow.
239 *
240  scale = scalel*scaleu
241  IF( scale.NE.one ) THEN
242  ix = icamax( n, work, 1 )
243  IF( scale.LT.cabs1( work( ix ) )*smlnum .OR. scale.EQ.zero )
244  $ GO TO 20
245  CALL csrscl( n, scale, work, 1 )
246  END IF
247  GO TO 10
248  END IF
249 *
250 * Compute the estimate of the reciprocal condition number.
251 *
252  IF( ainvnm.NE.zero )
253  $ rcond = ( one / ainvnm ) / anorm
254 *
255  20 CONTINUE
256  RETURN
257 *
258 * End of CPOCON
259 *
integer function icamax(N, CX, INCX)
ICAMAX
Definition: icamax.f:73
subroutine clatrs(UPLO, TRANS, DIAG, NORMIN, N, A, LDA, X, SCALE, CNORM, INFO)
CLATRS solves a triangular system of equations with the scale factor set to prevent overflow...
Definition: clatrs.f:241
subroutine csrscl(N, SA, SX, INCX)
CSRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: csrscl.f:86
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:135
Here is the call graph for this function:
Here is the caller graph for this function: