 LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

◆ cgecon()

 subroutine cgecon ( character NORM, integer N, complex, dimension( lda, * ) A, integer LDA, real ANORM, real RCOND, complex, dimension( * ) WORK, real, dimension( * ) RWORK, integer INFO )

CGECON

Purpose:
CGECON estimates the reciprocal of the condition number of a general
complex matrix A, in either the 1-norm or the infinity-norm, using
the LU factorization computed by CGETRF.

An estimate is obtained for norm(inv(A)), and the reciprocal of the
condition number is computed as
RCOND = 1 / ( norm(A) * norm(inv(A)) ).
Parameters
 [in] NORM NORM is CHARACTER*1 Specifies whether the 1-norm condition number or the infinity-norm condition number is required: = '1' or 'O': 1-norm; = 'I': Infinity-norm. [in] N N is INTEGER The order of the matrix A. N >= 0. [in] A A is COMPLEX array, dimension (LDA,N) The factors L and U from the factorization A = P*L*U as computed by CGETRF. [in] LDA LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N). [in] ANORM ANORM is REAL If NORM = '1' or 'O', the 1-norm of the original matrix A. If NORM = 'I', the infinity-norm of the original matrix A. [out] RCOND RCOND is REAL The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(norm(A) * norm(inv(A))). [out] WORK WORK is COMPLEX array, dimension (2*N) [out] RWORK RWORK is REAL array, dimension (2*N) [out] INFO INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Definition at line 122 of file cgecon.f.

124 *
125 * -- LAPACK computational routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129 * .. Scalar Arguments ..
130  CHARACTER NORM
131  INTEGER INFO, LDA, N
132  REAL ANORM, RCOND
133 * ..
134 * .. Array Arguments ..
135  REAL RWORK( * )
136  COMPLEX A( LDA, * ), WORK( * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  REAL ONE, ZERO
143  parameter( one = 1.0e+0, zero = 0.0e+0 )
144 * ..
145 * .. Local Scalars ..
146  LOGICAL ONENRM
147  CHARACTER NORMIN
148  INTEGER IX, KASE, KASE1
149  REAL AINVNM, SCALE, SL, SMLNUM, SU
150  COMPLEX ZDUM
151 * ..
152 * .. Local Arrays ..
153  INTEGER ISAVE( 3 )
154 * ..
155 * .. External Functions ..
156  LOGICAL LSAME
157  INTEGER ICAMAX
158  REAL SLAMCH
159  EXTERNAL lsame, icamax, slamch
160 * ..
161 * .. External Subroutines ..
162  EXTERNAL clacn2, clatrs, csrscl, xerbla
163 * ..
164 * .. Intrinsic Functions ..
165  INTRINSIC abs, aimag, max, real
166 * ..
167 * .. Statement Functions ..
168  REAL CABS1
169 * ..
170 * .. Statement Function definitions ..
171  cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
172 * ..
173 * .. Executable Statements ..
174 *
175 * Test the input parameters.
176 *
177  info = 0
178  onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
179  IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
180  info = -1
181  ELSE IF( n.LT.0 ) THEN
182  info = -2
183  ELSE IF( lda.LT.max( 1, n ) ) THEN
184  info = -4
185  ELSE IF( anorm.LT.zero ) THEN
186  info = -5
187  END IF
188  IF( info.NE.0 ) THEN
189  CALL xerbla( 'CGECON', -info )
190  RETURN
191  END IF
192 *
193 * Quick return if possible
194 *
195  rcond = zero
196  IF( n.EQ.0 ) THEN
197  rcond = one
198  RETURN
199  ELSE IF( anorm.EQ.zero ) THEN
200  RETURN
201  END IF
202 *
203  smlnum = slamch( 'Safe minimum' )
204 *
205 * Estimate the norm of inv(A).
206 *
207  ainvnm = zero
208  normin = 'N'
209  IF( onenrm ) THEN
210  kase1 = 1
211  ELSE
212  kase1 = 2
213  END IF
214  kase = 0
215  10 CONTINUE
216  CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
217  IF( kase.NE.0 ) THEN
218  IF( kase.EQ.kase1 ) THEN
219 *
220 * Multiply by inv(L).
221 *
222  CALL clatrs( 'Lower', 'No transpose', 'Unit', normin, n, a,
223  \$ lda, work, sl, rwork, info )
224 *
225 * Multiply by inv(U).
226 *
227  CALL clatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
228  \$ a, lda, work, su, rwork( n+1 ), info )
229  ELSE
230 *
231 * Multiply by inv(U**H).
232 *
233  CALL clatrs( 'Upper', 'Conjugate transpose', 'Non-unit',
234  \$ normin, n, a, lda, work, su, rwork( n+1 ),
235  \$ info )
236 *
237 * Multiply by inv(L**H).
238 *
239  CALL clatrs( 'Lower', 'Conjugate transpose', 'Unit', normin,
240  \$ n, a, lda, work, sl, rwork, info )
241  END IF
242 *
243 * Divide X by 1/(SL*SU) if doing so will not cause overflow.
244 *
245  scale = sl*su
246  normin = 'Y'
247  IF( scale.NE.one ) THEN
248  ix = icamax( n, work, 1 )
249  IF( scale.LT.cabs1( work( ix ) )*smlnum .OR. scale.EQ.zero )
250  \$ GO TO 20
251  CALL csrscl( n, scale, work, 1 )
252  END IF
253  GO TO 10
254  END IF
255 *
256 * Compute the estimate of the reciprocal condition number.
257 *
258  IF( ainvnm.NE.zero )
259  \$ rcond = ( one / ainvnm ) / anorm
260 *
261  20 CONTINUE
262  RETURN
263 *
264 * End of CGECON
265 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
integer function icamax(N, CX, INCX)
ICAMAX
Definition: icamax.f:71
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine clatrs(UPLO, TRANS, DIAG, NORMIN, N, A, LDA, X, SCALE, CNORM, INFO)
CLATRS solves a triangular system of equations with the scale factor set to prevent overflow.
Definition: clatrs.f:239
subroutine csrscl(N, SA, SX, INCX)
CSRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: csrscl.f:84
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:133
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: