LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dlqt04.f
Go to the documentation of this file.
1*> \brief \b DLQT04
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DLQT04(M,N,NB,RESULT)
12*
13* .. Scalar Arguments ..
14* INTEGER M, N, NB, LDT
15* .. Return values ..
16* DOUBLE PRECISION RESULT(6)
17*
18*
19*> \par Purpose:
20* =============
21*>
22*> \verbatim
23*>
24*> DLQT04 tests DGELQT and DGEMLQT.
25*> \endverbatim
26*
27* Arguments:
28* ==========
29*
30*> \param[in] M
31*> \verbatim
32*> M is INTEGER
33*> Number of rows in test matrix.
34*> \endverbatim
35*>
36*> \param[in] N
37*> \verbatim
38*> N is INTEGER
39*> Number of columns in test matrix.
40*> \endverbatim
41*>
42*> \param[in] NB
43*> \verbatim
44*> NB is INTEGER
45*> Block size of test matrix. NB <= Min(M,N).
46*> \endverbatim
47*>
48*> \param[out] RESULT
49*> \verbatim
50*> RESULT is DOUBLE PRECISION array, dimension (6)
51*> Results of each of the six tests below.
52*>
53*> RESULT(1) = | A - L Q |
54*> RESULT(2) = | I - Q Q^H |
55*> RESULT(3) = | Q C - Q C |
56*> RESULT(4) = | Q^H C - Q^H C |
57*> RESULT(5) = | C Q - C Q |
58*> RESULT(6) = | C Q^H - C Q^H |
59*> \endverbatim
60*
61* Authors:
62* ========
63*
64*> \author Univ. of Tennessee
65*> \author Univ. of California Berkeley
66*> \author Univ. of Colorado Denver
67*> \author NAG Ltd.
68*
69*> \ingroup double_lin
70*
71* =====================================================================
72 SUBROUTINE dlqt04(M,N,NB,RESULT)
73 IMPLICIT NONE
74*
75* -- LAPACK test routine --
76* -- LAPACK is a software package provided by Univ. of Tennessee, --
77* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
78*
79* .. Scalar Arguments ..
80 INTEGER M, N, NB, LDT
81* .. Return values ..
82 DOUBLE PRECISION RESULT(6)
83*
84* =====================================================================
85*
86* ..
87* .. Local allocatable arrays
88 DOUBLE PRECISION, ALLOCATABLE :: AF(:,:), Q(:,:),
89 $ L(:,:), RWORK(:), WORK( : ), T(:,:),
90 $ CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
91*
92* .. Parameters ..
93 DOUBLE PRECISION ONE, ZERO
94 parameter( zero = 0.0, one = 1.0 )
95* ..
96* .. Local Scalars ..
97 INTEGER INFO, J, K, LL, LWORK
98 DOUBLE PRECISION ANORM, EPS, RESID, CNORM, DNORM
99* ..
100* .. Local Arrays ..
101 INTEGER ISEED( 4 )
102* ..
103* .. External Functions ..
104 DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
105 LOGICAL LSAME
106 EXTERNAL dlamch, dlange, dlansy, lsame
107* ..
108* .. Intrinsic Functions ..
109 INTRINSIC max, min
110* ..
111* .. Data statements ..
112 DATA iseed / 1988, 1989, 1990, 1991 /
113*
114 eps = dlamch( 'Epsilon' )
115 k = min(m,n)
116 ll = max(m,n)
117 lwork = max(2,ll)*max(2,ll)*nb
118*
119* Dynamically allocate local arrays
120*
121 ALLOCATE ( a(m,n), af(m,n), q(n,n), l(ll,n), rwork(ll),
122 $ work(lwork), t(nb,n), c(m,n), cf(m,n),
123 $ d(n,m), df(n,m) )
124*
125* Put random numbers into A and copy to AF
126*
127 ldt=nb
128 DO j=1,n
129 CALL dlarnv( 2, iseed, m, a( 1, j ) )
130 END DO
131 CALL dlacpy( 'Full', m, n, a, m, af, m )
132*
133* Factor the matrix A in the array AF.
134*
135 CALL dgelqt( m, n, nb, af, m, t, ldt, work, info )
136*
137* Generate the n-by-n matrix Q
138*
139 CALL dlaset( 'Full', n, n, zero, one, q, n )
140 CALL dgemlqt( 'R', 'N', n, n, k, nb, af, m, t, ldt, q, n,
141 $ work, info )
142*
143* Copy R
144*
145 CALL dlaset( 'Full', m, n, zero, zero, l, ll )
146 CALL dlacpy( 'Lower', m, n, af, m, l, ll )
147*
148* Compute |L - A*Q'| / |A| and store in RESULT(1)
149*
150 CALL dgemm( 'N', 'T', m, n, n, -one, a, m, q, n, one, l, ll )
151 anorm = dlange( '1', m, n, a, m, rwork )
152 resid = dlange( '1', m, n, l, ll, rwork )
153 IF( anorm.GT.zero ) THEN
154 result( 1 ) = resid / (eps*max(1,m)*anorm)
155 ELSE
156 result( 1 ) = zero
157 END IF
158*
159* Compute |I - Q'*Q| and store in RESULT(2)
160*
161 CALL dlaset( 'Full', n, n, zero, one, l, ll )
162 CALL dsyrk( 'U', 'C', n, n, -one, q, n, one, l, ll )
163 resid = dlansy( '1', 'Upper', n, l, ll, rwork )
164 result( 2 ) = resid / (eps*max(1,n))
165*
166* Generate random m-by-n matrix C and a copy CF
167*
168 DO j=1,m
169 CALL dlarnv( 2, iseed, n, d( 1, j ) )
170 END DO
171 dnorm = dlange( '1', n, m, d, n, rwork)
172 CALL dlacpy( 'Full', n, m, d, n, df, n )
173*
174* Apply Q to C as Q*C
175*
176 CALL dgemlqt( 'L', 'N', n, m, k, nb, af, m, t, nb, df, n,
177 $ work, info)
178*
179* Compute |Q*D - Q*D| / |D|
180*
181 CALL dgemm( 'N', 'N', n, m, n, -one, q, n, d, n, one, df, n )
182 resid = dlange( '1', n, m, df, n, rwork )
183 IF( dnorm.GT.zero ) THEN
184 result( 3 ) = resid / (eps*max(1,m)*dnorm)
185 ELSE
186 result( 3 ) = zero
187 END IF
188*
189* Copy D into DF again
190*
191 CALL dlacpy( 'Full', n, m, d, n, df, n )
192*
193* Apply Q to D as QT*D
194*
195 CALL dgemlqt( 'L', 'T', n, m, k, nb, af, m, t, nb, df, n,
196 $ work, info)
197*
198* Compute |QT*D - QT*D| / |D|
199*
200 CALL dgemm( 'T', 'N', n, m, n, -one, q, n, d, n, one, df, n )
201 resid = dlange( '1', n, m, df, n, rwork )
202 IF( dnorm.GT.zero ) THEN
203 result( 4 ) = resid / (eps*max(1,m)*dnorm)
204 ELSE
205 result( 4 ) = zero
206 END IF
207*
208* Generate random n-by-m matrix D and a copy DF
209*
210 DO j=1,n
211 CALL dlarnv( 2, iseed, m, c( 1, j ) )
212 END DO
213 cnorm = dlange( '1', m, n, c, m, rwork)
214 CALL dlacpy( 'Full', m, n, c, m, cf, m )
215*
216* Apply Q to C as C*Q
217*
218 CALL dgemlqt( 'R', 'N', m, n, k, nb, af, m, t, nb, cf, m,
219 $ work, info)
220*
221* Compute |C*Q - C*Q| / |C|
222*
223 CALL dgemm( 'N', 'N', m, n, n, -one, c, m, q, n, one, cf, m )
224 resid = dlange( '1', n, m, df, n, rwork )
225 IF( cnorm.GT.zero ) THEN
226 result( 5 ) = resid / (eps*max(1,m)*dnorm)
227 ELSE
228 result( 5 ) = zero
229 END IF
230*
231* Copy C into CF again
232*
233 CALL dlacpy( 'Full', m, n, c, m, cf, m )
234*
235* Apply Q to D as D*QT
236*
237 CALL dgemlqt( 'R', 'T', m, n, k, nb, af, m, t, nb, cf, m,
238 $ work, info)
239*
240* Compute |C*QT - C*QT| / |C|
241*
242 CALL dgemm( 'N', 'T', m, n, n, -one, c, m, q, n, one, cf, m )
243 resid = dlange( '1', m, n, cf, m, rwork )
244 IF( cnorm.GT.zero ) THEN
245 result( 6 ) = resid / (eps*max(1,m)*dnorm)
246 ELSE
247 result( 6 ) = zero
248 END IF
249*
250* Deallocate all arrays
251*
252 DEALLOCATE ( a, af, q, l, rwork, work, t, c, d, cf, df)
253*
254 RETURN
255 END
256
subroutine dlqt04(m, n, nb, result)
DLQT04
Definition dlqt04.f:73
subroutine dgelqt(m, n, mb, a, lda, t, ldt, work, info)
DGELQT
Definition dgelqt.f:139
subroutine dgemlqt(side, trans, m, n, k, mb, v, ldv, t, ldt, c, ldc, work, info)
DGEMLQT
Definition dgemlqt.f:168
subroutine dgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
DGEMM
Definition dgemm.f:188
subroutine dsyrk(uplo, trans, n, k, alpha, a, lda, beta, c, ldc)
DSYRK
Definition dsyrk.f:169
subroutine dlacpy(uplo, m, n, a, lda, b, ldb)
DLACPY copies all or part of one two-dimensional array to another.
Definition dlacpy.f:103
subroutine dlarnv(idist, iseed, n, x)
DLARNV returns a vector of random numbers from a uniform or normal distribution.
Definition dlarnv.f:97
subroutine dlaset(uplo, m, n, alpha, beta, a, lda)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition dlaset.f:110