LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
sormlq.f
Go to the documentation of this file.
1 *> \brief \b SORMLQ
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SORMLQ + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormlq.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormlq.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormlq.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SORMLQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * REAL A( LDA, * ), C( LDC, * ), TAU( * ),
30 * $ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> SORMLQ overwrites the general real M-by-N matrix C with
40 *>
41 *> SIDE = 'L' SIDE = 'R'
42 *> TRANS = 'N': Q * C C * Q
43 *> TRANS = 'T': Q**T * C C * Q**T
44 *>
45 *> where Q is a real orthogonal matrix defined as the product of k
46 *> elementary reflectors
47 *>
48 *> Q = H(k) . . . H(2) H(1)
49 *>
50 *> as returned by SGELQF. Q is of order M if SIDE = 'L' and of order N
51 *> if SIDE = 'R'.
52 *> \endverbatim
53 *
54 * Arguments:
55 * ==========
56 *
57 *> \param[in] SIDE
58 *> \verbatim
59 *> SIDE is CHARACTER*1
60 *> = 'L': apply Q or Q**T from the Left;
61 *> = 'R': apply Q or Q**T from the Right.
62 *> \endverbatim
63 *>
64 *> \param[in] TRANS
65 *> \verbatim
66 *> TRANS is CHARACTER*1
67 *> = 'N': No transpose, apply Q;
68 *> = 'T': Transpose, apply Q**T.
69 *> \endverbatim
70 *>
71 *> \param[in] M
72 *> \verbatim
73 *> M is INTEGER
74 *> The number of rows of the matrix C. M >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] N
78 *> \verbatim
79 *> N is INTEGER
80 *> The number of columns of the matrix C. N >= 0.
81 *> \endverbatim
82 *>
83 *> \param[in] K
84 *> \verbatim
85 *> K is INTEGER
86 *> The number of elementary reflectors whose product defines
87 *> the matrix Q.
88 *> If SIDE = 'L', M >= K >= 0;
89 *> if SIDE = 'R', N >= K >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] A
93 *> \verbatim
94 *> A is REAL array, dimension
95 *> (LDA,M) if SIDE = 'L',
96 *> (LDA,N) if SIDE = 'R'
97 *> The i-th row must contain the vector which defines the
98 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
99 *> SGELQF in the first k rows of its array argument A.
100 *> \endverbatim
101 *>
102 *> \param[in] LDA
103 *> \verbatim
104 *> LDA is INTEGER
105 *> The leading dimension of the array A. LDA >= max(1,K).
106 *> \endverbatim
107 *>
108 *> \param[in] TAU
109 *> \verbatim
110 *> TAU is REAL array, dimension (K)
111 *> TAU(i) must contain the scalar factor of the elementary
112 *> reflector H(i), as returned by SGELQF.
113 *> \endverbatim
114 *>
115 *> \param[in,out] C
116 *> \verbatim
117 *> C is REAL array, dimension (LDC,N)
118 *> On entry, the M-by-N matrix C.
119 *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
120 *> \endverbatim
121 *>
122 *> \param[in] LDC
123 *> \verbatim
124 *> LDC is INTEGER
125 *> The leading dimension of the array C. LDC >= max(1,M).
126 *> \endverbatim
127 *>
128 *> \param[out] WORK
129 *> \verbatim
130 *> WORK is REAL array, dimension (MAX(1,LWORK))
131 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132 *> \endverbatim
133 *>
134 *> \param[in] LWORK
135 *> \verbatim
136 *> LWORK is INTEGER
137 *> The dimension of the array WORK.
138 *> If SIDE = 'L', LWORK >= max(1,N);
139 *> if SIDE = 'R', LWORK >= max(1,M).
140 *> For good performance, LWORK should generally be larger.
141 *>
142 *> If LWORK = -1, then a workspace query is assumed; the routine
143 *> only calculates the optimal size of the WORK array, returns
144 *> this value as the first entry of the WORK array, and no error
145 *> message related to LWORK is issued by XERBLA.
146 *> \endverbatim
147 *>
148 *> \param[out] INFO
149 *> \verbatim
150 *> INFO is INTEGER
151 *> = 0: successful exit
152 *> < 0: if INFO = -i, the i-th argument had an illegal value
153 *> \endverbatim
154 *
155 * Authors:
156 * ========
157 *
158 *> \author Univ. of Tennessee
159 *> \author Univ. of California Berkeley
160 *> \author Univ. of Colorado Denver
161 *> \author NAG Ltd.
162 *
163 *> \date December 2016
164 *
165 *> \ingroup realOTHERcomputational
166 *
167 * =====================================================================
168  SUBROUTINE sormlq( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
169  $ WORK, LWORK, INFO )
170 *
171 * -- LAPACK computational routine (version 3.7.0) --
172 * -- LAPACK is a software package provided by Univ. of Tennessee, --
173 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
174 * December 2016
175 *
176 * .. Scalar Arguments ..
177  CHARACTER SIDE, TRANS
178  INTEGER INFO, K, LDA, LDC, LWORK, M, N
179 * ..
180 * .. Array Arguments ..
181  REAL A( lda, * ), C( ldc, * ), TAU( * ),
182  $ work( * )
183 * ..
184 *
185 * =====================================================================
186 *
187 * .. Parameters ..
188  INTEGER NBMAX, LDT, TSIZE
189  parameter( nbmax = 64, ldt = nbmax+1,
190  $ tsize = ldt*nbmax )
191 * ..
192 * .. Local Scalars ..
193  LOGICAL LEFT, LQUERY, NOTRAN
194  CHARACTER TRANST
195  INTEGER I, I1, I2, I3, IB, IC, IINFO, IWT, JC, LDWORK,
196  $ lwkopt, mi, nb, nbmin, ni, nq, nw
197 * ..
198 * .. External Functions ..
199  LOGICAL LSAME
200  INTEGER ILAENV
201  EXTERNAL lsame, ilaenv
202 * ..
203 * .. External Subroutines ..
204  EXTERNAL slarfb, slarft, sorml2, xerbla
205 * ..
206 * .. Intrinsic Functions ..
207  INTRINSIC max, min
208 * ..
209 * .. Executable Statements ..
210 *
211 * Test the input arguments
212 *
213  info = 0
214  left = lsame( side, 'L' )
215  notran = lsame( trans, 'N' )
216  lquery = ( lwork.EQ.-1 )
217 *
218 * NQ is the order of Q and NW is the minimum dimension of WORK
219 *
220  IF( left ) THEN
221  nq = m
222  nw = n
223  ELSE
224  nq = n
225  nw = m
226  END IF
227  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
228  info = -1
229  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
230  info = -2
231  ELSE IF( m.LT.0 ) THEN
232  info = -3
233  ELSE IF( n.LT.0 ) THEN
234  info = -4
235  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
236  info = -5
237  ELSE IF( lda.LT.max( 1, k ) ) THEN
238  info = -7
239  ELSE IF( ldc.LT.max( 1, m ) ) THEN
240  info = -10
241  ELSE IF( lwork.LT.max( 1, nw ) .AND. .NOT.lquery ) THEN
242  info = -12
243  END IF
244 *
245  IF( info.EQ.0 ) THEN
246 *
247 * Compute the workspace requirements
248 *
249  nb = min( nbmax, ilaenv( 1, 'SORMLQ', side // trans, m, n, k,
250  $ -1 ) )
251  lwkopt = max( 1, nw )*nb + tsize
252  work( 1 ) = lwkopt
253  END IF
254 *
255  IF( info.NE.0 ) THEN
256  CALL xerbla( 'SORMLQ', -info )
257  RETURN
258  ELSE IF( lquery ) THEN
259  RETURN
260  END IF
261 *
262 * Quick return if possible
263 *
264  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
265  work( 1 ) = 1
266  RETURN
267  END IF
268 *
269  nbmin = 2
270  ldwork = nw
271  IF( nb.GT.1 .AND. nb.LT.k ) THEN
272  IF( lwork.LT.nw*nb+tsize ) THEN
273  nb = (lwork-tsize) / ldwork
274  nbmin = max( 2, ilaenv( 2, 'SORMLQ', side // trans, m, n, k,
275  $ -1 ) )
276  END IF
277  END IF
278 *
279  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
280 *
281 * Use unblocked code
282 *
283  CALL sorml2( side, trans, m, n, k, a, lda, tau, c, ldc, work,
284  $ iinfo )
285  ELSE
286 *
287 * Use blocked code
288 *
289  iwt = 1 + nw*nb
290  IF( ( left .AND. notran ) .OR.
291  $ ( .NOT.left .AND. .NOT.notran ) ) THEN
292  i1 = 1
293  i2 = k
294  i3 = nb
295  ELSE
296  i1 = ( ( k-1 ) / nb )*nb + 1
297  i2 = 1
298  i3 = -nb
299  END IF
300 *
301  IF( left ) THEN
302  ni = n
303  jc = 1
304  ELSE
305  mi = m
306  ic = 1
307  END IF
308 *
309  IF( notran ) THEN
310  transt = 'T'
311  ELSE
312  transt = 'N'
313  END IF
314 *
315  DO 10 i = i1, i2, i3
316  ib = min( nb, k-i+1 )
317 *
318 * Form the triangular factor of the block reflector
319 * H = H(i) H(i+1) . . . H(i+ib-1)
320 *
321  CALL slarft( 'Forward', 'Rowwise', nq-i+1, ib, a( i, i ),
322  $ lda, tau( i ), work( iwt ), ldt )
323  IF( left ) THEN
324 *
325 * H or H**T is applied to C(i:m,1:n)
326 *
327  mi = m - i + 1
328  ic = i
329  ELSE
330 *
331 * H or H**T is applied to C(1:m,i:n)
332 *
333  ni = n - i + 1
334  jc = i
335  END IF
336 *
337 * Apply H or H**T
338 *
339  CALL slarfb( side, transt, 'Forward', 'Rowwise', mi, ni, ib,
340  $ a( i, i ), lda, work( iwt ), ldt,
341  $ c( ic, jc ), ldc, work, ldwork )
342  10 CONTINUE
343  END IF
344  work( 1 ) = lwkopt
345  RETURN
346 *
347 * End of SORMLQ
348 *
349  END
subroutine slarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
SLARFB applies a block reflector or its transpose to a general rectangular matrix.
Definition: slarfb.f:197
subroutine sormlq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMLQ
Definition: sormlq.f:170
subroutine slarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
SLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: slarft.f:165
subroutine sorml2(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
SORML2 multiplies a general matrix by the orthogonal matrix from a LQ factorization determined by sge...
Definition: sorml2.f:161
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62