LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dla_syrfsx_extended()

subroutine dla_syrfsx_extended ( integer  PREC_TYPE,
character  UPLO,
integer  N,
integer  NRHS,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension( * )  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
double precision, dimension( * )  RES,
double precision, dimension( * )  AYB,
double precision, dimension( * )  DY,
double precision, dimension( * )  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

DLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download DLA_SYRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLA_SYRFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by DSYRFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and
     P    = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X', 'E':  Extra
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
     On entry, the N-by-N matrix A.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is DOUBLE PRECISION array, dimension (LDAF,N)
     The block diagonal matrix D and the multipliers used to
     obtain the factor U or L as computed by DSYTRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     Details of the interchanges and the block structure of D
     as determined by DSYTRF.
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is DOUBLE PRECISION array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by DSYTRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by DLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace. This can be the same workspace passed for Y_TAIL.
[in]DY
          DY is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we definte as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to DLA_SYRFSX_EXTENDED had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017

Definition at line 398 of file dla_syrfsx_extended.f.

398 *
399 * -- LAPACK computational routine (version 3.7.1) --
400 * -- LAPACK is a software package provided by Univ. of Tennessee, --
401 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
402 * June 2017
403 *
404 * .. Scalar Arguments ..
405  INTEGER info, lda, ldaf, ldb, ldy, n, nrhs, prec_type,
406  $ n_norms, ithresh
407  CHARACTER uplo
408  LOGICAL colequ, ignore_cwise
409  DOUBLE PRECISION rthresh, dz_ub
410 * ..
411 * .. Array Arguments ..
412  INTEGER ipiv( * )
413  DOUBLE PRECISION a( lda, * ), af( ldaf, * ), b( ldb, * ),
414  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
415  DOUBLE PRECISION c( * ), ayb( * ), rcond, berr_out( * ),
416  $ err_bnds_norm( nrhs, * ),
417  $ err_bnds_comp( nrhs, * )
418 * ..
419 *
420 * =====================================================================
421 *
422 * .. Local Scalars ..
423  INTEGER uplo2, cnt, i, j, x_state, z_state
424  DOUBLE PRECISION yk, dyk, ymin, normy, normx, normdx, dxrat,
425  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
426  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
427  $ eps, hugeval, incr_thresh
428  LOGICAL incr_prec, upper
429 * ..
430 * .. Parameters ..
431  INTEGER unstable_state, working_state, conv_state,
432  $ noprog_state, y_prec_state, base_residual,
433  $ extra_residual, extra_y
434  parameter( unstable_state = 0, working_state = 1,
435  $ conv_state = 2, noprog_state = 3 )
436  parameter( base_residual = 0, extra_residual = 1,
437  $ extra_y = 2 )
438  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
439  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
440  INTEGER cmp_err_i, piv_growth_i
441  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
442  $ berr_i = 3 )
443  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
444  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
445  $ piv_growth_i = 9 )
446  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
447  $ la_linrx_cwise_i
448  parameter( la_linrx_itref_i = 1,
449  $ la_linrx_ithresh_i = 2 )
450  parameter( la_linrx_cwise_i = 3 )
451  INTEGER la_linrx_trust_i, la_linrx_err_i,
452  $ la_linrx_rcond_i
453  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
454  parameter( la_linrx_rcond_i = 3 )
455 * ..
456 * .. External Functions ..
457  LOGICAL lsame
458  EXTERNAL ilauplo
459  INTEGER ilauplo
460 * ..
461 * .. External Subroutines ..
462  EXTERNAL daxpy, dcopy, dsytrs, dsymv, blas_dsymv_x,
463  $ blas_dsymv2_x, dla_syamv, dla_wwaddw,
464  $ dla_lin_berr
465  DOUBLE PRECISION dlamch
466 * ..
467 * .. Intrinsic Functions ..
468  INTRINSIC abs, max, min
469 * ..
470 * .. Executable Statements ..
471 *
472  info = 0
473  upper = lsame( uplo, 'U' )
474  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
475  info = -2
476  ELSE IF( n.LT.0 ) THEN
477  info = -3
478  ELSE IF( nrhs.LT.0 ) THEN
479  info = -4
480  ELSE IF( lda.LT.max( 1, n ) ) THEN
481  info = -6
482  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
483  info = -8
484  ELSE IF( ldb.LT.max( 1, n ) ) THEN
485  info = -13
486  ELSE IF( ldy.LT.max( 1, n ) ) THEN
487  info = -15
488  END IF
489  IF( info.NE.0 ) THEN
490  CALL xerbla( 'DLA_SYRFSX_EXTENDED', -info )
491  RETURN
492  END IF
493  eps = dlamch( 'Epsilon' )
494  hugeval = dlamch( 'Overflow' )
495 * Force HUGEVAL to Inf
496  hugeval = hugeval * hugeval
497 * Using HUGEVAL may lead to spurious underflows.
498  incr_thresh = dble( n )*eps
499 
500  IF ( lsame( uplo, 'L' ) ) THEN
501  uplo2 = ilauplo( 'L' )
502  ELSE
503  uplo2 = ilauplo( 'U' )
504  ENDIF
505 
506  DO j = 1, nrhs
507  y_prec_state = extra_residual
508  IF ( y_prec_state .EQ. extra_y ) THEN
509  DO i = 1, n
510  y_tail( i ) = 0.0d+0
511  END DO
512  END IF
513 
514  dxrat = 0.0d+0
515  dxratmax = 0.0d+0
516  dzrat = 0.0d+0
517  dzratmax = 0.0d+0
518  final_dx_x = hugeval
519  final_dz_z = hugeval
520  prevnormdx = hugeval
521  prev_dz_z = hugeval
522  dz_z = hugeval
523  dx_x = hugeval
524 
525  x_state = working_state
526  z_state = unstable_state
527  incr_prec = .false.
528 
529  DO cnt = 1, ithresh
530 *
531 * Compute residual RES = B_s - op(A_s) * Y,
532 * op(A) = A, A**T, or A**H depending on TRANS (and type).
533 *
534  CALL dcopy( n, b( 1, j ), 1, res, 1 )
535  IF (y_prec_state .EQ. base_residual) THEN
536  CALL dsymv( uplo, n, -1.0d+0, a, lda, y(1,j), 1,
537  $ 1.0d+0, res, 1 )
538  ELSE IF (y_prec_state .EQ. extra_residual) THEN
539  CALL blas_dsymv_x( uplo2, n, -1.0d+0, a, lda,
540  $ y( 1, j ), 1, 1.0d+0, res, 1, prec_type )
541  ELSE
542  CALL blas_dsymv2_x(uplo2, n, -1.0d+0, a, lda,
543  $ y(1, j), y_tail, 1, 1.0d+0, res, 1, prec_type)
544  END IF
545 
546 ! XXX: RES is no longer needed.
547  CALL dcopy( n, res, 1, dy, 1 )
548  CALL dsytrs( uplo, n, 1, af, ldaf, ipiv, dy, n, info )
549 *
550 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
551 *
552  normx = 0.0d+0
553  normy = 0.0d+0
554  normdx = 0.0d+0
555  dz_z = 0.0d+0
556  ymin = hugeval
557 
558  DO i = 1, n
559  yk = abs( y( i, j ) )
560  dyk = abs( dy( i ) )
561 
562  IF ( yk .NE. 0.0d+0 ) THEN
563  dz_z = max( dz_z, dyk / yk )
564  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
565  dz_z = hugeval
566  END IF
567 
568  ymin = min( ymin, yk )
569 
570  normy = max( normy, yk )
571 
572  IF ( colequ ) THEN
573  normx = max( normx, yk * c( i ) )
574  normdx = max( normdx, dyk * c( i ) )
575  ELSE
576  normx = normy
577  normdx = max(normdx, dyk)
578  END IF
579  END DO
580 
581  IF ( normx .NE. 0.0d+0 ) THEN
582  dx_x = normdx / normx
583  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
584  dx_x = 0.0d+0
585  ELSE
586  dx_x = hugeval
587  END IF
588 
589  dxrat = normdx / prevnormdx
590  dzrat = dz_z / prev_dz_z
591 *
592 * Check termination criteria.
593 *
594  IF ( ymin*rcond .LT. incr_thresh*normy
595  $ .AND. y_prec_state .LT. extra_y )
596  $ incr_prec = .true.
597 
598  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
599  $ x_state = working_state
600  IF ( x_state .EQ. working_state ) THEN
601  IF ( dx_x .LE. eps ) THEN
602  x_state = conv_state
603  ELSE IF ( dxrat .GT. rthresh ) THEN
604  IF ( y_prec_state .NE. extra_y ) THEN
605  incr_prec = .true.
606  ELSE
607  x_state = noprog_state
608  END IF
609  ELSE
610  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
611  END IF
612  IF ( x_state .GT. working_state ) final_dx_x = dx_x
613  END IF
614 
615  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
616  $ z_state = working_state
617  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
618  $ z_state = working_state
619  IF ( z_state .EQ. working_state ) THEN
620  IF ( dz_z .LE. eps ) THEN
621  z_state = conv_state
622  ELSE IF ( dz_z .GT. dz_ub ) THEN
623  z_state = unstable_state
624  dzratmax = 0.0d+0
625  final_dz_z = hugeval
626  ELSE IF ( dzrat .GT. rthresh ) THEN
627  IF ( y_prec_state .NE. extra_y ) THEN
628  incr_prec = .true.
629  ELSE
630  z_state = noprog_state
631  END IF
632  ELSE
633  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
634  END IF
635  IF ( z_state .GT. working_state ) final_dz_z = dz_z
636  END IF
637 
638  IF ( x_state.NE.working_state.AND.
639  $ ( ignore_cwise.OR.z_state.NE.working_state ) )
640  $ GOTO 666
641 
642  IF ( incr_prec ) THEN
643  incr_prec = .false.
644  y_prec_state = y_prec_state + 1
645  DO i = 1, n
646  y_tail( i ) = 0.0d+0
647  END DO
648  END IF
649 
650  prevnormdx = normdx
651  prev_dz_z = dz_z
652 *
653 * Update soluton.
654 *
655  IF (y_prec_state .LT. extra_y) THEN
656  CALL daxpy( n, 1.0d+0, dy, 1, y(1,j), 1 )
657  ELSE
658  CALL dla_wwaddw( n, y(1,j), y_tail, dy )
659  END IF
660 
661  END DO
662 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
663  666 CONTINUE
664 *
665 * Set final_* when cnt hits ithresh.
666 *
667  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
668  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
669 *
670 * Compute error bounds.
671 *
672  IF ( n_norms .GE. 1 ) THEN
673  err_bnds_norm( j, la_linrx_err_i ) =
674  $ final_dx_x / (1 - dxratmax)
675  END IF
676  IF ( n_norms .GE. 2 ) THEN
677  err_bnds_comp( j, la_linrx_err_i ) =
678  $ final_dz_z / (1 - dzratmax)
679  END IF
680 *
681 * Compute componentwise relative backward error from formula
682 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
683 * where abs(Z) is the componentwise absolute value of the matrix
684 * or vector Z.
685 *
686 * Compute residual RES = B_s - op(A_s) * Y,
687 * op(A) = A, A**T, or A**H depending on TRANS (and type).
688  CALL dcopy( n, b( 1, j ), 1, res, 1 )
689  CALL dsymv( uplo, n, -1.0d+0, a, lda, y(1,j), 1, 1.0d+0, res,
690  $ 1 )
691 
692  DO i = 1, n
693  ayb( i ) = abs( b( i, j ) )
694  END DO
695 *
696 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
697 *
698  CALL dla_syamv( uplo2, n, 1.0d+0,
699  $ a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )
700 
701  CALL dla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
702 *
703 * End of loop for each RHS.
704 *
705  END DO
706 *
707  RETURN
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine dla_syamv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DLA_SYAMV computes a matrix-vector product using a symmetric indefinite matrix to calculate error bou...
Definition: dla_syamv.f:179
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:84
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:91
subroutine dla_wwaddw(N, X, Y, W)
DLA_WWADDW adds a vector into a doubled-single vector.
Definition: dla_wwaddw.f:83
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dsytrs(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
DSYTRS
Definition: dsytrs.f:122
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
integer function ilauplo(UPLO)
ILAUPLO
Definition: ilauplo.f:60
subroutine dla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
DLA_LIN_BERR computes a component-wise relative backward error.
Definition: dla_lin_berr.f:103
subroutine dsymv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DSYMV
Definition: dsymv.f:154
Here is the call graph for this function:
Here is the caller graph for this function: