LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cla_gerfsx_extended()

subroutine cla_gerfsx_extended ( integer  PREC_TYPE,
integer  TRANS_TYPE,
integer  N,
integer  NRHS,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
logical  COLEQU,
real, dimension( * )  C,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldy, * )  Y,
integer  LDY,
real, dimension( * )  BERR_OUT,
integer  N_NORMS,
real, dimension( nrhs, * )  ERRS_N,
real, dimension( nrhs, * )  ERRS_C,
complex, dimension( * )  RES,
real, dimension( * )  AYB,
complex, dimension( * )  DY,
complex, dimension( * )  Y_TAIL,
real  RCOND,
integer  ITHRESH,
real  RTHRESH,
real  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

CLA_GERFSX_EXTENDED

Download CLA_GERFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLA_GERFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by CGERFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERRS_N
 and ERRS_C for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERRS_N and ERRS_C.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and
     P    = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X', 'E':  Extra
[in]TRANS_TYPE
          TRANS_TYPE is INTEGER
     Specifies the transposition operation on A.
     The value is defined by ILATRANS(T) where T is a CHARACTER and
     T    = 'N':  No transpose
          = 'T':  Transpose
          = 'C':  Conjugate transpose
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]A
          A is COMPLEX array, dimension (LDA,N)
     On entry, the N-by-N matrix A.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is COMPLEX array, dimension (LDAF,N)
     The factors L and U from the factorization
     A = P*L*U as computed by CGETRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     The pivot indices from the factorization A = P*L*U
     as computed by CGETRF; row i of the matrix was interchanged
     with row IPIV(i).
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is REAL array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is COMPLEX array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is COMPLEX array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by CGETRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is REAL array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by CLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERRS_N
     and ERRS_C).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERRS_N
          ERRS_N is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERRS_N(i,:) corresponds to the ith
     right-hand side.

     The second index in ERRS_N(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERRS_C
          ERRS_C is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERRS_C is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERRS_C(i,:) corresponds to the ith
     right-hand side.

     The second index in ERRS_C(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is COMPLEX array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is REAL array, dimension (N)
     Workspace.
[in]DY
          DY is COMPLEX array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is COMPLEX array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is REAL
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERRS_N and ERRS_C may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is REAL
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is REAL
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we definte as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to CGETRS had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 399 of file cla_gerfsx_extended.f.

399 *
400 * -- LAPACK computational routine (version 3.7.0) --
401 * -- LAPACK is a software package provided by Univ. of Tennessee, --
402 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
403 * December 2016
404 *
405 * .. Scalar Arguments ..
406  INTEGER info, lda, ldaf, ldb, ldy, n, nrhs, prec_type,
407  $ trans_type, n_norms
408  LOGICAL colequ, ignore_cwise
409  INTEGER ithresh
410  REAL rthresh, dz_ub
411 * ..
412 * .. Array Arguments
413  INTEGER ipiv( * )
414  COMPLEX a( lda, * ), af( ldaf, * ), b( ldb, * ),
415  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
416  REAL c( * ), ayb( * ), rcond, berr_out( * ),
417  $ errs_n( nrhs, * ), errs_c( nrhs, * )
418 * ..
419 *
420 * =====================================================================
421 *
422 * .. Local Scalars ..
423  CHARACTER trans
424  INTEGER cnt, i, j, x_state, z_state, y_prec_state
425  REAL yk, dyk, ymin, normy, normx, normdx, dxrat,
426  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
427  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
428  $ eps, hugeval, incr_thresh
429  LOGICAL incr_prec
430  COMPLEX zdum
431 * ..
432 * .. Parameters ..
433  INTEGER unstable_state, working_state, conv_state,
434  $ noprog_state, base_residual, extra_residual,
435  $ extra_y
436  parameter( unstable_state = 0, working_state = 1,
437  $ conv_state = 2,
438  $ noprog_state = 3 )
439  parameter( base_residual = 0, extra_residual = 1,
440  $ extra_y = 2 )
441  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
442  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
443  INTEGER cmp_err_i, piv_growth_i
444  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
445  $ berr_i = 3 )
446  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
447  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
448  $ piv_growth_i = 9 )
449  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
450  $ la_linrx_cwise_i
451  parameter( la_linrx_itref_i = 1,
452  $ la_linrx_ithresh_i = 2 )
453  parameter( la_linrx_cwise_i = 3 )
454  INTEGER la_linrx_trust_i, la_linrx_err_i,
455  $ la_linrx_rcond_i
456  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
457  parameter( la_linrx_rcond_i = 3 )
458 * ..
459 * .. External Subroutines ..
460  EXTERNAL caxpy, ccopy, cgetrs, cgemv, blas_cgemv_x,
461  $ blas_cgemv2_x, cla_geamv, cla_wwaddw, slamch,
463  REAL slamch
464  CHARACTER chla_transtype
465 * ..
466 * .. Intrinsic Functions ..
467  INTRINSIC abs, max, min
468 * ..
469 * .. Statement Functions ..
470  REAL cabs1
471 * ..
472 * .. Statement Function Definitions ..
473  cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( aimag( zdum ) )
474 * ..
475 * .. Executable Statements ..
476 *
477  IF ( info.NE.0 ) RETURN
478  trans = chla_transtype(trans_type)
479  eps = slamch( 'Epsilon' )
480  hugeval = slamch( 'Overflow' )
481 * Force HUGEVAL to Inf
482  hugeval = hugeval * hugeval
483 * Using HUGEVAL may lead to spurious underflows.
484  incr_thresh = REAL( N ) * eps
485 *
486  DO j = 1, nrhs
487  y_prec_state = extra_residual
488  IF ( y_prec_state .EQ. extra_y ) THEN
489  DO i = 1, n
490  y_tail( i ) = 0.0
491  END DO
492  END IF
493 
494  dxrat = 0.0
495  dxratmax = 0.0
496  dzrat = 0.0
497  dzratmax = 0.0
498  final_dx_x = hugeval
499  final_dz_z = hugeval
500  prevnormdx = hugeval
501  prev_dz_z = hugeval
502  dz_z = hugeval
503  dx_x = hugeval
504 
505  x_state = working_state
506  z_state = unstable_state
507  incr_prec = .false.
508 
509  DO cnt = 1, ithresh
510 *
511 * Compute residual RES = B_s - op(A_s) * Y,
512 * op(A) = A, A**T, or A**H depending on TRANS (and type).
513 *
514  CALL ccopy( n, b( 1, j ), 1, res, 1 )
515  IF ( y_prec_state .EQ. base_residual ) THEN
516  CALL cgemv( trans, n, n, (-1.0e+0,0.0e+0), a, lda,
517  $ y( 1, j ), 1, (1.0e+0,0.0e+0), res, 1)
518  ELSE IF (y_prec_state .EQ. extra_residual) THEN
519  CALL blas_cgemv_x( trans_type, n, n, (-1.0e+0,0.0e+0), a,
520  $ lda, y( 1, j ), 1, (1.0e+0,0.0e+0),
521  $ res, 1, prec_type )
522  ELSE
523  CALL blas_cgemv2_x( trans_type, n, n, (-1.0e+0,0.0e+0),
524  $ a, lda, y(1, j), y_tail, 1, (1.0e+0,0.0e+0), res, 1,
525  $ prec_type)
526  END IF
527 
528 ! XXX: RES is no longer needed.
529  CALL ccopy( n, res, 1, dy, 1 )
530  CALL cgetrs( trans, n, 1, af, ldaf, ipiv, dy, n, info )
531 *
532 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
533 *
534  normx = 0.0e+0
535  normy = 0.0e+0
536  normdx = 0.0e+0
537  dz_z = 0.0e+0
538  ymin = hugeval
539 *
540  DO i = 1, n
541  yk = cabs1( y( i, j ) )
542  dyk = cabs1( dy( i ) )
543 
544  IF ( yk .NE. 0.0e+0 ) THEN
545  dz_z = max( dz_z, dyk / yk )
546  ELSE IF ( dyk .NE. 0.0 ) THEN
547  dz_z = hugeval
548  END IF
549 
550  ymin = min( ymin, yk )
551 
552  normy = max( normy, yk )
553 
554  IF ( colequ ) THEN
555  normx = max( normx, yk * c( i ) )
556  normdx = max( normdx, dyk * c( i ) )
557  ELSE
558  normx = normy
559  normdx = max(normdx, dyk)
560  END IF
561  END DO
562 
563  IF ( normx .NE. 0.0 ) THEN
564  dx_x = normdx / normx
565  ELSE IF ( normdx .EQ. 0.0 ) THEN
566  dx_x = 0.0
567  ELSE
568  dx_x = hugeval
569  END IF
570 
571  dxrat = normdx / prevnormdx
572  dzrat = dz_z / prev_dz_z
573 *
574 * Check termination criteria
575 *
576  IF (.NOT.ignore_cwise
577  $ .AND. ymin*rcond .LT. incr_thresh*normy
578  $ .AND. y_prec_state .LT. extra_y )
579  $ incr_prec = .true.
580 
581  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
582  $ x_state = working_state
583  IF ( x_state .EQ. working_state ) THEN
584  IF (dx_x .LE. eps) THEN
585  x_state = conv_state
586  ELSE IF ( dxrat .GT. rthresh ) THEN
587  IF ( y_prec_state .NE. extra_y ) THEN
588  incr_prec = .true.
589  ELSE
590  x_state = noprog_state
591  END IF
592  ELSE
593  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
594  END IF
595  IF ( x_state .GT. working_state ) final_dx_x = dx_x
596  END IF
597 
598  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
599  $ z_state = working_state
600  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
601  $ z_state = working_state
602  IF ( z_state .EQ. working_state ) THEN
603  IF ( dz_z .LE. eps ) THEN
604  z_state = conv_state
605  ELSE IF ( dz_z .GT. dz_ub ) THEN
606  z_state = unstable_state
607  dzratmax = 0.0
608  final_dz_z = hugeval
609  ELSE IF ( dzrat .GT. rthresh ) THEN
610  IF ( y_prec_state .NE. extra_y ) THEN
611  incr_prec = .true.
612  ELSE
613  z_state = noprog_state
614  END IF
615  ELSE
616  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
617  END IF
618  IF ( z_state .GT. working_state ) final_dz_z = dz_z
619  END IF
620 *
621 * Exit if both normwise and componentwise stopped working,
622 * but if componentwise is unstable, let it go at least two
623 * iterations.
624 *
625  IF ( x_state.NE.working_state ) THEN
626  IF ( ignore_cwise ) GOTO 666
627  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
628  $ GOTO 666
629  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
630  END IF
631 
632  IF ( incr_prec ) THEN
633  incr_prec = .false.
634  y_prec_state = y_prec_state + 1
635  DO i = 1, n
636  y_tail( i ) = 0.0
637  END DO
638  END IF
639 
640  prevnormdx = normdx
641  prev_dz_z = dz_z
642 *
643 * Update soluton.
644 *
645  IF ( y_prec_state .LT. extra_y ) THEN
646  CALL caxpy( n, (1.0e+0,0.0e+0), dy, 1, y(1,j), 1 )
647  ELSE
648  CALL cla_wwaddw( n, y( 1, j ), y_tail, dy )
649  END IF
650 
651  END DO
652 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
653  666 CONTINUE
654 *
655 * Set final_* when cnt hits ithresh
656 *
657  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
658  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
659 *
660 * Compute error bounds
661 *
662  IF (n_norms .GE. 1) THEN
663  errs_n( j, la_linrx_err_i ) = final_dx_x / (1 - dxratmax)
664 
665  END IF
666  IF ( n_norms .GE. 2 ) THEN
667  errs_c( j, la_linrx_err_i ) = final_dz_z / (1 - dzratmax)
668  END IF
669 *
670 * Compute componentwise relative backward error from formula
671 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
672 * where abs(Z) is the componentwise absolute value of the matrix
673 * or vector Z.
674 *
675 * Compute residual RES = B_s - op(A_s) * Y,
676 * op(A) = A, A**T, or A**H depending on TRANS (and type).
677 *
678  CALL ccopy( n, b( 1, j ), 1, res, 1 )
679  CALL cgemv( trans, n, n, (-1.0e+0,0.0e+0), a, lda, y(1,j), 1,
680  $ (1.0e+0,0.0e+0), res, 1 )
681 
682  DO i = 1, n
683  ayb( i ) = cabs1( b( i, j ) )
684  END DO
685 *
686 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
687 *
688  CALL cla_geamv ( trans_type, n, n, 1.0e+0,
689  $ a, lda, y(1, j), 1, 1.0e+0, ayb, 1 )
690 
691  CALL cla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
692 *
693 * End of loop for each RHS.
694 *
695  END DO
696 *
697  RETURN
subroutine cla_wwaddw(N, X, Y, W)
CLA_WWADDW adds a vector into a doubled-single vector.
Definition: cla_wwaddw.f:83
subroutine cgetrs(TRANS, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
CGETRS
Definition: cgetrs.f:123
subroutine cgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGEMV
Definition: cgemv.f:160
subroutine cla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
CLA_LIN_BERR computes a component-wise relative backward error.
Definition: cla_lin_berr.f:103
subroutine cla_geamv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CLA_GEAMV computes a matrix-vector product using a general matrix to calculate error bounds...
Definition: cla_geamv.f:177
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:83
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:90
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
Here is the call graph for this function:
Here is the caller graph for this function: