LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

## ◆ zhetrf()

 subroutine zhetrf ( character UPLO, integer N, complex*16, dimension( lda, * ) A, integer LDA, integer, dimension( * ) IPIV, complex*16, dimension( * ) WORK, integer LWORK, integer INFO )

ZHETRF

Purpose:
``` ZHETRF computes the factorization of a complex Hermitian matrix A
using the Bunch-Kaufman diagonal pivoting method.  The form of the
factorization is

A = U*D*U**H  or  A = L*D*L**H

where U (or L) is a product of permutation and unit upper (lower)
triangular matrices, and D is Hermitian and block diagonal with
1-by-1 and 2-by-2 diagonal blocks.

This is the blocked version of the algorithm, calling Level 3 BLAS.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, the block diagonal matrix D and the multipliers used to obtain the factor U or L (see below for further details).``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [out] IPIV ``` IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D. If IPIV(k) > 0, then rows and columns k and IPIV(k) were interchanged and D(k,k) is a 1-by-1 diagonal block. If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k) is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) = IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.``` [out] WORK ``` WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The length of WORK. LWORK >=1. For best performance LWORK >= N*NB, where NB is the block size returned by ILAENV.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, D(i,i) is exactly zero. The factorization has been completed, but the block diagonal matrix D is exactly singular, and division by zero will occur if it is used to solve a system of equations.```
Date
December 2016
Further Details:
```  If UPLO = 'U', then A = U*D*U**H, where
U = P(n)*U(n)* ... *P(k)U(k)* ...,
i.e., U is a product of terms P(k)*U(k), where k decreases from n to
1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
that if the diagonal block D(k) is of order s (s = 1 or 2), then

(   I    v    0   )   k-s
U(k) =  (   0    I    0   )   s
(   0    0    I   )   n-k
k-s   s   n-k

If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
and A(k,k), and v overwrites A(1:k-2,k-1:k).

If UPLO = 'L', then A = L*D*L**H, where
L = P(1)*L(1)* ... *P(k)*L(k)* ...,
i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
that if the diagonal block D(k) is of order s (s = 1 or 2), then

(   I    0     0   )  k-1
L(k) =  (   0    I     0   )  s
(   0    v     I   )  n-k-s+1
k-1   s  n-k-s+1

If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).```

Definition at line 179 of file zhetrf.f.

179 *
180 * -- LAPACK computational routine (version 3.7.0) --
181 * -- LAPACK is a software package provided by Univ. of Tennessee, --
182 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
183 * December 2016
184 *
185 * .. Scalar Arguments ..
186  CHARACTER uplo
187  INTEGER info, lda, lwork, n
188 * ..
189 * .. Array Arguments ..
190  INTEGER ipiv( * )
191  COMPLEX*16 a( lda, * ), work( * )
192 * ..
193 *
194 * =====================================================================
195 *
196 * .. Local Scalars ..
197  LOGICAL lquery, upper
198  INTEGER iinfo, iws, j, k, kb, ldwork, lwkopt, nb, nbmin
199 * ..
200 * .. External Functions ..
201  LOGICAL lsame
202  INTEGER ilaenv
203  EXTERNAL lsame, ilaenv
204 * ..
205 * .. External Subroutines ..
206  EXTERNAL xerbla, zhetf2, zlahef
207 * ..
208 * .. Intrinsic Functions ..
209  INTRINSIC max
210 * ..
211 * .. Executable Statements ..
212 *
213 * Test the input parameters.
214 *
215  info = 0
216  upper = lsame( uplo, 'U' )
217  lquery = ( lwork.EQ.-1 )
218  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
219  info = -1
220  ELSE IF( n.LT.0 ) THEN
221  info = -2
222  ELSE IF( lda.LT.max( 1, n ) ) THEN
223  info = -4
224  ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
225  info = -7
226  END IF
227 *
228  IF( info.EQ.0 ) THEN
229 *
230 * Determine the block size
231 *
232  nb = ilaenv( 1, 'ZHETRF', uplo, n, -1, -1, -1 )
233  lwkopt = n*nb
234  work( 1 ) = lwkopt
235  END IF
236 *
237  IF( info.NE.0 ) THEN
238  CALL xerbla( 'ZHETRF', -info )
239  RETURN
240  ELSE IF( lquery ) THEN
241  RETURN
242  END IF
243 *
244  nbmin = 2
245  ldwork = n
246  IF( nb.GT.1 .AND. nb.LT.n ) THEN
247  iws = ldwork*nb
248  IF( lwork.LT.iws ) THEN
249  nb = max( lwork / ldwork, 1 )
250  nbmin = max( 2, ilaenv( 2, 'ZHETRF', uplo, n, -1, -1, -1 ) )
251  END IF
252  ELSE
253  iws = 1
254  END IF
255  IF( nb.LT.nbmin )
256  \$ nb = n
257 *
258  IF( upper ) THEN
259 *
260 * Factorize A as U*D*U**H using the upper triangle of A
261 *
262 * K is the main loop index, decreasing from N to 1 in steps of
263 * KB, where KB is the number of columns factorized by ZLAHEF;
264 * KB is either NB or NB-1, or K for the last block
265 *
266  k = n
267  10 CONTINUE
268 *
269 * If K < 1, exit from loop
270 *
271  IF( k.LT.1 )
272  \$ GO TO 40
273 *
274  IF( k.GT.nb ) THEN
275 *
276 * Factorize columns k-kb+1:k of A and use blocked code to
277 * update columns 1:k-kb
278 *
279  CALL zlahef( uplo, k, nb, kb, a, lda, ipiv, work, n, iinfo )
280  ELSE
281 *
282 * Use unblocked code to factorize columns 1:k of A
283 *
284  CALL zhetf2( uplo, k, a, lda, ipiv, iinfo )
285  kb = k
286  END IF
287 *
288 * Set INFO on the first occurrence of a zero pivot
289 *
290  IF( info.EQ.0 .AND. iinfo.GT.0 )
291  \$ info = iinfo
292 *
293 * Decrease K and return to the start of the main loop
294 *
295  k = k - kb
296  GO TO 10
297 *
298  ELSE
299 *
300 * Factorize A as L*D*L**H using the lower triangle of A
301 *
302 * K is the main loop index, increasing from 1 to N in steps of
303 * KB, where KB is the number of columns factorized by ZLAHEF;
304 * KB is either NB or NB-1, or N-K+1 for the last block
305 *
306  k = 1
307  20 CONTINUE
308 *
309 * If K > N, exit from loop
310 *
311  IF( k.GT.n )
312  \$ GO TO 40
313 *
314  IF( k.LE.n-nb ) THEN
315 *
316 * Factorize columns k:k+kb-1 of A and use blocked code to
317 * update columns k+kb:n
318 *
319  CALL zlahef( uplo, n-k+1, nb, kb, a( k, k ), lda, ipiv( k ),
320  \$ work, n, iinfo )
321  ELSE
322 *
323 * Use unblocked code to factorize columns k:n of A
324 *
325  CALL zhetf2( uplo, n-k+1, a( k, k ), lda, ipiv( k ), iinfo )
326  kb = n - k + 1
327  END IF
328 *
329 * Set INFO on the first occurrence of a zero pivot
330 *
331  IF( info.EQ.0 .AND. iinfo.GT.0 )
332  \$ info = iinfo + k - 1
333 *
335 *
336  DO 30 j = k, k + kb - 1
337  IF( ipiv( j ).GT.0 ) THEN
338  ipiv( j ) = ipiv( j ) + k - 1
339  ELSE
340  ipiv( j ) = ipiv( j ) - k + 1
341  END IF
342  30 CONTINUE
343 *
344 * Increase K and return to the start of the main loop
345 *
346  k = k + kb
347  GO TO 20
348 *
349  END IF
350 *
351  40 CONTINUE
352  work( 1 ) = lwkopt
353  RETURN
354 *
355 * End of ZHETRF
356 *
subroutine zlahef(UPLO, N, NB, KB, A, LDA, IPIV, W, LDW, INFO)
ZLAHEF computes a partial factorization of a complex Hermitian indefinite matrix using the Bunch-Kauf...
Definition: zlahef.f:179
subroutine zhetf2(UPLO, N, A, LDA, IPIV, INFO)
ZHETF2 computes the factorization of a complex Hermitian matrix, using the diagonal pivoting method (...
Definition: zhetf2.f:193
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: tstiee.f:83
Here is the call graph for this function:
Here is the caller graph for this function: