dsyconvf()

subroutine dsyconvf	(	character	uplo,
		character	way,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	e,
		integer, dimension( * )	ipiv,
		integer	info
	)

DSYCONVF

Download DSYCONVF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 If parameter WAY = 'C':
 DSYCONVF converts the factorization output format used in
 DSYTRF provided on entry in parameter A into the factorization
 output format used in DSYTRF_RK (or DSYTRF_BK) that is stored
 on exit in parameters A and E. It also converts in place details of
 the interchanges stored in IPIV from the format used in DSYTRF into
 the format used in DSYTRF_RK (or DSYTRF_BK).

 If parameter WAY = 'R':
 DSYCONVF performs the conversion in reverse direction, i.e.
 converts the factorization output format used in DSYTRF_RK
 (or DSYTRF_BK) provided on entry in parameters A and E into
 the factorization output format used in DSYTRF that is stored
 on exit in parameter A. It also converts in place details of
 the interchanges stored in IPIV from the format used in DSYTRF_RK
 (or DSYTRF_BK) into the format used in DSYTRF.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the details of the factorization are stored as an upper or lower triangular matrix A. = 'U': Upper triangular = 'L': Lower triangular
[in]	WAY	WAY is CHARACTER*1 = 'C': Convert = 'R': Revert
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) 1) If WAY ='C': On entry, contains factorization details in format used in DSYTRF: a) all elements of the symmetric block diagonal matrix D on the diagonal of A and on superdiagonal (or subdiagonal) of A, and b) If UPLO = 'U': multipliers used to obtain factor U in the superdiagonal part of A. If UPLO = 'L': multipliers used to obtain factor L in the superdiagonal part of A. On exit, contains factorization details in format used in DSYTRF_RK or DSYTRF_BK: a) ONLY diagonal elements of the symmetric block diagonal matrix D on the diagonal of A, i.e. D(k,k) = A(k,k); (superdiagonal (or subdiagonal) elements of D are stored on exit in array E), and b) If UPLO = 'U': factor U in the superdiagonal part of A. If UPLO = 'L': factor L in the subdiagonal part of A. 2) If WAY = 'R': On entry, contains factorization details in format used in DSYTRF_RK or DSYTRF_BK: a) ONLY diagonal elements of the symmetric block diagonal matrix D on the diagonal of A, i.e. D(k,k) = A(k,k); (superdiagonal (or subdiagonal) elements of D are stored on exit in array E), and b) If UPLO = 'U': factor U in the superdiagonal part of A. If UPLO = 'L': factor L in the subdiagonal part of A. On exit, contains factorization details in format used in DSYTRF: a) all elements of the symmetric block diagonal matrix D on the diagonal of A and on superdiagonal (or subdiagonal) of A, and b) If UPLO = 'U': multipliers used to obtain factor U in the superdiagonal part of A. If UPLO = 'L': multipliers used to obtain factor L in the superdiagonal part of A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in,out]	E	E is DOUBLE PRECISION array, dimension (N) 1) If WAY ='C': On entry, just a workspace. On exit, contains the superdiagonal (or subdiagonal) elements of the symmetric block diagonal matrix D with 1-by-1 or 2-by-2 diagonal blocks, where If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0; If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0. 2) If WAY = 'R': On entry, contains the superdiagonal (or subdiagonal) elements of the symmetric block diagonal matrix D with 1-by-1 or 2-by-2 diagonal blocks, where If UPLO = 'U': E(i) = D(i-1,i),i=2:N, E(1) not referenced; If UPLO = 'L': E(i) = D(i+1,i),i=1:N-1, E(N) not referenced. On exit, is not changed
[in,out]	IPIV	IPIV is INTEGER array, dimension (N) 1) If WAY ='C': On entry, details of the interchanges and the block structure of D in the format used in DSYTRF. On exit, details of the interchanges and the block structure of D in the format used in DSYTRF_RK ( or DSYTRF_BK). 1) If WAY ='R': On entry, details of the interchanges and the block structure of D in the format used in DSYTRF_RK ( or DSYTRF_BK). On exit, details of the interchanges and the block structure of D in the format used in DSYTRF.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

  November 2017,  Igor Kozachenko,
                  Computer Science Division,
                  University of California, Berkeley

Definition at line 205 of file dsyconvf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO, WAY
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      DOUBLE PRECISION   A( LDA, * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*
*     .. External Subroutines ..
      EXTERNAL           dswap, xerbla
*     .. Local Scalars ..
      LOGICAL            UPPER, CONVERT
      INTEGER            I, IP
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      convert = lsame( way, 'C' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.convert .AND. .NOT.lsame( way, 'R' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
 
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSYCONVF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Begin A is UPPER
*
         IF ( convert ) THEN
*
*           Convert A (A is upper)
*
*
*           Convert VALUE
*
*           Assign superdiagonal entries of D to array E and zero out
*           corresponding entries in input storage A
*
            i = n
            e( 1 ) = zero
            DO WHILE ( i.GT.1 )
               IF( ipiv( i ).LT.0 ) THEN
                  e( i ) = a( i-1, i )
                  e( i-1 ) = zero
                  a( i-1, i ) = zero
                  i = i - 1
               ELSE
                  e( i ) = zero
               END IF
               i = i - 1
            END DO
*
*           Convert PERMUTATIONS and IPIV
*
*           Apply permutations to submatrices of upper part of A
*           in factorization order where i decreases from N to 1
*
            i = n
            DO WHILE ( i.GE.1 )
               IF( ipiv( i ).GT.0 ) THEN
*
*                 1-by-1 pivot interchange
*
*                 Swap rows i and IPIV(i) in A(1:i,N-i:N)
*
                  ip = ipiv( i )
                  IF( i.LT.n ) THEN
                     IF( ip.NE.i ) THEN
                        CALL dswap( n-i, a( i, i+1 ), lda,
     $                              a( ip, i+1 ), lda )
                     END IF
                  END IF
*
               ELSE
*
*                 2-by-2 pivot interchange
*
*                 Swap rows i-1 and IPIV(i) in A(1:i,N-i:N)
*
                  ip = -ipiv( i )
                  IF( i.LT.n ) THEN
                     IF( ip.NE.(i-1) ) THEN
                        CALL dswap( n-i, a( i-1, i+1 ), lda,
     $                              a( ip, i+1 ), lda )
                     END IF
                  END IF
*
*                 Convert IPIV
*                 There is no interchange of rows i and and IPIV(i),
*                 so this should be reflected in IPIV format for
*                 *SYTRF_RK ( or *SYTRF_BK)
*
                  ipiv( i ) = i
*
                  i = i - 1
*
               END IF
               i = i - 1
            END DO
*
         ELSE
*
*           Revert A (A is upper)
*
*
*           Revert PERMUTATIONS and IPIV
*
*           Apply permutations to submatrices of upper part of A
*           in reverse factorization order where i increases from 1 to N
*
            i = 1
            DO WHILE ( i.LE.n )
               IF( ipiv( i ).GT.0 ) THEN
*
*                 1-by-1 pivot interchange
*
*                 Swap rows i and IPIV(i) in A(1:i,N-i:N)
*
                  ip = ipiv( i )
                  IF( i.LT.n ) THEN
                     IF( ip.NE.i ) THEN
                        CALL dswap( n-i, a( ip, i+1 ), lda,
     $                              a( i, i+1 ), lda )
                     END IF
                  END IF
*
               ELSE
*
*                 2-by-2 pivot interchange
*
*                 Swap rows i-1 and IPIV(i) in A(1:i,N-i:N)
*
                  i = i + 1
                  ip = -ipiv( i )
                  IF( i.LT.n ) THEN
                     IF( ip.NE.(i-1) ) THEN
                        CALL dswap( n-i, a( ip, i+1 ), lda,
     $                              a( i-1, i+1 ), lda )
                     END IF
                  END IF
*
*                 Convert IPIV
*                 There is one interchange of rows i-1 and IPIV(i-1),
*                 so this should be recorded in two consecutive entries
*                 in IPIV format for *SYTRF
*
                  ipiv( i ) = ipiv( i-1 )
*
               END IF
               i = i + 1
            END DO
*
*           Revert VALUE
*           Assign superdiagonal entries of D from array E to
*           superdiagonal entries of A.
*
            i = n
            DO WHILE ( i.GT.1 )
               IF( ipiv( i ).LT.0 ) THEN
                  a( i-1, i ) = e( i )
                  i = i - 1
               END IF
               i = i - 1
            END DO
*
*        End A is UPPER
*
         END IF
*
      ELSE
*
*        Begin A is LOWER
*
         IF ( convert ) THEN
*
*           Convert A (A is lower)
*
*
*           Convert VALUE
*           Assign subdiagonal entries of D to array E and zero out
*           corresponding entries in input storage A
*
            i = 1
            e( n ) = zero
            DO WHILE ( i.LE.n )
               IF( i.LT.n .AND. ipiv(i).LT.0 ) THEN
                  e( i ) = a( i+1, i )
                  e( i+1 ) = zero
                  a( i+1, i ) = zero
                  i = i + 1
               ELSE
                  e( i ) = zero
               END IF
               i = i + 1
            END DO
*
*           Convert PERMUTATIONS and IPIV
*
*           Apply permutations to submatrices of lower part of A
*           in factorization order where k increases from 1 to N
*
            i = 1
            DO WHILE ( i.LE.n )
               IF( ipiv( i ).GT.0 ) THEN
*
*                 1-by-1 pivot interchange
*
*                 Swap rows i and IPIV(i) in A(i:N,1:i-1)
*
                  ip = ipiv( i )
                  IF ( i.GT.1 ) THEN
                     IF( ip.NE.i ) THEN
                        CALL dswap( i-1, a( i, 1 ), lda,
     $                              a( ip, 1 ), lda )
                     END IF
                  END IF
*
               ELSE
*
*                 2-by-2 pivot interchange
*
*                 Swap rows i+1 and IPIV(i) in A(i:N,1:i-1)
*
                  ip = -ipiv( i )
                  IF ( i.GT.1 ) THEN
                     IF( ip.NE.(i+1) ) THEN
                        CALL dswap( i-1, a( i+1, 1 ), lda,
     $                              a( ip, 1 ), lda )
                     END IF
                  END IF
*
*                 Convert IPIV
*                 There is no interchange of rows i and and IPIV(i),
*                 so this should be reflected in IPIV format for
*                 *SYTRF_RK ( or *SYTRF_BK)
*
                  ipiv( i ) = i
*
                  i = i + 1
*
               END IF
               i = i + 1
            END DO
*
         ELSE
*
*           Revert A (A is lower)
*
*
*           Revert PERMUTATIONS and IPIV
*
*           Apply permutations to submatrices of lower part of A
*           in reverse factorization order where i decreases from N to 1
*
            i = n
            DO WHILE ( i.GE.1 )
               IF( ipiv( i ).GT.0 ) THEN
*
*                 1-by-1 pivot interchange
*
*                 Swap rows i and IPIV(i) in A(i:N,1:i-1)
*
                  ip = ipiv( i )
                  IF ( i.GT.1 ) THEN
                     IF( ip.NE.i ) THEN
                        CALL dswap( i-1, a( ip, 1 ), lda,
     $                              a( i, 1 ), lda )
                     END IF
                  END IF
*
               ELSE
*
*                 2-by-2 pivot interchange
*
*                 Swap rows i+1 and IPIV(i) in A(i:N,1:i-1)
*
                  i = i - 1
                  ip = -ipiv( i )
                  IF ( i.GT.1 ) THEN
                     IF( ip.NE.(i+1) ) THEN
                        CALL dswap( i-1, a( ip, 1 ), lda,
     $                              a( i+1, 1 ), lda )
                     END IF
                  END IF
*
*                 Convert IPIV
*                 There is one interchange of rows i+1 and IPIV(i+1),
*                 so this should be recorded in consecutive entries
*                 in IPIV format for *SYTRF
*
                  ipiv( i ) = ipiv( i+1 )
*
               END IF
               i = i - 1
            END DO
*
*           Revert VALUE
*           Assign subdiagonal entries of D from array E to
*           subdiagonal entries of A.
*
            i = 1
            DO WHILE ( i.LE.n-1 )
               IF( ipiv( i ).LT.0 ) THEN
                  a( i + 1, i ) = e( i )
                  i = i + 1
               END IF
               i = i + 1
            END DO
*
         END IF
*
*        End A is LOWER
*
      END IF
 
      RETURN
*
*     End of DSYCONVF
*

Here is the call graph for this function: