LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

## ◆ cung2l()

 subroutine cung2l ( integer M, integer N, integer K, complex, dimension( lda, * ) A, integer LDA, complex, dimension( * ) TAU, complex, dimension( * ) WORK, integer INFO )

CUNG2L generates all or part of the unitary matrix Q from a QL factorization determined by cgeqlf (unblocked algorithm).

Download CUNG2L + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` CUNG2L generates an m by n complex matrix Q with orthonormal columns,
which is defined as the last n columns of a product of k elementary
reflectors of order m

Q  =  H(k) . . . H(2) H(1)

as returned by CGEQLF.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix Q. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix Q. M >= N >= 0.``` [in] K ``` K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.``` [in,out] A ``` A is COMPLEX array, dimension (LDA,N) On entry, the (n-k+i)-th column must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by CGEQLF in the last k columns of its array argument A. On exit, the m-by-n matrix Q.``` [in] LDA ``` LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).``` [in] TAU ``` TAU is COMPLEX array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by CGEQLF.``` [out] WORK ` WORK is COMPLEX array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value```

Definition at line 113 of file cung2l.f.

114 *
115 * -- LAPACK computational routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119 * .. Scalar Arguments ..
120  INTEGER INFO, K, LDA, M, N
121 * ..
122 * .. Array Arguments ..
123  COMPLEX A( LDA, * ), TAU( * ), WORK( * )
124 * ..
125 *
126 * =====================================================================
127 *
128 * .. Parameters ..
129  COMPLEX ONE, ZERO
130  parameter( one = ( 1.0e+0, 0.0e+0 ),
131  \$ zero = ( 0.0e+0, 0.0e+0 ) )
132 * ..
133 * .. Local Scalars ..
134  INTEGER I, II, J, L
135 * ..
136 * .. External Subroutines ..
137  EXTERNAL clarf, cscal, xerbla
138 * ..
139 * .. Intrinsic Functions ..
140  INTRINSIC max
141 * ..
142 * .. Executable Statements ..
143 *
144 * Test the input arguments
145 *
146  info = 0
147  IF( m.LT.0 ) THEN
148  info = -1
149  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
150  info = -2
151  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
152  info = -3
153  ELSE IF( lda.LT.max( 1, m ) ) THEN
154  info = -5
155  END IF
156  IF( info.NE.0 ) THEN
157  CALL xerbla( 'CUNG2L', -info )
158  RETURN
159  END IF
160 *
161 * Quick return if possible
162 *
163  IF( n.LE.0 )
164  \$ RETURN
165 *
166 * Initialise columns 1:n-k to columns of the unit matrix
167 *
168  DO 20 j = 1, n - k
169  DO 10 l = 1, m
170  a( l, j ) = zero
171  10 CONTINUE
172  a( m-n+j, j ) = one
173  20 CONTINUE
174 *
175  DO 40 i = 1, k
176  ii = n - k + i
177 *
178 * Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
179 *
180  a( m-n+ii, ii ) = one
181  CALL clarf( 'Left', m-n+ii, ii-1, a( 1, ii ), 1, tau( i ), a,
182  \$ lda, work )
183  CALL cscal( m-n+ii-1, -tau( i ), a( 1, ii ), 1 )
184  a( m-n+ii, ii ) = one - tau( i )
185 *
186 * Set A(m-k+i+1:m,n-k+i) to zero
187 *
188  DO 30 l = m - n + ii + 1, m
189  a( l, ii ) = zero
190  30 CONTINUE
191  40 CONTINUE
192  RETURN
193 *
194 * End of CUNG2L
195 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
Here is the call graph for this function:
Here is the caller graph for this function: