LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
dsbgvd.f
Go to the documentation of this file.
1 *> \brief \b DSBGVD
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DSBGVD + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsbgvd.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsbgvd.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsbgvd.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DSBGVD( JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, W,
22 * Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER JOBZ, UPLO
26 * INTEGER INFO, KA, KB, LDAB, LDBB, LDZ, LIWORK, LWORK, N
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IWORK( * )
30 * DOUBLE PRECISION AB( LDAB, * ), BB( LDBB, * ), W( * ),
31 * $ WORK( * ), Z( LDZ, * )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> DSBGVD computes all the eigenvalues, and optionally, the eigenvectors
41 *> of a real generalized symmetric-definite banded eigenproblem, of the
42 *> form A*x=(lambda)*B*x. Here A and B are assumed to be symmetric and
43 *> banded, and B is also positive definite. If eigenvectors are
44 *> desired, it uses a divide and conquer algorithm.
45 *>
46 *> The divide and conquer algorithm makes very mild assumptions about
47 *> floating point arithmetic. It will work on machines with a guard
48 *> digit in add/subtract, or on those binary machines without guard
49 *> digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
50 *> Cray-2. It could conceivably fail on hexadecimal or decimal machines
51 *> without guard digits, but we know of none.
52 *> \endverbatim
53 *
54 * Arguments:
55 * ==========
56 *
57 *> \param[in] JOBZ
58 *> \verbatim
59 *> JOBZ is CHARACTER*1
60 *> = 'N': Compute eigenvalues only;
61 *> = 'V': Compute eigenvalues and eigenvectors.
62 *> \endverbatim
63 *>
64 *> \param[in] UPLO
65 *> \verbatim
66 *> UPLO is CHARACTER*1
67 *> = 'U': Upper triangles of A and B are stored;
68 *> = 'L': Lower triangles of A and B are stored.
69 *> \endverbatim
70 *>
71 *> \param[in] N
72 *> \verbatim
73 *> N is INTEGER
74 *> The order of the matrices A and B. N >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] KA
78 *> \verbatim
79 *> KA is INTEGER
80 *> The number of superdiagonals of the matrix A if UPLO = 'U',
81 *> or the number of subdiagonals if UPLO = 'L'. KA >= 0.
82 *> \endverbatim
83 *>
84 *> \param[in] KB
85 *> \verbatim
86 *> KB is INTEGER
87 *> The number of superdiagonals of the matrix B if UPLO = 'U',
88 *> or the number of subdiagonals if UPLO = 'L'. KB >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in,out] AB
92 *> \verbatim
93 *> AB is DOUBLE PRECISION array, dimension (LDAB, N)
94 *> On entry, the upper or lower triangle of the symmetric band
95 *> matrix A, stored in the first ka+1 rows of the array. The
96 *> j-th column of A is stored in the j-th column of the array AB
97 *> as follows:
98 *> if UPLO = 'U', AB(ka+1+i-j,j) = A(i,j) for max(1,j-ka)<=i<=j;
99 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+ka).
100 *>
101 *> On exit, the contents of AB are destroyed.
102 *> \endverbatim
103 *>
104 *> \param[in] LDAB
105 *> \verbatim
106 *> LDAB is INTEGER
107 *> The leading dimension of the array AB. LDAB >= KA+1.
108 *> \endverbatim
109 *>
110 *> \param[in,out] BB
111 *> \verbatim
112 *> BB is DOUBLE PRECISION array, dimension (LDBB, N)
113 *> On entry, the upper or lower triangle of the symmetric band
114 *> matrix B, stored in the first kb+1 rows of the array. The
115 *> j-th column of B is stored in the j-th column of the array BB
116 *> as follows:
117 *> if UPLO = 'U', BB(ka+1+i-j,j) = B(i,j) for max(1,j-kb)<=i<=j;
118 *> if UPLO = 'L', BB(1+i-j,j) = B(i,j) for j<=i<=min(n,j+kb).
119 *>
120 *> On exit, the factor S from the split Cholesky factorization
121 *> B = S**T*S, as returned by DPBSTF.
122 *> \endverbatim
123 *>
124 *> \param[in] LDBB
125 *> \verbatim
126 *> LDBB is INTEGER
127 *> The leading dimension of the array BB. LDBB >= KB+1.
128 *> \endverbatim
129 *>
130 *> \param[out] W
131 *> \verbatim
132 *> W is DOUBLE PRECISION array, dimension (N)
133 *> If INFO = 0, the eigenvalues in ascending order.
134 *> \endverbatim
135 *>
136 *> \param[out] Z
137 *> \verbatim
138 *> Z is DOUBLE PRECISION array, dimension (LDZ, N)
139 *> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
140 *> eigenvectors, with the i-th column of Z holding the
141 *> eigenvector associated with W(i). The eigenvectors are
142 *> normalized so Z**T*B*Z = I.
143 *> If JOBZ = 'N', then Z is not referenced.
144 *> \endverbatim
145 *>
146 *> \param[in] LDZ
147 *> \verbatim
148 *> LDZ is INTEGER
149 *> The leading dimension of the array Z. LDZ >= 1, and if
150 *> JOBZ = 'V', LDZ >= max(1,N).
151 *> \endverbatim
152 *>
153 *> \param[out] WORK
154 *> \verbatim
155 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
156 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
157 *> \endverbatim
158 *>
159 *> \param[in] LWORK
160 *> \verbatim
161 *> LWORK is INTEGER
162 *> The dimension of the array WORK.
163 *> If N <= 1, LWORK >= 1.
164 *> If JOBZ = 'N' and N > 1, LWORK >= 2*N.
165 *> If JOBZ = 'V' and N > 1, LWORK >= 1 + 5*N + 2*N**2.
166 *>
167 *> If LWORK = -1, then a workspace query is assumed; the routine
168 *> only calculates the optimal sizes of the WORK and IWORK
169 *> arrays, returns these values as the first entries of the WORK
170 *> and IWORK arrays, and no error message related to LWORK or
171 *> LIWORK is issued by XERBLA.
172 *> \endverbatim
173 *>
174 *> \param[out] IWORK
175 *> \verbatim
176 *> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
177 *> On exit, if LIWORK > 0, IWORK(1) returns the optimal LIWORK.
178 *> \endverbatim
179 *>
180 *> \param[in] LIWORK
181 *> \verbatim
182 *> LIWORK is INTEGER
183 *> The dimension of the array IWORK.
184 *> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
185 *> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
186 *>
187 *> If LIWORK = -1, then a workspace query is assumed; the
188 *> routine only calculates the optimal sizes of the WORK and
189 *> IWORK arrays, returns these values as the first entries of
190 *> the WORK and IWORK arrays, and no error message related to
191 *> LWORK or LIWORK is issued by XERBLA.
192 *> \endverbatim
193 *>
194 *> \param[out] INFO
195 *> \verbatim
196 *> INFO is INTEGER
197 *> = 0: successful exit
198 *> < 0: if INFO = -i, the i-th argument had an illegal value
199 *> > 0: if INFO = i, and i is:
200 *> <= N: the algorithm failed to converge:
201 *> i off-diagonal elements of an intermediate
202 *> tridiagonal form did not converge to zero;
203 *> > N: if INFO = N + i, for 1 <= i <= N, then DPBSTF
204 *> returned INFO = i: B is not positive definite.
205 *> The factorization of B could not be completed and
206 *> no eigenvalues or eigenvectors were computed.
207 *> \endverbatim
208 *
209 * Authors:
210 * ========
211 *
212 *> \author Univ. of Tennessee
213 *> \author Univ. of California Berkeley
214 *> \author Univ. of Colorado Denver
215 *> \author NAG Ltd.
216 *
217 *> \date June 2016
218 *
219 *> \ingroup doubleOTHEReigen
220 *
221 *> \par Contributors:
222 * ==================
223 *>
224 *> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
225 *
226 * =====================================================================
227  SUBROUTINE dsbgvd( JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, W,
228  $ Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO )
229 *
230 * -- LAPACK driver routine (version 3.7.0) --
231 * -- LAPACK is a software package provided by Univ. of Tennessee, --
232 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
233 * June 2016
234 *
235 * .. Scalar Arguments ..
236  CHARACTER JOBZ, UPLO
237  INTEGER INFO, KA, KB, LDAB, LDBB, LDZ, LIWORK, LWORK, N
238 * ..
239 * .. Array Arguments ..
240  INTEGER IWORK( * )
241  DOUBLE PRECISION AB( ldab, * ), BB( ldbb, * ), W( * ),
242  $ work( * ), z( ldz, * )
243 * ..
244 *
245 * =====================================================================
246 *
247 * .. Parameters ..
248  DOUBLE PRECISION ONE, ZERO
249  parameter( one = 1.0d+0, zero = 0.0d+0 )
250 * ..
251 * .. Local Scalars ..
252  LOGICAL LQUERY, UPPER, WANTZ
253  CHARACTER VECT
254  INTEGER IINFO, INDE, INDWK2, INDWRK, LIWMIN, LLWRK2,
255  $ lwmin
256 * ..
257 * .. External Functions ..
258  LOGICAL LSAME
259  EXTERNAL lsame
260 * ..
261 * .. External Subroutines ..
262  EXTERNAL dgemm, dlacpy, dpbstf, dsbgst, dsbtrd, dstedc,
263  $ dsterf, xerbla
264 * ..
265 * .. Executable Statements ..
266 *
267 * Test the input parameters.
268 *
269  wantz = lsame( jobz, 'V' )
270  upper = lsame( uplo, 'U' )
271  lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
272 *
273  info = 0
274  IF( n.LE.1 ) THEN
275  liwmin = 1
276  lwmin = 1
277  ELSE IF( wantz ) THEN
278  liwmin = 3 + 5*n
279  lwmin = 1 + 5*n + 2*n**2
280  ELSE
281  liwmin = 1
282  lwmin = 2*n
283  END IF
284 *
285  IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
286  info = -1
287  ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
288  info = -2
289  ELSE IF( n.LT.0 ) THEN
290  info = -3
291  ELSE IF( ka.LT.0 ) THEN
292  info = -4
293  ELSE IF( kb.LT.0 .OR. kb.GT.ka ) THEN
294  info = -5
295  ELSE IF( ldab.LT.ka+1 ) THEN
296  info = -7
297  ELSE IF( ldbb.LT.kb+1 ) THEN
298  info = -9
299  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
300  info = -12
301  END IF
302 *
303  IF( info.EQ.0 ) THEN
304  work( 1 ) = lwmin
305  iwork( 1 ) = liwmin
306 *
307  IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
308  info = -14
309  ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
310  info = -16
311  END IF
312  END IF
313 *
314  IF( info.NE.0 ) THEN
315  CALL xerbla( 'DSBGVD', -info )
316  RETURN
317  ELSE IF( lquery ) THEN
318  RETURN
319  END IF
320 *
321 * Quick return if possible
322 *
323  IF( n.EQ.0 )
324  $ RETURN
325 *
326 * Form a split Cholesky factorization of B.
327 *
328  CALL dpbstf( uplo, n, kb, bb, ldbb, info )
329  IF( info.NE.0 ) THEN
330  info = n + info
331  RETURN
332  END IF
333 *
334 * Transform problem to standard eigenvalue problem.
335 *
336  inde = 1
337  indwrk = inde + n
338  indwk2 = indwrk + n*n
339  llwrk2 = lwork - indwk2 + 1
340  CALL dsbgst( jobz, uplo, n, ka, kb, ab, ldab, bb, ldbb, z, ldz,
341  $ work, iinfo )
342 *
343 * Reduce to tridiagonal form.
344 *
345  IF( wantz ) THEN
346  vect = 'U'
347  ELSE
348  vect = 'N'
349  END IF
350  CALL dsbtrd( vect, uplo, n, ka, ab, ldab, w, work( inde ), z, ldz,
351  $ work( indwrk ), iinfo )
352 *
353 * For eigenvalues only, call DSTERF. For eigenvectors, call SSTEDC.
354 *
355  IF( .NOT.wantz ) THEN
356  CALL dsterf( n, w, work( inde ), info )
357  ELSE
358  CALL dstedc( 'I', n, w, work( inde ), work( indwrk ), n,
359  $ work( indwk2 ), llwrk2, iwork, liwork, info )
360  CALL dgemm( 'N', 'N', n, n, n, one, z, ldz, work( indwrk ), n,
361  $ zero, work( indwk2 ), n )
362  CALL dlacpy( 'A', n, n, work( indwk2 ), n, z, ldz )
363  END IF
364 *
365  work( 1 ) = lwmin
366  iwork( 1 ) = liwmin
367 *
368  RETURN
369 *
370 * End of DSBGVD
371 *
372  END
subroutine dsterf(N, D, E, INFO)
DSTERF
Definition: dsterf.f:88
subroutine dsbtrd(VECT, UPLO, N, KD, AB, LDAB, D, E, Q, LDQ, WORK, INFO)
DSBTRD
Definition: dsbtrd.f:165
subroutine dstedc(COMPZ, N, D, E, Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO)
DSTEDC
Definition: dstedc.f:190
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:189
subroutine dpbstf(UPLO, N, KD, AB, LDAB, INFO)
DPBSTF
Definition: dpbstf.f:154
subroutine dsbgst(VECT, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, X, LDX, WORK, INFO)
DSBGST
Definition: dsbgst.f:161
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dsbgvd(JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, W, Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO)
DSBGVD
Definition: dsbgvd.f:229
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:105