LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cgebd2()

subroutine cgebd2 ( integer  M,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  D,
real, dimension( * )  E,
complex, dimension( * )  TAUQ,
complex, dimension( * )  TAUP,
complex, dimension( * )  WORK,
integer  INFO 
)

CGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download CGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CGEBD2 reduces a complex general m by n matrix A to upper or lower
 real bidiagonal form B by a unitary transformation: Q**H * A * P = B.

 If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
Parameters
[in]M
          M is INTEGER
          The number of rows in the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns in the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the m by n general matrix to be reduced.
          On exit,
          if m >= n, the diagonal and the first superdiagonal are
            overwritten with the upper bidiagonal matrix B; the
            elements below the diagonal, with the array TAUQ, represent
            the unitary matrix Q as a product of elementary
            reflectors, and the elements above the first superdiagonal,
            with the array TAUP, represent the unitary matrix P as
            a product of elementary reflectors;
          if m < n, the diagonal and the first subdiagonal are
            overwritten with the lower bidiagonal matrix B; the
            elements below the first subdiagonal, with the array TAUQ,
            represent the unitary matrix Q as a product of
            elementary reflectors, and the elements above the diagonal,
            with the array TAUP, represent the unitary matrix P as
            a product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]D
          D is REAL array, dimension (min(M,N))
          The diagonal elements of the bidiagonal matrix B:
          D(i) = A(i,i).
[out]E
          E is REAL array, dimension (min(M,N)-1)
          The off-diagonal elements of the bidiagonal matrix B:
          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
[out]TAUQ
          TAUQ is COMPLEX array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the unitary matrix Q. See Further Details.
[out]TAUP
          TAUP is COMPLEX array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the unitary matrix P. See Further Details.
[out]WORK
          WORK is COMPLEX array, dimension (max(M,N))
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017
Further Details:
  The matrices Q and P are represented as products of elementary
  reflectors:

  If m >= n,

     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H

  where tauq and taup are complex scalars, and v and u are complex
  vectors; v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
  A(i+1:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
  A(i,i+2:n); tauq is stored in TAUQ(i) and taup in TAUP(i).

  If m < n,

     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H

  where tauq and taup are complex scalars, v and u are complex vectors;
  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  The contents of A on exit are illustrated by the following examples:

  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):

    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
    (  v1  v2  v3  v4  v5 )

  where d and e denote diagonal and off-diagonal elements of B, vi
  denotes an element of the vector defining H(i), and ui an element of
  the vector defining G(i).

Definition at line 192 of file cgebd2.f.

192 *
193 * -- LAPACK computational routine (version 3.7.1) --
194 * -- LAPACK is a software package provided by Univ. of Tennessee, --
195 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
196 * June 2017
197 *
198 * .. Scalar Arguments ..
199  INTEGER info, lda, m, n
200 * ..
201 * .. Array Arguments ..
202  REAL d( * ), e( * )
203  COMPLEX a( lda, * ), taup( * ), tauq( * ), work( * )
204 * ..
205 *
206 * =====================================================================
207 *
208 * .. Parameters ..
209  COMPLEX zero, one
210  parameter( zero = ( 0.0e+0, 0.0e+0 ),
211  $ one = ( 1.0e+0, 0.0e+0 ) )
212 * ..
213 * .. Local Scalars ..
214  INTEGER i
215  COMPLEX alpha
216 * ..
217 * .. External Subroutines ..
218  EXTERNAL clacgv, clarf, clarfg, xerbla
219 * ..
220 * .. Intrinsic Functions ..
221  INTRINSIC conjg, max, min
222 * ..
223 * .. Executable Statements ..
224 *
225 * Test the input parameters
226 *
227  info = 0
228  IF( m.LT.0 ) THEN
229  info = -1
230  ELSE IF( n.LT.0 ) THEN
231  info = -2
232  ELSE IF( lda.LT.max( 1, m ) ) THEN
233  info = -4
234  END IF
235  IF( info.LT.0 ) THEN
236  CALL xerbla( 'CGEBD2', -info )
237  RETURN
238  END IF
239 *
240  IF( m.GE.n ) THEN
241 *
242 * Reduce to upper bidiagonal form
243 *
244  DO 10 i = 1, n
245 *
246 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
247 *
248  alpha = a( i, i )
249  CALL clarfg( m-i+1, alpha, a( min( i+1, m ), i ), 1,
250  $ tauq( i ) )
251  d( i ) = alpha
252  a( i, i ) = one
253 *
254 * Apply H(i)**H to A(i:m,i+1:n) from the left
255 *
256  IF( i.LT.n )
257  $ CALL clarf( 'Left', m-i+1, n-i, a( i, i ), 1,
258  $ conjg( tauq( i ) ), a( i, i+1 ), lda, work )
259  a( i, i ) = d( i )
260 *
261  IF( i.LT.n ) THEN
262 *
263 * Generate elementary reflector G(i) to annihilate
264 * A(i,i+2:n)
265 *
266  CALL clacgv( n-i, a( i, i+1 ), lda )
267  alpha = a( i, i+1 )
268  CALL clarfg( n-i, alpha, a( i, min( i+2, n ) ),
269  $ lda, taup( i ) )
270  e( i ) = alpha
271  a( i, i+1 ) = one
272 *
273 * Apply G(i) to A(i+1:m,i+1:n) from the right
274 *
275  CALL clarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
276  $ taup( i ), a( i+1, i+1 ), lda, work )
277  CALL clacgv( n-i, a( i, i+1 ), lda )
278  a( i, i+1 ) = e( i )
279  ELSE
280  taup( i ) = zero
281  END IF
282  10 CONTINUE
283  ELSE
284 *
285 * Reduce to lower bidiagonal form
286 *
287  DO 20 i = 1, m
288 *
289 * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
290 *
291  CALL clacgv( n-i+1, a( i, i ), lda )
292  alpha = a( i, i )
293  CALL clarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
294  $ taup( i ) )
295  d( i ) = alpha
296  a( i, i ) = one
297 *
298 * Apply G(i) to A(i+1:m,i:n) from the right
299 *
300  IF( i.LT.m )
301  $ CALL clarf( 'Right', m-i, n-i+1, a( i, i ), lda,
302  $ taup( i ), a( i+1, i ), lda, work )
303  CALL clacgv( n-i+1, a( i, i ), lda )
304  a( i, i ) = d( i )
305 *
306  IF( i.LT.m ) THEN
307 *
308 * Generate elementary reflector H(i) to annihilate
309 * A(i+2:m,i)
310 *
311  alpha = a( i+1, i )
312  CALL clarfg( m-i, alpha, a( min( i+2, m ), i ), 1,
313  $ tauq( i ) )
314  e( i ) = alpha
315  a( i+1, i ) = one
316 *
317 * Apply H(i)**H to A(i+1:m,i+1:n) from the left
318 *
319  CALL clarf( 'Left', m-i, n-i, a( i+1, i ), 1,
320  $ conjg( tauq( i ) ), a( i+1, i+1 ), lda,
321  $ work )
322  a( i+1, i ) = e( i )
323  ELSE
324  tauq( i ) = zero
325  END IF
326  20 CONTINUE
327  END IF
328  RETURN
329 *
330 * End of CGEBD2
331 *
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:130
Here is the call graph for this function:
Here is the caller graph for this function: