LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ sgttrs()

 subroutine sgttrs ( character TRANS, integer N, integer NRHS, real, dimension( * ) DL, real, dimension( * ) D, real, dimension( * ) DU, real, dimension( * ) DU2, integer, dimension( * ) IPIV, real, dimension( ldb, * ) B, integer LDB, integer INFO )

SGTTRS

Purpose:
``` SGTTRS solves one of the systems of equations
A*X = B  or  A**T*X = B,
with a tridiagonal matrix A using the LU factorization computed
by SGTTRF.```
Parameters
 [in] TRANS ``` TRANS is CHARACTER*1 Specifies the form of the system of equations. = 'N': A * X = B (No transpose) = 'T': A**T* X = B (Transpose) = 'C': A**T* X = B (Conjugate transpose = Transpose)``` [in] N ``` N is INTEGER The order of the matrix A.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.``` [in] DL ``` DL is REAL array, dimension (N-1) The (n-1) multipliers that define the matrix L from the LU factorization of A.``` [in] D ``` D is REAL array, dimension (N) The n diagonal elements of the upper triangular matrix U from the LU factorization of A.``` [in] DU ``` DU is REAL array, dimension (N-1) The (n-1) elements of the first super-diagonal of U.``` [in] DU2 ``` DU2 is REAL array, dimension (N-2) The (n-2) elements of the second super-diagonal of U.``` [in] IPIV ``` IPIV is INTEGER array, dimension (N) The pivot indices; for 1 <= i <= n, row i of the matrix was interchanged with row IPIV(i). IPIV(i) will always be either i or i+1; IPIV(i) = i indicates a row interchange was not required.``` [in,out] B ``` B is REAL array, dimension (LDB,NRHS) On entry, the matrix of right hand side vectors B. On exit, B is overwritten by the solution vectors X.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```

Definition at line 136 of file sgttrs.f.

138 *
139 * -- LAPACK computational routine --
140 * -- LAPACK is a software package provided by Univ. of Tennessee, --
141 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
142 *
143 * .. Scalar Arguments ..
144  CHARACTER TRANS
145  INTEGER INFO, LDB, N, NRHS
146 * ..
147 * .. Array Arguments ..
148  INTEGER IPIV( * )
149  REAL B( LDB, * ), D( * ), DL( * ), DU( * ), DU2( * )
150 * ..
151 *
152 * =====================================================================
153 *
154 * .. Local Scalars ..
155  LOGICAL NOTRAN
156  INTEGER ITRANS, J, JB, NB
157 * ..
158 * .. External Functions ..
159  INTEGER ILAENV
160  EXTERNAL ilaenv
161 * ..
162 * .. External Subroutines ..
163  EXTERNAL sgtts2, xerbla
164 * ..
165 * .. Intrinsic Functions ..
166  INTRINSIC max, min
167 * ..
168 * .. Executable Statements ..
169 *
170  info = 0
171  notran = ( trans.EQ.'N' .OR. trans.EQ.'n' )
172  IF( .NOT.notran .AND. .NOT.( trans.EQ.'T' .OR. trans.EQ.
173  \$ 't' ) .AND. .NOT.( trans.EQ.'C' .OR. trans.EQ.'c' ) ) THEN
174  info = -1
175  ELSE IF( n.LT.0 ) THEN
176  info = -2
177  ELSE IF( nrhs.LT.0 ) THEN
178  info = -3
179  ELSE IF( ldb.LT.max( n, 1 ) ) THEN
180  info = -10
181  END IF
182  IF( info.NE.0 ) THEN
183  CALL xerbla( 'SGTTRS', -info )
184  RETURN
185  END IF
186 *
187 * Quick return if possible
188 *
189  IF( n.EQ.0 .OR. nrhs.EQ.0 )
190  \$ RETURN
191 *
192 * Decode TRANS
193 *
194  IF( notran ) THEN
195  itrans = 0
196  ELSE
197  itrans = 1
198  END IF
199 *
200 * Determine the number of right-hand sides to solve at a time.
201 *
202  IF( nrhs.EQ.1 ) THEN
203  nb = 1
204  ELSE
205  nb = max( 1, ilaenv( 1, 'SGTTRS', trans, n, nrhs, -1, -1 ) )
206  END IF
207 *
208  IF( nb.GE.nrhs ) THEN
209  CALL sgtts2( itrans, n, nrhs, dl, d, du, du2, ipiv, b, ldb )
210  ELSE
211  DO 10 j = 1, nrhs, nb
212  jb = min( nrhs-j+1, nb )
213  CALL sgtts2( itrans, n, jb, dl, d, du, du2, ipiv, b( 1, j ),
214  \$ ldb )
215  10 CONTINUE
216  END IF
217 *
218 * End of SGTTRS
219 *
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: ilaenv.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine sgtts2(ITRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB)
SGTTS2 solves a system of linear equations with a tridiagonal matrix using the LU factorization compu...
Definition: sgtts2.f:128
Here is the call graph for this function:
Here is the caller graph for this function: