LAPACK  3.10.1 LAPACK: Linear Algebra PACKage
clanhe.f
Go to the documentation of this file.
1 *> \brief \b CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CLANHE + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhe.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhe.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhe.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANHE( NORM, UPLO, N, A, LDA, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER LDA, N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX A( LDA, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANHE returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex hermitian matrix A.
41 *> \endverbatim
42 *>
43 *> \return CLANHE
44 *> \verbatim
45 *>
46 *> CLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANHE as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> hermitian matrix A is to be referenced.
75 *> = 'U': Upper triangular part of A is referenced
76 *> = 'L': Lower triangular part of A is referenced
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, CLANHE is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] A
87 *> \verbatim
88 *> A is COMPLEX array, dimension (LDA,N)
89 *> The hermitian matrix A. If UPLO = 'U', the leading n by n
90 *> upper triangular part of A contains the upper triangular part
91 *> of the matrix A, and the strictly lower triangular part of A
92 *> is not referenced. If UPLO = 'L', the leading n by n lower
93 *> triangular part of A contains the lower triangular part of
94 *> the matrix A, and the strictly upper triangular part of A is
95 *> not referenced. Note that the imaginary parts of the diagonal
96 *> elements need not be set and are assumed to be zero.
97 *> \endverbatim
98 *>
99 *> \param[in] LDA
100 *> \verbatim
101 *> LDA is INTEGER
102 *> The leading dimension of the array A. LDA >= max(N,1).
103 *> \endverbatim
104 *>
105 *> \param[out] WORK
106 *> \verbatim
107 *> WORK is REAL array, dimension (MAX(1,LWORK)),
108 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
109 *> WORK is not referenced.
110 *> \endverbatim
111 *
112 * Authors:
113 * ========
114 *
115 *> \author Univ. of Tennessee
116 *> \author Univ. of California Berkeley
117 *> \author Univ. of Colorado Denver
118 *> \author NAG Ltd.
119 *
120 *> \ingroup complexHEauxiliary
121 *
122 * =====================================================================
123  REAL function clanhe( norm, uplo, n, a, lda, work )
124 *
125 * -- LAPACK auxiliary routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129 * .. Scalar Arguments ..
130  CHARACTER norm, uplo
131  INTEGER lda, n
132 * ..
133 * .. Array Arguments ..
134  REAL work( * )
135  COMPLEX a( lda, * )
136 * ..
137 *
138 * =====================================================================
139 *
140 * .. Parameters ..
141  REAL one, zero
142  parameter( one = 1.0e+0, zero = 0.0e+0 )
143 * ..
144 * .. Local Scalars ..
145  INTEGER i, j
146  REAL absa, scale, sum, value
147 * ..
148 * .. External Functions ..
149  LOGICAL lsame, sisnan
150  EXTERNAL lsame, sisnan
151 * ..
152 * .. External Subroutines ..
153  EXTERNAL classq
154 * ..
155 * .. Intrinsic Functions ..
156  INTRINSIC abs, real, sqrt
157 * ..
158 * .. Executable Statements ..
159 *
160  IF( n.EQ.0 ) THEN
161  VALUE = zero
162  ELSE IF( lsame( norm, 'M' ) ) THEN
163 *
164 * Find max(abs(A(i,j))).
165 *
166  VALUE = zero
167  IF( lsame( uplo, 'U' ) ) THEN
168  DO 20 j = 1, n
169  DO 10 i = 1, j - 1
170  sum = abs( a( i, j ) )
171  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
172  10 CONTINUE
173  sum = abs( real( a( j, j ) ) )
174  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
175  20 CONTINUE
176  ELSE
177  DO 40 j = 1, n
178  sum = abs( real( a( j, j ) ) )
179  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
180  DO 30 i = j + 1, n
181  sum = abs( a( i, j ) )
182  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
183  30 CONTINUE
184  40 CONTINUE
185  END IF
186  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
187  \$ ( norm.EQ.'1' ) ) THEN
188 *
189 * Find normI(A) ( = norm1(A), since A is hermitian).
190 *
191  VALUE = zero
192  IF( lsame( uplo, 'U' ) ) THEN
193  DO 60 j = 1, n
194  sum = zero
195  DO 50 i = 1, j - 1
196  absa = abs( a( i, j ) )
197  sum = sum + absa
198  work( i ) = work( i ) + absa
199  50 CONTINUE
200  work( j ) = sum + abs( real( a( j, j ) ) )
201  60 CONTINUE
202  DO 70 i = 1, n
203  sum = work( i )
204  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
205  70 CONTINUE
206  ELSE
207  DO 80 i = 1, n
208  work( i ) = zero
209  80 CONTINUE
210  DO 100 j = 1, n
211  sum = work( j ) + abs( real( a( j, j ) ) )
212  DO 90 i = j + 1, n
213  absa = abs( a( i, j ) )
214  sum = sum + absa
215  work( i ) = work( i ) + absa
216  90 CONTINUE
217  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
218  100 CONTINUE
219  END IF
220  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
221 *
222 * Find normF(A).
223 *
224  scale = zero
225  sum = one
226  IF( lsame( uplo, 'U' ) ) THEN
227  DO 110 j = 2, n
228  CALL classq( j-1, a( 1, j ), 1, scale, sum )
229  110 CONTINUE
230  ELSE
231  DO 120 j = 1, n - 1
232  CALL classq( n-j, a( j+1, j ), 1, scale, sum )
233  120 CONTINUE
234  END IF
235  sum = 2*sum
236  DO 130 i = 1, n
237  IF( real( a( i, i ) ).NE.zero ) THEN
238  absa = abs( real( a( i, i ) ) )
239  IF( scale.LT.absa ) THEN
240  sum = one + sum*( scale / absa )**2
241  scale = absa
242  ELSE
243  sum = sum + ( absa / scale )**2
244  END IF
245  END IF
246  130 CONTINUE
247  VALUE = scale*sqrt( sum )
248  END IF
249 *
250  clanhe = VALUE
251  RETURN
252 *
253 * End of CLANHE
254 *
255  END
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clanhe(NORM, UPLO, N, A, LDA, WORK)
CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhe.f:124