LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ssbmv.f
Go to the documentation of this file.
1*> \brief \b SSBMV
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE SSBMV(UPLO,N,K,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
12*
13* .. Scalar Arguments ..
14* REAL ALPHA,BETA
15* INTEGER INCX,INCY,K,LDA,N
16* CHARACTER UPLO
17* ..
18* .. Array Arguments ..
19* REAL A(LDA,*),X(*),Y(*)
20* ..
21*
22*
23*> \par Purpose:
24* =============
25*>
26*> \verbatim
27*>
28*> SSBMV performs the matrix-vector operation
29*>
30*> y := alpha*A*x + beta*y,
31*>
32*> where alpha and beta are scalars, x and y are n element vectors and
33*> A is an n by n symmetric band matrix, with k super-diagonals.
34*> \endverbatim
35*
36* Arguments:
37* ==========
38*
39*> \param[in] UPLO
40*> \verbatim
41*> UPLO is CHARACTER*1
42*> On entry, UPLO specifies whether the upper or lower
43*> triangular part of the band matrix A is being supplied as
44*> follows:
45*>
46*> UPLO = 'U' or 'u' The upper triangular part of A is
47*> being supplied.
48*>
49*> UPLO = 'L' or 'l' The lower triangular part of A is
50*> being supplied.
51*> \endverbatim
52*>
53*> \param[in] N
54*> \verbatim
55*> N is INTEGER
56*> On entry, N specifies the order of the matrix A.
57*> N must be at least zero.
58*> \endverbatim
59*>
60*> \param[in] K
61*> \verbatim
62*> K is INTEGER
63*> On entry, K specifies the number of super-diagonals of the
64*> matrix A. K must satisfy 0 .le. K.
65*> \endverbatim
66*>
67*> \param[in] ALPHA
68*> \verbatim
69*> ALPHA is REAL
70*> On entry, ALPHA specifies the scalar alpha.
71*> \endverbatim
72*>
73*> \param[in] A
74*> \verbatim
75*> A is REAL array, dimension ( LDA, N )
76*> Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
77*> by n part of the array A must contain the upper triangular
78*> band part of the symmetric matrix, supplied column by
79*> column, with the leading diagonal of the matrix in row
80*> ( k + 1 ) of the array, the first super-diagonal starting at
81*> position 2 in row k, and so on. The top left k by k triangle
82*> of the array A is not referenced.
83*> The following program segment will transfer the upper
84*> triangular part of a symmetric band matrix from conventional
85*> full matrix storage to band storage:
86*>
87*> DO 20, J = 1, N
88*> M = K + 1 - J
89*> DO 10, I = MAX( 1, J - K ), J
90*> A( M + I, J ) = matrix( I, J )
91*> 10 CONTINUE
92*> 20 CONTINUE
93*>
94*> Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
95*> by n part of the array A must contain the lower triangular
96*> band part of the symmetric matrix, supplied column by
97*> column, with the leading diagonal of the matrix in row 1 of
98*> the array, the first sub-diagonal starting at position 1 in
99*> row 2, and so on. The bottom right k by k triangle of the
100*> array A is not referenced.
101*> The following program segment will transfer the lower
102*> triangular part of a symmetric band matrix from conventional
103*> full matrix storage to band storage:
104*>
105*> DO 20, J = 1, N
106*> M = 1 - J
107*> DO 10, I = J, MIN( N, J + K )
108*> A( M + I, J ) = matrix( I, J )
109*> 10 CONTINUE
110*> 20 CONTINUE
111*> \endverbatim
112*>
113*> \param[in] LDA
114*> \verbatim
115*> LDA is INTEGER
116*> On entry, LDA specifies the first dimension of A as declared
117*> in the calling (sub) program. LDA must be at least
118*> ( k + 1 ).
119*> \endverbatim
120*>
121*> \param[in] X
122*> \verbatim
123*> X is REAL array, dimension at least
124*> ( 1 + ( n - 1 )*abs( INCX ) ).
125*> Before entry, the incremented array X must contain the
126*> vector x.
127*> \endverbatim
128*>
129*> \param[in] INCX
130*> \verbatim
131*> INCX is INTEGER
132*> On entry, INCX specifies the increment for the elements of
133*> X. INCX must not be zero.
134*> \endverbatim
135*>
136*> \param[in] BETA
137*> \verbatim
138*> BETA is REAL
139*> On entry, BETA specifies the scalar beta.
140*> \endverbatim
141*>
142*> \param[in,out] Y
143*> \verbatim
144*> Y is REAL array, dimension at least
145*> ( 1 + ( n - 1 )*abs( INCY ) ).
146*> Before entry, the incremented array Y must contain the
147*> vector y. On exit, Y is overwritten by the updated vector y.
148*> \endverbatim
149*>
150*> \param[in] INCY
151*> \verbatim
152*> INCY is INTEGER
153*> On entry, INCY specifies the increment for the elements of
154*> Y. INCY must not be zero.
155*> \endverbatim
156*
157* Authors:
158* ========
159*
160*> \author Univ. of Tennessee
161*> \author Univ. of California Berkeley
162*> \author Univ. of Colorado Denver
163*> \author NAG Ltd.
164*
165*> \ingroup hbmv
166*
167*> \par Further Details:
168* =====================
169*>
170*> \verbatim
171*>
172*> Level 2 Blas routine.
173*> The vector and matrix arguments are not referenced when N = 0, or M = 0
174*>
175*> -- Written on 22-October-1986.
176*> Jack Dongarra, Argonne National Lab.
177*> Jeremy Du Croz, Nag Central Office.
178*> Sven Hammarling, Nag Central Office.
179*> Richard Hanson, Sandia National Labs.
180*> \endverbatim
181*>
182* =====================================================================
183 SUBROUTINE ssbmv(UPLO,N,K,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
184*
185* -- Reference BLAS level2 routine --
186* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
187* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
188*
189* .. Scalar Arguments ..
190 REAL ALPHA,BETA
191 INTEGER INCX,INCY,K,LDA,N
192 CHARACTER UPLO
193* ..
194* .. Array Arguments ..
195 REAL A(LDA,*),X(*),Y(*)
196* ..
197*
198* =====================================================================
199*
200* .. Parameters ..
201 REAL ONE,ZERO
202 parameter(one=1.0e+0,zero=0.0e+0)
203* ..
204* .. Local Scalars ..
205 REAL TEMP1,TEMP2
206 INTEGER I,INFO,IX,IY,J,JX,JY,KPLUS1,KX,KY,L
207* ..
208* .. External Functions ..
209 LOGICAL LSAME
210 EXTERNAL lsame
211* ..
212* .. External Subroutines ..
213 EXTERNAL xerbla
214* ..
215* .. Intrinsic Functions ..
216 INTRINSIC max,min
217* ..
218*
219* Test the input parameters.
220*
221 info = 0
222 IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
223 info = 1
224 ELSE IF (n.LT.0) THEN
225 info = 2
226 ELSE IF (k.LT.0) THEN
227 info = 3
228 ELSE IF (lda.LT. (k+1)) THEN
229 info = 6
230 ELSE IF (incx.EQ.0) THEN
231 info = 8
232 ELSE IF (incy.EQ.0) THEN
233 info = 11
234 END IF
235 IF (info.NE.0) THEN
236 CALL xerbla('SSBMV ',info)
237 RETURN
238 END IF
239*
240* Quick return if possible.
241*
242 IF ((n.EQ.0) .OR. ((alpha.EQ.zero).AND. (beta.EQ.one))) RETURN
243*
244* Set up the start points in X and Y.
245*
246 IF (incx.GT.0) THEN
247 kx = 1
248 ELSE
249 kx = 1 - (n-1)*incx
250 END IF
251 IF (incy.GT.0) THEN
252 ky = 1
253 ELSE
254 ky = 1 - (n-1)*incy
255 END IF
256*
257* Start the operations. In this version the elements of the array A
258* are accessed sequentially with one pass through A.
259*
260* First form y := beta*y.
261*
262 IF (beta.NE.one) THEN
263 IF (incy.EQ.1) THEN
264 IF (beta.EQ.zero) THEN
265 DO 10 i = 1,n
266 y(i) = zero
267 10 CONTINUE
268 ELSE
269 DO 20 i = 1,n
270 y(i) = beta*y(i)
271 20 CONTINUE
272 END IF
273 ELSE
274 iy = ky
275 IF (beta.EQ.zero) THEN
276 DO 30 i = 1,n
277 y(iy) = zero
278 iy = iy + incy
279 30 CONTINUE
280 ELSE
281 DO 40 i = 1,n
282 y(iy) = beta*y(iy)
283 iy = iy + incy
284 40 CONTINUE
285 END IF
286 END IF
287 END IF
288 IF (alpha.EQ.zero) RETURN
289 IF (lsame(uplo,'U')) THEN
290*
291* Form y when upper triangle of A is stored.
292*
293 kplus1 = k + 1
294 IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
295 DO 60 j = 1,n
296 temp1 = alpha*x(j)
297 temp2 = zero
298 l = kplus1 - j
299 DO 50 i = max(1,j-k),j - 1
300 y(i) = y(i) + temp1*a(l+i,j)
301 temp2 = temp2 + a(l+i,j)*x(i)
302 50 CONTINUE
303 y(j) = y(j) + temp1*a(kplus1,j) + alpha*temp2
304 60 CONTINUE
305 ELSE
306 jx = kx
307 jy = ky
308 DO 80 j = 1,n
309 temp1 = alpha*x(jx)
310 temp2 = zero
311 ix = kx
312 iy = ky
313 l = kplus1 - j
314 DO 70 i = max(1,j-k),j - 1
315 y(iy) = y(iy) + temp1*a(l+i,j)
316 temp2 = temp2 + a(l+i,j)*x(ix)
317 ix = ix + incx
318 iy = iy + incy
319 70 CONTINUE
320 y(jy) = y(jy) + temp1*a(kplus1,j) + alpha*temp2
321 jx = jx + incx
322 jy = jy + incy
323 IF (j.GT.k) THEN
324 kx = kx + incx
325 ky = ky + incy
326 END IF
327 80 CONTINUE
328 END IF
329 ELSE
330*
331* Form y when lower triangle of A is stored.
332*
333 IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
334 DO 100 j = 1,n
335 temp1 = alpha*x(j)
336 temp2 = zero
337 y(j) = y(j) + temp1*a(1,j)
338 l = 1 - j
339 DO 90 i = j + 1,min(n,j+k)
340 y(i) = y(i) + temp1*a(l+i,j)
341 temp2 = temp2 + a(l+i,j)*x(i)
342 90 CONTINUE
343 y(j) = y(j) + alpha*temp2
344 100 CONTINUE
345 ELSE
346 jx = kx
347 jy = ky
348 DO 120 j = 1,n
349 temp1 = alpha*x(jx)
350 temp2 = zero
351 y(jy) = y(jy) + temp1*a(1,j)
352 l = 1 - j
353 ix = jx
354 iy = jy
355 DO 110 i = j + 1,min(n,j+k)
356 ix = ix + incx
357 iy = iy + incy
358 y(iy) = y(iy) + temp1*a(l+i,j)
359 temp2 = temp2 + a(l+i,j)*x(ix)
360 110 CONTINUE
361 y(jy) = y(jy) + alpha*temp2
362 jx = jx + incx
363 jy = jy + incy
364 120 CONTINUE
365 END IF
366 END IF
367*
368 RETURN
369*
370* End of SSBMV
371*
372 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine ssbmv(uplo, n, k, alpha, a, lda, x, incx, beta, y, incy)
SSBMV
Definition ssbmv.f:184