LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cgges3()

subroutine cgges3 ( character  JOBVSL,
character  JOBVSR,
character  SORT,
external  SELCTG,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldb, * )  B,
integer  LDB,
integer  SDIM,
complex, dimension( * )  ALPHA,
complex, dimension( * )  BETA,
complex, dimension( ldvsl, * )  VSL,
integer  LDVSL,
complex, dimension( ldvsr, * )  VSR,
integer  LDVSR,
complex, dimension( * )  WORK,
integer  LWORK,
real, dimension( * )  RWORK,
logical, dimension( * )  BWORK,
integer  INFO 
)

CGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices (blocked algorithm)

Download CGGES3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CGGES3 computes for a pair of N-by-N complex nonsymmetric matrices
 (A,B), the generalized eigenvalues, the generalized complex Schur
 form (S, T), and optionally left and/or right Schur vectors (VSL
 and VSR). This gives the generalized Schur factorization

         (A,B) = ( (VSL)*S*(VSR)**H, (VSL)*T*(VSR)**H )

 where (VSR)**H is the conjugate-transpose of VSR.

 Optionally, it also orders the eigenvalues so that a selected cluster
 of eigenvalues appears in the leading diagonal blocks of the upper
 triangular matrix S and the upper triangular matrix T. The leading
 columns of VSL and VSR then form an unitary basis for the
 corresponding left and right eigenspaces (deflating subspaces).

 (If only the generalized eigenvalues are needed, use the driver
 CGGEV instead, which is faster.)

 A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
 or a ratio alpha/beta = w, such that  A - w*B is singular.  It is
 usually represented as the pair (alpha,beta), as there is a
 reasonable interpretation for beta=0, and even for both being zero.

 A pair of matrices (S,T) is in generalized complex Schur form if S
 and T are upper triangular and, in addition, the diagonal elements
 of T are non-negative real numbers.
Parameters
[in]JOBVSL
          JOBVSL is CHARACTER*1
          = 'N':  do not compute the left Schur vectors;
          = 'V':  compute the left Schur vectors.
[in]JOBVSR
          JOBVSR is CHARACTER*1
          = 'N':  do not compute the right Schur vectors;
          = 'V':  compute the right Schur vectors.
[in]SORT
          SORT is CHARACTER*1
          Specifies whether or not to order the eigenvalues on the
          diagonal of the generalized Schur form.
          = 'N':  Eigenvalues are not ordered;
          = 'S':  Eigenvalues are ordered (see SELCTG).
[in]SELCTG
          SELCTG is a LOGICAL FUNCTION of two COMPLEX arguments
          SELCTG must be declared EXTERNAL in the calling subroutine.
          If SORT = 'N', SELCTG is not referenced.
          If SORT = 'S', SELCTG is used to select eigenvalues to sort
          to the top left of the Schur form.
          An eigenvalue ALPHA(j)/BETA(j) is selected if
          SELCTG(ALPHA(j),BETA(j)) is true.

          Note that a selected complex eigenvalue may no longer satisfy
          SELCTG(ALPHA(j),BETA(j)) = .TRUE. after ordering, since
          ordering may change the value of complex eigenvalues
          (especially if the eigenvalue is ill-conditioned), in this
          case INFO is set to N+2 (See INFO below).
[in]N
          N is INTEGER
          The order of the matrices A, B, VSL, and VSR.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA, N)
          On entry, the first of the pair of matrices.
          On exit, A has been overwritten by its generalized Schur
          form S.
[in]LDA
          LDA is INTEGER
          The leading dimension of A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX array, dimension (LDB, N)
          On entry, the second of the pair of matrices.
          On exit, B has been overwritten by its generalized Schur
          form T.
[in]LDB
          LDB is INTEGER
          The leading dimension of B.  LDB >= max(1,N).
[out]SDIM
          SDIM is INTEGER
          If SORT = 'N', SDIM = 0.
          If SORT = 'S', SDIM = number of eigenvalues (after sorting)
          for which SELCTG is true.
[out]ALPHA
          ALPHA is COMPLEX array, dimension (N)
[out]BETA
          BETA is COMPLEX array, dimension (N)
          On exit,  ALPHA(j)/BETA(j), j=1,...,N, will be the
          generalized eigenvalues.  ALPHA(j), j=1,...,N  and  BETA(j),
          j=1,...,N  are the diagonals of the complex Schur form (A,B)
          output by CGGES3. The  BETA(j) will be non-negative real.

          Note: the quotients ALPHA(j)/BETA(j) may easily over- or
          underflow, and BETA(j) may even be zero.  Thus, the user
          should avoid naively computing the ratio alpha/beta.
          However, ALPHA will be always less than and usually
          comparable with norm(A) in magnitude, and BETA always less
          than and usually comparable with norm(B).
[out]VSL
          VSL is COMPLEX array, dimension (LDVSL,N)
          If JOBVSL = 'V', VSL will contain the left Schur vectors.
          Not referenced if JOBVSL = 'N'.
[in]LDVSL
          LDVSL is INTEGER
          The leading dimension of the matrix VSL. LDVSL >= 1, and
          if JOBVSL = 'V', LDVSL >= N.
[out]VSR
          VSR is COMPLEX array, dimension (LDVSR,N)
          If JOBVSR = 'V', VSR will contain the right Schur vectors.
          Not referenced if JOBVSR = 'N'.
[in]LDVSR
          LDVSR is INTEGER
          The leading dimension of the matrix VSR. LDVSR >= 1, and
          if JOBVSR = 'V', LDVSR >= N.
[out]WORK
          WORK is COMPLEX array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]RWORK
          RWORK is REAL array, dimension (8*N)
[out]BWORK
          BWORK is LOGICAL array, dimension (N)
          Not referenced if SORT = 'N'.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value.
          =1,...,N:
                The QZ iteration failed.  (A,B) are not in Schur
                form, but ALPHA(j) and BETA(j) should be correct for
                j=INFO+1,...,N.
          > N:  =N+1: other than QZ iteration failed in CHGEQZ
                =N+2: after reordering, roundoff changed values of
                      some complex eigenvalues so that leading
                      eigenvalues in the Generalized Schur form no
                      longer satisfy SELCTG=.TRUE.  This could also
                      be caused due to scaling.
                =N+3: reordering failed in CTGSEN.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
January 2015

Definition at line 271 of file cgges3.f.

271 *
272 * -- LAPACK driver routine (version 3.6.1) --
273 * -- LAPACK is a software package provided by Univ. of Tennessee, --
274 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
275 * January 2015
276 *
277 * .. Scalar Arguments ..
278  CHARACTER jobvsl, jobvsr, sort
279  INTEGER info, lda, ldb, ldvsl, ldvsr, lwork, n, sdim
280 * ..
281 * .. Array Arguments ..
282  LOGICAL bwork( * )
283  REAL rwork( * )
284  COMPLEX a( lda, * ), alpha( * ), b( ldb, * ),
285  $ beta( * ), vsl( ldvsl, * ), vsr( ldvsr, * ),
286  $ work( * )
287 * ..
288 * .. Function Arguments ..
289  LOGICAL selctg
290  EXTERNAL selctg
291 * ..
292 *
293 * =====================================================================
294 *
295 * .. Parameters ..
296  REAL zero, one
297  parameter( zero = 0.0e0, one = 1.0e0 )
298  COMPLEX czero, cone
299  parameter( czero = ( 0.0e0, 0.0e0 ),
300  $ cone = ( 1.0e0, 0.0e0 ) )
301 * ..
302 * .. Local Scalars ..
303  LOGICAL cursl, ilascl, ilbscl, ilvsl, ilvsr, lastsl,
304  $ lquery, wantst
305  INTEGER i, icols, ierr, ihi, ijobvl, ijobvr, ileft,
306  $ ilo, iright, irows, irwrk, itau, iwrk, lwkopt
307  REAL anrm, anrmto, bignum, bnrm, bnrmto, eps, pvsl,
308  $ pvsr, smlnum
309 * ..
310 * .. Local Arrays ..
311  INTEGER idum( 1 )
312  REAL dif( 2 )
313 * ..
314 * .. External Subroutines ..
315  EXTERNAL cgeqrf, cggbak, cggbal, cgghd3, chgeqz, clacpy,
317  $ xerbla
318 * ..
319 * .. External Functions ..
320  LOGICAL lsame
321  REAL clange, slamch
322  EXTERNAL lsame, clange, slamch
323 * ..
324 * .. Intrinsic Functions ..
325  INTRINSIC max, sqrt
326 * ..
327 * .. Executable Statements ..
328 *
329 * Decode the input arguments
330 *
331  IF( lsame( jobvsl, 'N' ) ) THEN
332  ijobvl = 1
333  ilvsl = .false.
334  ELSE IF( lsame( jobvsl, 'V' ) ) THEN
335  ijobvl = 2
336  ilvsl = .true.
337  ELSE
338  ijobvl = -1
339  ilvsl = .false.
340  END IF
341 *
342  IF( lsame( jobvsr, 'N' ) ) THEN
343  ijobvr = 1
344  ilvsr = .false.
345  ELSE IF( lsame( jobvsr, 'V' ) ) THEN
346  ijobvr = 2
347  ilvsr = .true.
348  ELSE
349  ijobvr = -1
350  ilvsr = .false.
351  END IF
352 *
353  wantst = lsame( sort, 'S' )
354 *
355 * Test the input arguments
356 *
357  info = 0
358  lquery = ( lwork.EQ.-1 )
359  IF( ijobvl.LE.0 ) THEN
360  info = -1
361  ELSE IF( ijobvr.LE.0 ) THEN
362  info = -2
363  ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
364  info = -3
365  ELSE IF( n.LT.0 ) THEN
366  info = -5
367  ELSE IF( lda.LT.max( 1, n ) ) THEN
368  info = -7
369  ELSE IF( ldb.LT.max( 1, n ) ) THEN
370  info = -9
371  ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
372  info = -14
373  ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
374  info = -16
375  ELSE IF( lwork.LT.max( 1, 2*n ) .AND. .NOT.lquery ) THEN
376  info = -18
377  END IF
378 *
379 * Compute workspace
380 *
381  IF( info.EQ.0 ) THEN
382  CALL cgeqrf( n, n, b, ldb, work, work, -1, ierr )
383  lwkopt = max( 1, n + int( work( 1 ) ) )
384  CALL cunmqr( 'L', 'C', n, n, n, b, ldb, work, a, lda, work,
385  $ -1, ierr )
386  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
387  IF( ilvsl ) THEN
388  CALL cungqr( n, n, n, vsl, ldvsl, work, work, -1,
389  $ ierr )
390  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
391  END IF
392  CALL cgghd3( jobvsl, jobvsr, n, 1, n, a, lda, b, ldb, vsl,
393  $ ldvsl, vsr, ldvsr, work, -1, ierr )
394  lwkopt = max( lwkopt, n + int( work( 1 ) ) )
395  CALL chgeqz( 'S', jobvsl, jobvsr, n, 1, n, a, lda, b, ldb,
396  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, work, -1,
397  $ rwork, ierr )
398  lwkopt = max( lwkopt, int( work( 1 ) ) )
399  IF( wantst ) THEN
400  CALL ctgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
401  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, sdim,
402  $ pvsl, pvsr, dif, work, -1, idum, 1, ierr )
403  lwkopt = max( lwkopt, int( work( 1 ) ) )
404  END IF
405  work( 1 ) = cmplx( lwkopt )
406  END IF
407 
408 *
409  IF( info.NE.0 ) THEN
410  CALL xerbla( 'CGGES3 ', -info )
411  RETURN
412  ELSE IF( lquery ) THEN
413  RETURN
414  END IF
415 *
416 * Quick return if possible
417 *
418  IF( n.EQ.0 ) THEN
419  sdim = 0
420  RETURN
421  END IF
422 *
423 * Get machine constants
424 *
425  eps = slamch( 'P' )
426  smlnum = slamch( 'S' )
427  bignum = one / smlnum
428  CALL slabad( smlnum, bignum )
429  smlnum = sqrt( smlnum ) / eps
430  bignum = one / smlnum
431 *
432 * Scale A if max element outside range [SMLNUM,BIGNUM]
433 *
434  anrm = clange( 'M', n, n, a, lda, rwork )
435  ilascl = .false.
436  IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
437  anrmto = smlnum
438  ilascl = .true.
439  ELSE IF( anrm.GT.bignum ) THEN
440  anrmto = bignum
441  ilascl = .true.
442  END IF
443 *
444  IF( ilascl )
445  $ CALL clascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
446 *
447 * Scale B if max element outside range [SMLNUM,BIGNUM]
448 *
449  bnrm = clange( 'M', n, n, b, ldb, rwork )
450  ilbscl = .false.
451  IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
452  bnrmto = smlnum
453  ilbscl = .true.
454  ELSE IF( bnrm.GT.bignum ) THEN
455  bnrmto = bignum
456  ilbscl = .true.
457  END IF
458 *
459  IF( ilbscl )
460  $ CALL clascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
461 *
462 * Permute the matrix to make it more nearly triangular
463 *
464  ileft = 1
465  iright = n + 1
466  irwrk = iright + n
467  CALL cggbal( 'P', n, a, lda, b, ldb, ilo, ihi, rwork( ileft ),
468  $ rwork( iright ), rwork( irwrk ), ierr )
469 *
470 * Reduce B to triangular form (QR decomposition of B)
471 *
472  irows = ihi + 1 - ilo
473  icols = n + 1 - ilo
474  itau = 1
475  iwrk = itau + irows
476  CALL cgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
477  $ work( iwrk ), lwork+1-iwrk, ierr )
478 *
479 * Apply the orthogonal transformation to matrix A
480 *
481  CALL cunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
482  $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
483  $ lwork+1-iwrk, ierr )
484 *
485 * Initialize VSL
486 *
487  IF( ilvsl ) THEN
488  CALL claset( 'Full', n, n, czero, cone, vsl, ldvsl )
489  IF( irows.GT.1 ) THEN
490  CALL clacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
491  $ vsl( ilo+1, ilo ), ldvsl )
492  END IF
493  CALL cungqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
494  $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
495  END IF
496 *
497 * Initialize VSR
498 *
499  IF( ilvsr )
500  $ CALL claset( 'Full', n, n, czero, cone, vsr, ldvsr )
501 *
502 * Reduce to generalized Hessenberg form
503 *
504  CALL cgghd3( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
505  $ ldvsl, vsr, ldvsr, work( iwrk ), lwork+1-iwrk, ierr )
506 *
507  sdim = 0
508 *
509 * Perform QZ algorithm, computing Schur vectors if desired
510 *
511  iwrk = itau
512  CALL chgeqz( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
513  $ alpha, beta, vsl, ldvsl, vsr, ldvsr, work( iwrk ),
514  $ lwork+1-iwrk, rwork( irwrk ), ierr )
515  IF( ierr.NE.0 ) THEN
516  IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
517  info = ierr
518  ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
519  info = ierr - n
520  ELSE
521  info = n + 1
522  END IF
523  GO TO 30
524  END IF
525 *
526 * Sort eigenvalues ALPHA/BETA if desired
527 *
528  IF( wantst ) THEN
529 *
530 * Undo scaling on eigenvalues before selecting
531 *
532  IF( ilascl )
533  $ CALL clascl( 'G', 0, 0, anrm, anrmto, n, 1, alpha, n, ierr )
534  IF( ilbscl )
535  $ CALL clascl( 'G', 0, 0, bnrm, bnrmto, n, 1, beta, n, ierr )
536 *
537 * Select eigenvalues
538 *
539  DO 10 i = 1, n
540  bwork( i ) = selctg( alpha( i ), beta( i ) )
541  10 CONTINUE
542 *
543  CALL ctgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alpha,
544  $ beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl, pvsr,
545  $ dif, work( iwrk ), lwork-iwrk+1, idum, 1, ierr )
546  IF( ierr.EQ.1 )
547  $ info = n + 3
548 *
549  END IF
550 *
551 * Apply back-permutation to VSL and VSR
552 *
553  IF( ilvsl )
554  $ CALL cggbak( 'P', 'L', n, ilo, ihi, rwork( ileft ),
555  $ rwork( iright ), n, vsl, ldvsl, ierr )
556  IF( ilvsr )
557  $ CALL cggbak( 'P', 'R', n, ilo, ihi, rwork( ileft ),
558  $ rwork( iright ), n, vsr, ldvsr, ierr )
559 *
560 * Undo scaling
561 *
562  IF( ilascl ) THEN
563  CALL clascl( 'U', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
564  CALL clascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
565  END IF
566 *
567  IF( ilbscl ) THEN
568  CALL clascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
569  CALL clascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
570  END IF
571 *
572  IF( wantst ) THEN
573 *
574 * Check if reordering is correct
575 *
576  lastsl = .true.
577  sdim = 0
578  DO 20 i = 1, n
579  cursl = selctg( alpha( i ), beta( i ) )
580  IF( cursl )
581  $ sdim = sdim + 1
582  IF( cursl .AND. .NOT.lastsl )
583  $ info = n + 2
584  lastsl = cursl
585  20 CONTINUE
586 *
587  END IF
588 *
589  30 CONTINUE
590 *
591  work( 1 ) = cmplx( lwkopt )
592 *
593  RETURN
594 *
595 * End of CGGES3
596 *
subroutine cggbal(JOB, N, A, LDA, B, LDB, ILO, IHI, LSCALE, RSCALE, WORK, INFO)
CGGBAL
Definition: cggbal.f:179
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: claset.f:108
subroutine cungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGQR
Definition: cungqr.f:130
subroutine cgghd3(COMPQ, COMPZ, N, ILO, IHI, A, LDA, B, LDB, Q, LDQ, Z, LDZ, WORK, LWORK, INFO)
CGGHD3
Definition: cgghd3.f:233
subroutine clascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
CLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: clascl.f:145
subroutine chgeqz(JOB, COMPQ, COMPZ, N, ILO, IHI, H, LDH, T, LDT, ALPHA, BETA, Q, LDQ, Z, LDZ, WORK, LWORK, RWORK, INFO)
CHGEQZ
Definition: chgeqz.f:286
real function clange(NORM, M, N, A, LDA, WORK)
CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clange.f:117
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine cgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
CGEQRF
Definition: cgeqrf.f:138
subroutine ctgsen(IJOB, WANTQ, WANTZ, SELECT, N, A, LDA, B, LDB, ALPHA, BETA, Q, LDQ, Z, LDZ, M, PL, PR, DIF, WORK, LWORK, IWORK, LIWORK, INFO)
CTGSEN
Definition: ctgsen.f:435
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:105
subroutine slabad(SMALL, LARGE)
SLABAD
Definition: slabad.f:76
subroutine cggbak(JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V, LDV, INFO)
CGGBAK
Definition: cggbak.f:150
subroutine cunmqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
CUNMQR
Definition: cunmqr.f:170
Here is the call graph for this function:
Here is the caller graph for this function: