LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cungr2()

subroutine cungr2 ( integer  M,
integer  N,
integer  K,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( * )  TAU,
complex, dimension( * )  WORK,
integer  INFO 
)

CUNGR2 generates all or part of the unitary matrix Q from an RQ factorization determined by cgerqf (unblocked algorithm).

Download CUNGR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CUNGR2 generates an m by n complex matrix Q with orthonormal rows,
 which is defined as the last m rows of a product of k elementary
 reflectors of order n

       Q  =  H(1)**H H(2)**H . . . H(k)**H

 as returned by CGERQF.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q. N >= M.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. M >= K >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the (m-k+i)-th row must contain the vector which
          defines the elementary reflector H(i), for i = 1,2,...,k, as
          returned by CGERQF in the last k rows of its array argument
          A.
          On exit, the m-by-n matrix Q.
[in]LDA
          LDA is INTEGER
          The first dimension of the array A. LDA >= max(1,M).
[in]TAU
          TAU is COMPLEX array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by CGERQF.
[out]WORK
          WORK is COMPLEX array, dimension (M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument has an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 116 of file cungr2.f.

116 *
117 * -- LAPACK computational routine (version 3.7.0) --
118 * -- LAPACK is a software package provided by Univ. of Tennessee, --
119 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120 * December 2016
121 *
122 * .. Scalar Arguments ..
123  INTEGER info, k, lda, m, n
124 * ..
125 * .. Array Arguments ..
126  COMPLEX a( lda, * ), tau( * ), work( * )
127 * ..
128 *
129 * =====================================================================
130 *
131 * .. Parameters ..
132  COMPLEX one, zero
133  parameter( one = ( 1.0e+0, 0.0e+0 ),
134  $ zero = ( 0.0e+0, 0.0e+0 ) )
135 * ..
136 * .. Local Scalars ..
137  INTEGER i, ii, j, l
138 * ..
139 * .. External Subroutines ..
140  EXTERNAL clacgv, clarf, cscal, xerbla
141 * ..
142 * .. Intrinsic Functions ..
143  INTRINSIC conjg, max
144 * ..
145 * .. Executable Statements ..
146 *
147 * Test the input arguments
148 *
149  info = 0
150  IF( m.LT.0 ) THEN
151  info = -1
152  ELSE IF( n.LT.m ) THEN
153  info = -2
154  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
155  info = -3
156  ELSE IF( lda.LT.max( 1, m ) ) THEN
157  info = -5
158  END IF
159  IF( info.NE.0 ) THEN
160  CALL xerbla( 'CUNGR2', -info )
161  RETURN
162  END IF
163 *
164 * Quick return if possible
165 *
166  IF( m.LE.0 )
167  $ RETURN
168 *
169  IF( k.LT.m ) THEN
170 *
171 * Initialise rows 1:m-k to rows of the unit matrix
172 *
173  DO 20 j = 1, n
174  DO 10 l = 1, m - k
175  a( l, j ) = zero
176  10 CONTINUE
177  IF( j.GT.n-m .AND. j.LE.n-k )
178  $ a( m-n+j, j ) = one
179  20 CONTINUE
180  END IF
181 *
182  DO 40 i = 1, k
183  ii = m - k + i
184 *
185 * Apply H(i)**H to A(1:m-k+i,1:n-k+i) from the right
186 *
187  CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
188  a( ii, n-m+ii ) = one
189  CALL clarf( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda,
190  $ conjg( tau( i ) ), a, lda, work )
191  CALL cscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
192  CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
193  a( ii, n-m+ii ) = one - conjg( tau( i ) )
194 *
195 * Set A(m-k+i,n-k+i+1:n) to zero
196 *
197  DO 30 l = n - m + ii + 1, n
198  a( ii, l ) = zero
199  30 CONTINUE
200  40 CONTINUE
201  RETURN
202 *
203 * End of CUNGR2
204 *
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:80
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:130
Here is the call graph for this function:
Here is the caller graph for this function: