LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ chseqr()

subroutine chseqr ( character  JOB,
character  COMPZ,
integer  N,
integer  ILO,
integer  IHI,
complex, dimension( ldh, * )  H,
integer  LDH,
complex, dimension( * )  W,
complex, dimension( ldz, * )  Z,
integer  LDZ,
complex, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

CHSEQR

Download CHSEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    CHSEQR computes the eigenvalues of a Hessenberg matrix H
    and, optionally, the matrices T and Z from the Schur decomposition
    H = Z T Z**H, where T is an upper triangular matrix (the
    Schur form), and Z is the unitary matrix of Schur vectors.

    Optionally Z may be postmultiplied into an input unitary
    matrix Q so that this routine can give the Schur factorization
    of a matrix A which has been reduced to the Hessenberg form H
    by the unitary matrix Q:  A = Q*H*Q**H = (QZ)*T*(QZ)**H.
Parameters
[in]JOB
          JOB is CHARACTER*1
           = 'E':  compute eigenvalues only;
           = 'S':  compute eigenvalues and the Schur form T.
[in]COMPZ
          COMPZ is CHARACTER*1
           = 'N':  no Schur vectors are computed;
           = 'I':  Z is initialized to the unit matrix and the matrix Z
                   of Schur vectors of H is returned;
           = 'V':  Z must contain an unitary matrix Q on entry, and
                   the product Q*Z is returned.
[in]N
          N is INTEGER
           The order of the matrix H.  N .GE. 0.
[in]ILO
          ILO is INTEGER
[in]IHI
          IHI is INTEGER

           It is assumed that H is already upper triangular in rows
           and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
           set by a previous call to CGEBAL, and then passed to ZGEHRD
           when the matrix output by CGEBAL is reduced to Hessenberg
           form. Otherwise ILO and IHI should be set to 1 and N
           respectively.  If N.GT.0, then 1.LE.ILO.LE.IHI.LE.N.
           If N = 0, then ILO = 1 and IHI = 0.
[in,out]H
          H is COMPLEX array, dimension (LDH,N)
           On entry, the upper Hessenberg matrix H.
           On exit, if INFO = 0 and JOB = 'S', H contains the upper
           triangular matrix T from the Schur decomposition (the
           Schur form). If INFO = 0 and JOB = 'E', the contents of
           H are unspecified on exit.  (The output value of H when
           INFO.GT.0 is given under the description of INFO below.)

           Unlike earlier versions of CHSEQR, this subroutine may
           explicitly H(i,j) = 0 for i.GT.j and j = 1, 2, ... ILO-1
           or j = IHI+1, IHI+2, ... N.
[in]LDH
          LDH is INTEGER
           The leading dimension of the array H. LDH .GE. max(1,N).
[out]W
          W is COMPLEX array, dimension (N)
           The computed eigenvalues. If JOB = 'S', the eigenvalues are
           stored in the same order as on the diagonal of the Schur
           form returned in H, with W(i) = H(i,i).
[in,out]Z
          Z is COMPLEX array, dimension (LDZ,N)
           If COMPZ = 'N', Z is not referenced.
           If COMPZ = 'I', on entry Z need not be set and on exit,
           if INFO = 0, Z contains the unitary matrix Z of the Schur
           vectors of H.  If COMPZ = 'V', on entry Z must contain an
           N-by-N matrix Q, which is assumed to be equal to the unit
           matrix except for the submatrix Z(ILO:IHI,ILO:IHI). On exit,
           if INFO = 0, Z contains Q*Z.
           Normally Q is the unitary matrix generated by CUNGHR
           after the call to CGEHRD which formed the Hessenberg matrix
           H. (The output value of Z when INFO.GT.0 is given under
           the description of INFO below.)
[in]LDZ
          LDZ is INTEGER
           The leading dimension of the array Z.  if COMPZ = 'I' or
           COMPZ = 'V', then LDZ.GE.MAX(1,N).  Otherwize, LDZ.GE.1.
[out]WORK
          WORK is COMPLEX array, dimension (LWORK)
           On exit, if INFO = 0, WORK(1) returns an estimate of
           the optimal value for LWORK.
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK.  LWORK .GE. max(1,N)
           is sufficient and delivers very good and sometimes
           optimal performance.  However, LWORK as large as 11*N
           may be required for optimal performance.  A workspace
           query is recommended to determine the optimal workspace
           size.

           If LWORK = -1, then CHSEQR does a workspace query.
           In this case, CHSEQR checks the input parameters and
           estimates the optimal workspace size for the given
           values of N, ILO and IHI.  The estimate is returned
           in WORK(1).  No error message related to LWORK is
           issued by XERBLA.  Neither H nor Z are accessed.
[out]INFO
          INFO is INTEGER
             =  0:  successful exit
           .LT. 0:  if INFO = -i, the i-th argument had an illegal
                    value
           .GT. 0:  if INFO = i, CHSEQR failed to compute all of
                the eigenvalues.  Elements 1:ilo-1 and i+1:n of WR
                and WI contain those eigenvalues which have been
                successfully computed.  (Failures are rare.)

                If INFO .GT. 0 and JOB = 'E', then on exit, the
                remaining unconverged eigenvalues are the eigen-
                values of the upper Hessenberg matrix rows and
                columns ILO through INFO of the final, output
                value of H.

                If INFO .GT. 0 and JOB   = 'S', then on exit

           (*)  (initial value of H)*U  = U*(final value of H)

                where U is a unitary matrix.  The final
                value of  H is upper Hessenberg and triangular in
                rows and columns INFO+1 through IHI.

                If INFO .GT. 0 and COMPZ = 'V', then on exit

                  (final value of Z)  =  (initial value of Z)*U

                where U is the unitary matrix in (*) (regard-
                less of the value of JOB.)

                If INFO .GT. 0 and COMPZ = 'I', then on exit
                      (final value of Z)  = U
                where U is the unitary matrix in (*) (regard-
                less of the value of JOB.)

                If INFO .GT. 0 and COMPZ = 'N', then Z is not
                accessed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Contributors:
Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA
Further Details:
             Default values supplied by
             ILAENV(ISPEC,'CHSEQR',JOB(:1)//COMPZ(:1),N,ILO,IHI,LWORK).
             It is suggested that these defaults be adjusted in order
             to attain best performance in each particular
             computational environment.

            ISPEC=12: The CLAHQR vs CLAQR0 crossover point.
                      Default: 75. (Must be at least 11.)

            ISPEC=13: Recommended deflation window size.
                      This depends on ILO, IHI and NS.  NS is the
                      number of simultaneous shifts returned
                      by ILAENV(ISPEC=15).  (See ISPEC=15 below.)
                      The default for (IHI-ILO+1).LE.500 is NS.
                      The default for (IHI-ILO+1).GT.500 is 3*NS/2.

            ISPEC=14: Nibble crossover point. (See IPARMQ for
                      details.)  Default: 14% of deflation window
                      size.

            ISPEC=15: Number of simultaneous shifts in a multishift
                      QR iteration.

                      If IHI-ILO+1 is ...

                      greater than      ...but less    ... the
                      or equal to ...      than        default is

                           1               30          NS =   2(+)
                          30               60          NS =   4(+)
                          60              150          NS =  10(+)
                         150              590          NS =  **
                         590             3000          NS =  64
                        3000             6000          NS = 128
                        6000             infinity      NS = 256

                  (+)  By default some or all matrices of this order
                       are passed to the implicit double shift routine
                       CLAHQR and this parameter is ignored.  See
                       ISPEC=12 above and comments in IPARMQ for
                       details.

                 (**)  The asterisks (**) indicate an ad-hoc
                       function of N increasing from 10 to 64.

            ISPEC=16: Select structured matrix multiply.
                      If the number of simultaneous shifts (specified
                      by ISPEC=15) is less than 14, then the default
                      for ISPEC=16 is 0.  Otherwise the default for
                      ISPEC=16 is 2.
References:
K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part I: Maintaining Well Focused Shifts, and Level 3 Performance, SIAM Journal of Matrix Analysis, volume 23, pages 929–947, 2002.
K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part II: Aggressive Early Deflation, SIAM Journal of Matrix Analysis, volume 23, pages 948–973, 2002.

Definition at line 301 of file chseqr.f.

301 *
302 * -- LAPACK computational routine (version 3.7.0) --
303 * -- LAPACK is a software package provided by Univ. of Tennessee, --
304 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
305 * December 2016
306 *
307 * .. Scalar Arguments ..
308  INTEGER ihi, ilo, info, ldh, ldz, lwork, n
309  CHARACTER compz, job
310 * ..
311 * .. Array Arguments ..
312  COMPLEX h( ldh, * ), w( * ), work( * ), z( ldz, * )
313 * ..
314 *
315 * =====================================================================
316 *
317 * .. Parameters ..
318 *
319 * ==== Matrices of order NTINY or smaller must be processed by
320 * . CLAHQR because of insufficient subdiagonal scratch space.
321 * . (This is a hard limit.) ====
322  INTEGER ntiny
323  parameter( ntiny = 11 )
324 *
325 * ==== NL allocates some local workspace to help small matrices
326 * . through a rare CLAHQR failure. NL .GT. NTINY = 11 is
327 * . required and NL .LE. NMIN = ILAENV(ISPEC=12,...) is recom-
328 * . mended. (The default value of NMIN is 75.) Using NL = 49
329 * . allows up to six simultaneous shifts and a 16-by-16
330 * . deflation window. ====
331  INTEGER nl
332  parameter( nl = 49 )
333  COMPLEX zero, one
334  parameter( zero = ( 0.0e0, 0.0e0 ),
335  $ one = ( 1.0e0, 0.0e0 ) )
336  REAL rzero
337  parameter( rzero = 0.0e0 )
338 * ..
339 * .. Local Arrays ..
340  COMPLEX hl( nl, nl ), workl( nl )
341 * ..
342 * .. Local Scalars ..
343  INTEGER kbot, nmin
344  LOGICAL initz, lquery, wantt, wantz
345 * ..
346 * .. External Functions ..
347  INTEGER ilaenv
348  LOGICAL lsame
349  EXTERNAL ilaenv, lsame
350 * ..
351 * .. External Subroutines ..
352  EXTERNAL ccopy, clacpy, clahqr, claqr0, claset, xerbla
353 * ..
354 * .. Intrinsic Functions ..
355  INTRINSIC cmplx, max, min, real
356 * ..
357 * .. Executable Statements ..
358 *
359 * ==== Decode and check the input parameters. ====
360 *
361  wantt = lsame( job, 'S' )
362  initz = lsame( compz, 'I' )
363  wantz = initz .OR. lsame( compz, 'V' )
364  work( 1 ) = cmplx( REAL( MAX( 1, N ) ), rzero )
365  lquery = lwork.EQ.-1
366 *
367  info = 0
368  IF( .NOT.lsame( job, 'E' ) .AND. .NOT.wantt ) THEN
369  info = -1
370  ELSE IF( .NOT.lsame( compz, 'N' ) .AND. .NOT.wantz ) THEN
371  info = -2
372  ELSE IF( n.LT.0 ) THEN
373  info = -3
374  ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
375  info = -4
376  ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
377  info = -5
378  ELSE IF( ldh.LT.max( 1, n ) ) THEN
379  info = -7
380  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.max( 1, n ) ) ) THEN
381  info = -10
382  ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
383  info = -12
384  END IF
385 *
386  IF( info.NE.0 ) THEN
387 *
388 * ==== Quick return in case of invalid argument. ====
389 *
390  CALL xerbla( 'CHSEQR', -info )
391  RETURN
392 *
393  ELSE IF( n.EQ.0 ) THEN
394 *
395 * ==== Quick return in case N = 0; nothing to do. ====
396 *
397  RETURN
398 *
399  ELSE IF( lquery ) THEN
400 *
401 * ==== Quick return in case of a workspace query ====
402 *
403  CALL claqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo, ihi, z,
404  $ ldz, work, lwork, info )
405 * ==== Ensure reported workspace size is backward-compatible with
406 * . previous LAPACK versions. ====
407  work( 1 ) = cmplx( max( REAL( WORK( 1 ) ), REAL( MAX( 1, $ N ) ) ), rzero )
408  RETURN
409 *
410  ELSE
411 *
412 * ==== copy eigenvalues isolated by CGEBAL ====
413 *
414  IF( ilo.GT.1 )
415  $ CALL ccopy( ilo-1, h, ldh+1, w, 1 )
416  IF( ihi.LT.n )
417  $ CALL ccopy( n-ihi, h( ihi+1, ihi+1 ), ldh+1, w( ihi+1 ), 1 )
418 *
419 * ==== Initialize Z, if requested ====
420 *
421  IF( initz )
422  $ CALL claset( 'A', n, n, zero, one, z, ldz )
423 *
424 * ==== Quick return if possible ====
425 *
426  IF( ilo.EQ.ihi ) THEN
427  w( ilo ) = h( ilo, ilo )
428  RETURN
429  END IF
430 *
431 * ==== CLAHQR/CLAQR0 crossover point ====
432 *
433  nmin = ilaenv( 12, 'CHSEQR', job( : 1 ) // compz( : 1 ), n,
434  $ ilo, ihi, lwork )
435  nmin = max( ntiny, nmin )
436 *
437 * ==== CLAQR0 for big matrices; CLAHQR for small ones ====
438 *
439  IF( n.GT.nmin ) THEN
440  CALL claqr0( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo, ihi,
441  $ z, ldz, work, lwork, info )
442  ELSE
443 *
444 * ==== Small matrix ====
445 *
446  CALL clahqr( wantt, wantz, n, ilo, ihi, h, ldh, w, ilo, ihi,
447  $ z, ldz, info )
448 *
449  IF( info.GT.0 ) THEN
450 *
451 * ==== A rare CLAHQR failure! CLAQR0 sometimes succeeds
452 * . when CLAHQR fails. ====
453 *
454  kbot = info
455 *
456  IF( n.GE.nl ) THEN
457 *
458 * ==== Larger matrices have enough subdiagonal scratch
459 * . space to call CLAQR0 directly. ====
460 *
461  CALL claqr0( wantt, wantz, n, ilo, kbot, h, ldh, w,
462  $ ilo, ihi, z, ldz, work, lwork, info )
463 *
464  ELSE
465 *
466 * ==== Tiny matrices don't have enough subdiagonal
467 * . scratch space to benefit from CLAQR0. Hence,
468 * . tiny matrices must be copied into a larger
469 * . array before calling CLAQR0. ====
470 *
471  CALL clacpy( 'A', n, n, h, ldh, hl, nl )
472  hl( n+1, n ) = zero
473  CALL claset( 'A', nl, nl-n, zero, zero, hl( 1, n+1 ),
474  $ nl )
475  CALL claqr0( wantt, wantz, nl, ilo, kbot, hl, nl, w,
476  $ ilo, ihi, z, ldz, workl, nl, info )
477  IF( wantt .OR. info.NE.0 )
478  $ CALL clacpy( 'A', n, n, hl, nl, h, ldh )
479  END IF
480  END IF
481  END IF
482 *
483 * ==== Clear out the trash, if necessary. ====
484 *
485  IF( ( wantt .OR. info.NE.0 ) .AND. n.GT.2 )
486  $ CALL claset( 'L', n-2, n-2, zero, zero, h( 3, 1 ), ldh )
487 *
488 * ==== Ensure reported workspace size is backward-compatible with
489 * . previous LAPACK versions. ====
490 *
491  work( 1 ) = cmplx( max( REAL( MAX( 1, N ) ),
492  $ REAL( WORK( 1 ) ) ), rzero )
493  END IF
494 *
495 * ==== End of CHSEQR ====
496 *
497 
subroutine clahqr(WANTT, WANTZ, N, ILO, IHI, H, LDH, W, ILOZ, IHIZ, Z, LDZ, INFO)
CLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix, using the double-shift/single-shift QR algorithm.
Definition: clahqr.f:197
subroutine claqr0(WANTT, WANTZ, N, ILO, IHI, H, LDH, W, ILOZ, IHIZ, Z, LDZ, WORK, LWORK, INFO)
CLAQR0 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur de...
Definition: claqr0.f:242
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: claset.f:108
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: tstiee.f:83
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:105
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:83
Here is the call graph for this function:
Here is the caller graph for this function: