LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zla_gbrfsx_extended()

subroutine zla_gbrfsx_extended ( integer  PREC_TYPE,
integer  TRANS_TYPE,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
complex*16, dimension( ldab, * )  AB,
integer  LDAB,
complex*16, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension( * )  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
complex*16, dimension( * )  RES,
double precision, dimension(*)  AYB,
complex*16, dimension( * )  DY,
complex*16, dimension( * )  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

ZLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download ZLA_GBRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLA_GBRFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by ZGBRFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and
     P    = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X', 'E':  Extra
[in]TRANS_TYPE
          TRANS_TYPE is INTEGER
     Specifies the transposition operation on A.
     The value is defined by ILATRANS(T) where T is a CHARACTER and
     T    = 'N':  No transpose
          = 'T':  Transpose
          = 'C':  Conjugate transpose
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]KL
          KL is INTEGER
     The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
     The number of superdiagonals within the band of A.  KU >= 0
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]AB
          AB is COMPLEX*16 array, dimension (LDAB,N)
     On entry, the N-by-N matrix A.
[in]LDAB
          LDAB is INTEGER
     The leading dimension of the array A.  LDAB >= max(1,N).
[in]AFB
          AFB is COMPLEX*16 array, dimension (LDAF,N)
     The factors L and U from the factorization
     A = P*L*U as computed by ZGBTRF.
[in]LDAFB
          LDAFB is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     The pivot indices from the factorization A = P*L*U
     as computed by ZGBTRF; row i of the matrix was interchanged
     with row IPIV(i).
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is COMPLEX*16 array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by ZGBTRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by ZLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace.
[in]DY
          DY is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is COMPLEX*16 array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we definte as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to ZGBTRS had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017

Definition at line 412 of file zla_gbrfsx_extended.f.

412 *
413 * -- LAPACK computational routine (version 3.7.1) --
414 * -- LAPACK is a software package provided by Univ. of Tennessee, --
415 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
416 * June 2017
417 *
418 * .. Scalar Arguments ..
419  INTEGER info, ldab, ldafb, ldb, ldy, n, kl, ku, nrhs,
420  $ prec_type, trans_type, n_norms, ithresh
421  LOGICAL colequ, ignore_cwise
422  DOUBLE PRECISION rthresh, dz_ub
423 * ..
424 * .. Array Arguments ..
425  INTEGER ipiv( * )
426  COMPLEX*16 ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
427  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
428  DOUBLE PRECISION c( * ), ayb(*), rcond, berr_out( * ),
429  $ err_bnds_norm( nrhs, * ),
430  $ err_bnds_comp( nrhs, * )
431 * ..
432 *
433 * =====================================================================
434 *
435 * .. Local Scalars ..
436  CHARACTER trans
437  INTEGER cnt, i, j, m, x_state, z_state, y_prec_state
438  DOUBLE PRECISION yk, dyk, ymin, normy, normx, normdx, dxrat,
439  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
440  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
441  $ eps, hugeval, incr_thresh
442  LOGICAL incr_prec
443  COMPLEX*16 zdum
444 * ..
445 * .. Parameters ..
446  INTEGER unstable_state, working_state, conv_state,
447  $ noprog_state, base_residual, extra_residual,
448  $ extra_y
449  parameter( unstable_state = 0, working_state = 1,
450  $ conv_state = 2, noprog_state = 3 )
451  parameter( base_residual = 0, extra_residual = 1,
452  $ extra_y = 2 )
453  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
454  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
455  INTEGER cmp_err_i, piv_growth_i
456  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
457  $ berr_i = 3 )
458  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
459  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
460  $ piv_growth_i = 9 )
461  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
462  $ la_linrx_cwise_i
463  parameter( la_linrx_itref_i = 1,
464  $ la_linrx_ithresh_i = 2 )
465  parameter( la_linrx_cwise_i = 3 )
466  INTEGER la_linrx_trust_i, la_linrx_err_i,
467  $ la_linrx_rcond_i
468  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
469  parameter( la_linrx_rcond_i = 3 )
470 * ..
471 * .. External Subroutines ..
472  EXTERNAL zaxpy, zcopy, zgbtrs, zgbmv, blas_zgbmv_x,
473  $ blas_zgbmv2_x, zla_gbamv, zla_wwaddw, dlamch,
475  DOUBLE PRECISION dlamch
476  CHARACTER chla_transtype
477 * ..
478 * .. Intrinsic Functions..
479  INTRINSIC abs, max, min
480 * ..
481 * .. Statement Functions ..
482  DOUBLE PRECISION cabs1
483 * ..
484 * .. Statement Function Definitions ..
485  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
486 * ..
487 * .. Executable Statements ..
488 *
489  IF (info.NE.0) RETURN
490  trans = chla_transtype(trans_type)
491  eps = dlamch( 'Epsilon' )
492  hugeval = dlamch( 'Overflow' )
493 * Force HUGEVAL to Inf
494  hugeval = hugeval * hugeval
495 * Using HUGEVAL may lead to spurious underflows.
496  incr_thresh = dble( n ) * eps
497  m = kl+ku+1
498 
499  DO j = 1, nrhs
500  y_prec_state = extra_residual
501  IF ( y_prec_state .EQ. extra_y ) THEN
502  DO i = 1, n
503  y_tail( i ) = 0.0d+0
504  END DO
505  END IF
506 
507  dxrat = 0.0d+0
508  dxratmax = 0.0d+0
509  dzrat = 0.0d+0
510  dzratmax = 0.0d+0
511  final_dx_x = hugeval
512  final_dz_z = hugeval
513  prevnormdx = hugeval
514  prev_dz_z = hugeval
515  dz_z = hugeval
516  dx_x = hugeval
517 
518  x_state = working_state
519  z_state = unstable_state
520  incr_prec = .false.
521 
522  DO cnt = 1, ithresh
523 *
524 * Compute residual RES = B_s - op(A_s) * Y,
525 * op(A) = A, A**T, or A**H depending on TRANS (and type).
526 *
527  CALL zcopy( n, b( 1, j ), 1, res, 1 )
528  IF ( y_prec_state .EQ. base_residual ) THEN
529  CALL zgbmv( trans, m, n, kl, ku, (-1.0d+0,0.0d+0), ab,
530  $ ldab, y( 1, j ), 1, (1.0d+0,0.0d+0), res, 1 )
531  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
532  CALL blas_zgbmv_x( trans_type, n, n, kl, ku,
533  $ (-1.0d+0,0.0d+0), ab, ldab, y( 1, j ), 1,
534  $ (1.0d+0,0.0d+0), res, 1, prec_type )
535  ELSE
536  CALL blas_zgbmv2_x( trans_type, n, n, kl, ku,
537  $ (-1.0d+0,0.0d+0), ab, ldab, y( 1, j ), y_tail, 1,
538  $ (1.0d+0,0.0d+0), res, 1, prec_type )
539  END IF
540 
541 ! XXX: RES is no longer needed.
542  CALL zcopy( n, res, 1, dy, 1 )
543  CALL zgbtrs( trans, n, kl, ku, 1, afb, ldafb, ipiv, dy, n,
544  $ info )
545 *
546 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
547 *
548  normx = 0.0d+0
549  normy = 0.0d+0
550  normdx = 0.0d+0
551  dz_z = 0.0d+0
552  ymin = hugeval
553 
554  DO i = 1, n
555  yk = cabs1( y( i, j ) )
556  dyk = cabs1( dy( i ) )
557 
558  IF (yk .NE. 0.0d+0) THEN
559  dz_z = max( dz_z, dyk / yk )
560  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
561  dz_z = hugeval
562  END IF
563 
564  ymin = min( ymin, yk )
565 
566  normy = max( normy, yk )
567 
568  IF ( colequ ) THEN
569  normx = max( normx, yk * c( i ) )
570  normdx = max(normdx, dyk * c(i))
571  ELSE
572  normx = normy
573  normdx = max( normdx, dyk )
574  END IF
575  END DO
576 
577  IF ( normx .NE. 0.0d+0 ) THEN
578  dx_x = normdx / normx
579  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
580  dx_x = 0.0d+0
581  ELSE
582  dx_x = hugeval
583  END IF
584 
585  dxrat = normdx / prevnormdx
586  dzrat = dz_z / prev_dz_z
587 *
588 * Check termination criteria.
589 *
590  IF (.NOT.ignore_cwise
591  $ .AND. ymin*rcond .LT. incr_thresh*normy
592  $ .AND. y_prec_state .LT. extra_y )
593  $ incr_prec = .true.
594 
595  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
596  $ x_state = working_state
597  IF ( x_state .EQ. working_state ) THEN
598  IF ( dx_x .LE. eps ) THEN
599  x_state = conv_state
600  ELSE IF ( dxrat .GT. rthresh ) THEN
601  IF ( y_prec_state .NE. extra_y ) THEN
602  incr_prec = .true.
603  ELSE
604  x_state = noprog_state
605  END IF
606  ELSE
607  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
608  END IF
609  IF ( x_state .GT. working_state ) final_dx_x = dx_x
610  END IF
611 
612  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
613  $ z_state = working_state
614  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
615  $ z_state = working_state
616  IF ( z_state .EQ. working_state ) THEN
617  IF ( dz_z .LE. eps ) THEN
618  z_state = conv_state
619  ELSE IF ( dz_z .GT. dz_ub ) THEN
620  z_state = unstable_state
621  dzratmax = 0.0d+0
622  final_dz_z = hugeval
623  ELSE IF ( dzrat .GT. rthresh ) THEN
624  IF ( y_prec_state .NE. extra_y ) THEN
625  incr_prec = .true.
626  ELSE
627  z_state = noprog_state
628  END IF
629  ELSE
630  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
631  END IF
632  IF ( z_state .GT. working_state ) final_dz_z = dz_z
633  END IF
634 *
635 * Exit if both normwise and componentwise stopped working,
636 * but if componentwise is unstable, let it go at least two
637 * iterations.
638 *
639  IF ( x_state.NE.working_state ) THEN
640  IF ( ignore_cwise ) GOTO 666
641  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
642  $ GOTO 666
643  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
644  END IF
645 
646  IF ( incr_prec ) THEN
647  incr_prec = .false.
648  y_prec_state = y_prec_state + 1
649  DO i = 1, n
650  y_tail( i ) = 0.0d+0
651  END DO
652  END IF
653 
654  prevnormdx = normdx
655  prev_dz_z = dz_z
656 *
657 * Update soluton.
658 *
659  IF ( y_prec_state .LT. extra_y ) THEN
660  CALL zaxpy( n, (1.0d+0,0.0d+0), dy, 1, y(1,j), 1 )
661  ELSE
662  CALL zla_wwaddw( n, y(1,j), y_tail, dy )
663  END IF
664 
665  END DO
666 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
667  666 CONTINUE
668 *
669 * Set final_* when cnt hits ithresh.
670 *
671  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
672  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
673 *
674 * Compute error bounds.
675 *
676  IF ( n_norms .GE. 1 ) THEN
677  err_bnds_norm( j, la_linrx_err_i ) =
678  $ final_dx_x / (1 - dxratmax)
679  END IF
680  IF ( n_norms .GE. 2 ) THEN
681  err_bnds_comp( j, la_linrx_err_i ) =
682  $ final_dz_z / (1 - dzratmax)
683  END IF
684 *
685 * Compute componentwise relative backward error from formula
686 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
687 * where abs(Z) is the componentwise absolute value of the matrix
688 * or vector Z.
689 *
690 * Compute residual RES = B_s - op(A_s) * Y,
691 * op(A) = A, A**T, or A**H depending on TRANS (and type).
692 *
693  CALL zcopy( n, b( 1, j ), 1, res, 1 )
694  CALL zgbmv( trans, n, n, kl, ku, (-1.0d+0,0.0d+0), ab, ldab,
695  $ y(1,j), 1, (1.0d+0,0.0d+0), res, 1 )
696 
697  DO i = 1, n
698  ayb( i ) = cabs1( b( i, j ) )
699  END DO
700 *
701 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
702 *
703  CALL zla_gbamv( trans_type, n, n, kl, ku, 1.0d+0,
704  $ ab, ldab, y(1, j), 1, 1.0d+0, ayb, 1 )
705 
706  CALL zla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
707 *
708 * End of loop for each RHS.
709 *
710  END DO
711 *
712  RETURN
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
ZGBTRS
Definition: zgbtrs.f:140
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:83
subroutine zgbmv(TRANS, M, N, KL, KU, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGBMV
Definition: zgbmv.f:189
subroutine zla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
ZLA_LIN_BERR computes a component-wise relative backward error.
Definition: zla_lin_berr.f:103
subroutine zla_gbamv(TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X, INCX, BETA, Y, INCY)
ZLA_GBAMV performs a matrix-vector operation to calculate error bounds.
Definition: zla_gbamv.f:188
subroutine zla_wwaddw(N, X, Y, W)
ZLA_WWADDW adds a vector into a doubled-single vector.
Definition: zla_wwaddw.f:83
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:90
Here is the call graph for this function:
Here is the caller graph for this function: