zhpr()

subroutine zhpr	(	character	uplo,
		integer	n,
		double precision	alpha,
		complex*16, dimension(*)	x,
		integer	incx,
		complex*16, dimension(*)	ap
	)

ZHPR

Purpose:

 ZHPR    performs the hermitian rank 1 operation

    A := alpha*x*x**H + A,

 where alpha is a real scalar, x is an n element vector and A is an
 n by n hermitian matrix, supplied in packed form.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 On entry, UPLO specifies whether the upper or lower triangular part of the matrix A is supplied in the packed array AP as follows: UPLO = 'U' or 'u' The upper triangular part of A is supplied in AP. UPLO = 'L' or 'l' The lower triangular part of A is supplied in AP.
[in]	N	N is INTEGER On entry, N specifies the order of the matrix A. N must be at least zero.
[in]	ALPHA	ALPHA is DOUBLE PRECISION. On entry, ALPHA specifies the scalar alpha.
[in]	X	X is COMPLEX*16 array, dimension at least ( 1 + ( n - 1 )*abs( INCX ) ). Before entry, the incremented array X must contain the n element vector x.
[in]	INCX	INCX is INTEGER On entry, INCX specifies the increment for the elements of X. INCX must not be zero.
[in,out]	AP	AP is COMPLEX*16 array, dimension at least ( ( n*( n + 1 ) )/2 ). Before entry with UPLO = 'U' or 'u', the array AP must contain the upper triangular part of the hermitian matrix packed sequentially, column by column, so that AP( 1 ) contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 ) respectively, and so on. On exit, the array AP is overwritten by the upper triangular part of the updated matrix. Before entry with UPLO = 'L' or 'l', the array AP must contain the lower triangular part of the hermitian matrix packed sequentially, column by column, so that AP( 1 ) contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 ) respectively, and so on. On exit, the array AP is overwritten by the lower triangular part of the updated matrix. Note that the imaginary parts of the diagonal elements need not be set, they are assumed to be zero, and on exit they are set to zero.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  Level 2 Blas routine.

  -- Written on 22-October-1986.
     Jack Dongarra, Argonne National Lab.
     Jeremy Du Croz, Nag Central Office.
     Sven Hammarling, Nag Central Office.
     Richard Hanson, Sandia National Labs.

Definition at line 129 of file zhpr.f.

*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION ALPHA
      INTEGER INCX,N
      CHARACTER UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX*16 AP(*),X(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16 ZERO
      parameter(zero= (0.0d+0,0.0d+0))
*     ..
*     .. Local Scalars ..
      COMPLEX*16 TEMP
      INTEGER I,INFO,IX,J,JX,K,KK,KX
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC dble,dconjg
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (n.LT.0) THEN
          info = 2
      ELSE IF (incx.EQ.0) THEN
          info = 5
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('ZHPR  ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF ((n.EQ.0) .OR. (alpha.EQ.dble(zero))) RETURN
*
*     Set the start point in X if the increment is not unity.
*
      IF (incx.LE.0) THEN
          kx = 1 - (n-1)*incx
      ELSE IF (incx.NE.1) THEN
          kx = 1
      END IF
*
*     Start the operations. In this version the elements of the array AP
*     are accessed sequentially with one pass through AP.
*
      kk = 1
      IF (lsame(uplo,'U')) THEN
*
*        Form  A  when upper triangle is stored in AP.
*
          IF (incx.EQ.1) THEN
              DO 20 j = 1,n
                  IF (x(j).NE.zero) THEN
                      temp = alpha*dconjg(x(j))
                      k = kk
                      DO 10 i = 1,j - 1
                          ap(k) = ap(k) + x(i)*temp
                          k = k + 1
   10                 CONTINUE
                      ap(kk+j-1) = dble(ap(kk+j-1)) + dble(x(j)*temp)
                  ELSE
                      ap(kk+j-1) = dble(ap(kk+j-1))
                  END IF
                  kk = kk + j
   20         CONTINUE
          ELSE
              jx = kx
              DO 40 j = 1,n
                  IF (x(jx).NE.zero) THEN
                      temp = alpha*dconjg(x(jx))
                      ix = kx
                      DO 30 k = kk,kk + j - 2
                          ap(k) = ap(k) + x(ix)*temp
                          ix = ix + incx
   30                 CONTINUE
                      ap(kk+j-1) = dble(ap(kk+j-1)) + dble(x(jx)*temp)
                  ELSE
                      ap(kk+j-1) = dble(ap(kk+j-1))
                  END IF
                  jx = jx + incx
                  kk = kk + j
   40         CONTINUE
          END IF
      ELSE
*
*        Form  A  when lower triangle is stored in AP.
*
          IF (incx.EQ.1) THEN
              DO 60 j = 1,n
                  IF (x(j).NE.zero) THEN
                      temp = alpha*dconjg(x(j))
                      ap(kk) = dble(ap(kk)) + dble(temp*x(j))
                      k = kk + 1
                      DO 50 i = j + 1,n
                          ap(k) = ap(k) + x(i)*temp
                          k = k + 1
   50                 CONTINUE
                  ELSE
                      ap(kk) = dble(ap(kk))
                  END IF
                  kk = kk + n - j + 1
   60         CONTINUE
          ELSE
              jx = kx
              DO 80 j = 1,n
                  IF (x(jx).NE.zero) THEN
                      temp = alpha*dconjg(x(jx))
                      ap(kk) = dble(ap(kk)) + dble(temp*x(jx))
                      ix = jx
                      DO 70 k = kk + 1,kk + n - j
                          ix = ix + incx
                          ap(k) = ap(k) + x(ix)*temp
   70                 CONTINUE
                  ELSE
                      ap(kk) = dble(ap(kk))
                  END IF
                  jx = jx + incx
                  kk = kk + n - j + 1
   80         CONTINUE
          END IF
      END IF
*
      RETURN
*
*     End of ZHPR
*

Here is the call graph for this function:

Here is the caller graph for this function: