LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zporfsx()

subroutine zporfsx ( character  UPLO,
character  EQUED,
integer  N,
integer  NRHS,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldaf, * )  AF,
integer  LDAF,
double precision, dimension( * )  S,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldx, * )  X,
integer  LDX,
double precision  RCOND,
double precision, dimension( * )  BERR,
integer  N_ERR_BNDS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
integer  NPARAMS,
double precision, dimension(*)  PARAMS,
complex*16, dimension( * )  WORK,
double precision, dimension( * )  RWORK,
integer  INFO 
)

ZPORFSX

Download ZPORFSX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    ZPORFSX improves the computed solution to a system of linear
    equations when the coefficient matrix is symmetric positive
    definite, and provides error bounds and backward error estimates
    for the solution.  In addition to normwise error bound, the code
    provides maximum componentwise error bound if possible.  See
    comments for ERR_BNDS_NORM and ERR_BNDS_COMP for details of the
    error bounds.

    The original system of linear equations may have been equilibrated
    before calling this routine, as described by arguments EQUED and S
    below. In this case, the solution and error bounds returned are
    for the original unequilibrated system.
     Some optional parameters are bundled in the PARAMS array.  These
     settings determine how refinement is performed, but often the
     defaults are acceptable.  If the defaults are acceptable, users
     can pass NPARAMS = 0 which prevents the source code from accessing
     the PARAMS argument.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]EQUED
          EQUED is CHARACTER*1
     Specifies the form of equilibration that was done to A
     before calling this routine. This is needed to compute
     the solution and error bounds correctly.
       = 'N':  No equilibration
       = 'Y':  Both row and column equilibration, i.e., A has been
               replaced by diag(S) * A * diag(S).
               The right hand side B has been changed accordingly.
[in]N
          N is INTEGER
     The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right hand sides, i.e., the number of columns
     of the matrices B and X.  NRHS >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
     The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
     upper triangular part of A contains the upper triangular part
     of the matrix A, and the strictly lower triangular part of A
     is not referenced.  If UPLO = 'L', the leading N-by-N lower
     triangular part of A contains the lower triangular part of
     the matrix A, and the strictly upper triangular part of A is
     not referenced.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is COMPLEX*16 array, dimension (LDAF,N)
     The triangular factor U or L from the Cholesky factorization
     A = U**T*U or A = L*L**T, as computed by DPOTRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in,out]S
          S is DOUBLE PRECISION array, dimension (N)
     The row scale factors for A.  If EQUED = 'Y', A is multiplied on
     the left and right by diag(S).  S is an input argument if FACT =
     'F'; otherwise, S is an output argument.  If FACT = 'F' and EQUED
     = 'Y', each element of S must be positive.  If S is output, each
     element of S is a power of the radix. If S is input, each element
     of S should be a power of the radix to ensure a reliable solution
     and error estimates. Scaling by powers of the radix does not cause
     rounding errors unless the result underflows or overflows.
     Rounding errors during scaling lead to refining with a matrix that
     is not equivalent to the input matrix, producing error estimates
     that may not be reliable.
[in]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
     The right hand side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]X
          X is COMPLEX*16 array, dimension (LDX,NRHS)
     On entry, the solution matrix X, as computed by DGETRS.
     On exit, the improved solution matrix X.
[in]LDX
          LDX is INTEGER
     The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[out]BERR
          BERR is DOUBLE PRECISION array, dimension (NRHS)
     Componentwise relative backward error.  This is the
     componentwise relative backward error of each solution vector X(j)
     (i.e., the smallest relative change in any element of A or B that
     makes X(j) an exact solution).
[in]N_ERR_BNDS
          N_ERR_BNDS is INTEGER
     Number of error bounds to return for each right hand side
     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
     ERR_BNDS_COMP below.
[out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * dlamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * dlamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * dlamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * dlamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * dlamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * dlamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[in]NPARAMS
          NPARAMS is INTEGER
     Specifies the number of parameters set in PARAMS.  If .LE. 0, the
     PARAMS array is never referenced and default values are used.
[in,out]PARAMS
          PARAMS is DOUBLE PRECISION array, dimension NPARAMS
     Specifies algorithm parameters.  If an entry is .LT. 0.0, then
     that entry will be filled with default value used for that
     parameter.  Only positions up to NPARAMS are accessed; defaults
     are used for higher-numbered parameters.

       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
            refinement or not.
         Default: 1.0D+0
            = 0.0 : No refinement is performed, and no error bounds are
                    computed.
            = 1.0 : Use the double-precision refinement algorithm,
                    possibly with doubled-single computations if the
                    compilation environment does not support DOUBLE
                    PRECISION.
              (other values are reserved for future use)

       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
            computations allowed for refinement.
         Default: 10
         Aggressive: Set to 100 to permit convergence using approximate
                     factorizations or factorizations other than LU. If
                     the factorization uses a technique other than
                     Gaussian elimination, the guarantees in
                     err_bnds_norm and err_bnds_comp may no longer be
                     trustworthy.

       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
            will attempt to find a solution with small componentwise
            relative error in the double-precision algorithm.  Positive
            is true, 0.0 is false.
         Default: 1.0 (attempt componentwise convergence)
[out]WORK
          WORK is COMPLEX*16 array, dimension (2*N)
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (2*N)
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit. The solution to every right-hand side is
         guaranteed.
       < 0:  If INFO = -i, the i-th argument had an illegal value
       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
         has been completed, but the factor U is exactly singular, so
         the solution and error bounds could not be computed. RCOND = 0
         is returned.
       = N+J: The solution corresponding to the Jth right-hand side is
         not guaranteed. The solutions corresponding to other right-
         hand sides K with K > J may not be guaranteed as well, but
         only the first such right-hand side is reported. If a small
         componentwise error is not requested (PARAMS(3) = 0.0) then
         the Jth right-hand side is the first with a normwise error
         bound that is not guaranteed (the smallest J such
         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
         the Jth right-hand side is the first with either a normwise or
         componentwise error bound that is not guaranteed (the smallest
         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
         about all of the right-hand sides check ERR_BNDS_NORM or
         ERR_BNDS_COMP.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 395 of file zporfsx.f.

395 *
396 * -- LAPACK computational routine (version 3.7.0) --
397 * -- LAPACK is a software package provided by Univ. of Tennessee, --
398 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
399 * April 2012
400 *
401 * .. Scalar Arguments ..
402  CHARACTER uplo, equed
403  INTEGER info, lda, ldaf, ldb, ldx, n, nrhs, nparams,
404  $ n_err_bnds
405  DOUBLE PRECISION rcond
406 * ..
407 * .. Array Arguments ..
408  COMPLEX*16 a( lda, * ), af( ldaf, * ), b( ldb, * ),
409  $ x( ldx, * ), work( * )
410  DOUBLE PRECISION rwork( * ), s( * ), params(*), berr( * ),
411  $ err_bnds_norm( nrhs, * ),
412  $ err_bnds_comp( nrhs, * )
413 * ..
414 *
415 * ==================================================================
416 *
417 * .. Parameters ..
418  DOUBLE PRECISION zero, one
419  parameter( zero = 0.0d+0, one = 1.0d+0 )
420  DOUBLE PRECISION itref_default, ithresh_default
421  DOUBLE PRECISION componentwise_default, rthresh_default
422  DOUBLE PRECISION dzthresh_default
423  parameter( itref_default = 1.0d+0 )
424  parameter( ithresh_default = 10.0d+0 )
425  parameter( componentwise_default = 1.0d+0 )
426  parameter( rthresh_default = 0.5d+0 )
427  parameter( dzthresh_default = 0.25d+0 )
428  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
429  $ la_linrx_cwise_i
430  parameter( la_linrx_itref_i = 1,
431  $ la_linrx_ithresh_i = 2 )
432  parameter( la_linrx_cwise_i = 3 )
433  INTEGER la_linrx_trust_i, la_linrx_err_i,
434  $ la_linrx_rcond_i
435  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
436  parameter( la_linrx_rcond_i = 3 )
437 * ..
438 * .. Local Scalars ..
439  CHARACTER(1) norm
440  LOGICAL rcequ
441  INTEGER j, prec_type, ref_type
442  INTEGER n_norms
443  DOUBLE PRECISION anorm, rcond_tmp
444  DOUBLE PRECISION illrcond_thresh, err_lbnd, cwise_wrong
445  LOGICAL ignore_cwise
446  INTEGER ithresh
447  DOUBLE PRECISION rthresh, unstable_thresh
448 * ..
449 * .. External Subroutines ..
451 * ..
452 * .. Intrinsic Functions ..
453  INTRINSIC max, sqrt, transfer
454 * ..
455 * .. External Functions ..
456  EXTERNAL lsame, ilaprec
458  DOUBLE PRECISION dlamch, zlanhe, zla_porcond_x, zla_porcond_c
459  LOGICAL lsame
460  INTEGER ilaprec
461 * ..
462 * .. Executable Statements ..
463 *
464 * Check the input parameters.
465 *
466  info = 0
467  ref_type = int( itref_default )
468  IF ( nparams .GE. la_linrx_itref_i ) THEN
469  IF ( params( la_linrx_itref_i ) .LT. 0.0d+0 ) THEN
470  params( la_linrx_itref_i ) = itref_default
471  ELSE
472  ref_type = params( la_linrx_itref_i )
473  END IF
474  END IF
475 *
476 * Set default parameters.
477 *
478  illrcond_thresh = dble( n ) * dlamch( 'Epsilon' )
479  ithresh = int( ithresh_default )
480  rthresh = rthresh_default
481  unstable_thresh = dzthresh_default
482  ignore_cwise = componentwise_default .EQ. 0.0d+0
483 *
484  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
485  IF ( params(la_linrx_ithresh_i ).LT.0.0d+0 ) THEN
486  params( la_linrx_ithresh_i ) = ithresh
487  ELSE
488  ithresh = int( params( la_linrx_ithresh_i ) )
489  END IF
490  END IF
491  IF ( nparams.GE.la_linrx_cwise_i ) THEN
492  IF ( params(la_linrx_cwise_i ).LT.0.0d+0 ) THEN
493  IF ( ignore_cwise ) THEN
494  params( la_linrx_cwise_i ) = 0.0d+0
495  ELSE
496  params( la_linrx_cwise_i ) = 1.0d+0
497  END IF
498  ELSE
499  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0d+0
500  END IF
501  END IF
502  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
503  n_norms = 0
504  ELSE IF ( ignore_cwise ) THEN
505  n_norms = 1
506  ELSE
507  n_norms = 2
508  END IF
509 *
510  rcequ = lsame( equed, 'Y' )
511 *
512 * Test input parameters.
513 *
514  IF (.NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
515  info = -1
516  ELSE IF( .NOT.rcequ .AND. .NOT.lsame( equed, 'N' ) ) THEN
517  info = -2
518  ELSE IF( n.LT.0 ) THEN
519  info = -3
520  ELSE IF( nrhs.LT.0 ) THEN
521  info = -4
522  ELSE IF( lda.LT.max( 1, n ) ) THEN
523  info = -6
524  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
525  info = -8
526  ELSE IF( ldb.LT.max( 1, n ) ) THEN
527  info = -11
528  ELSE IF( ldx.LT.max( 1, n ) ) THEN
529  info = -13
530  END IF
531  IF( info.NE.0 ) THEN
532  CALL xerbla( 'ZPORFSX', -info )
533  RETURN
534  END IF
535 *
536 * Quick return if possible.
537 *
538  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
539  rcond = 1.0d+0
540  DO j = 1, nrhs
541  berr( j ) = 0.0d+0
542  IF ( n_err_bnds .GE. 1 ) THEN
543  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
544  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
545  END IF
546  IF ( n_err_bnds .GE. 2 ) THEN
547  err_bnds_norm( j, la_linrx_err_i ) = 0.0d+0
548  err_bnds_comp( j, la_linrx_err_i ) = 0.0d+0
549  END IF
550  IF ( n_err_bnds .GE. 3 ) THEN
551  err_bnds_norm( j, la_linrx_rcond_i ) = 1.0d+0
552  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0d+0
553  END IF
554  END DO
555  RETURN
556  END IF
557 *
558 * Default to failure.
559 *
560  rcond = 0.0d+0
561  DO j = 1, nrhs
562  berr( j ) = 1.0d+0
563  IF ( n_err_bnds .GE. 1 ) THEN
564  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
565  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
566  END IF
567  IF ( n_err_bnds .GE. 2 ) THEN
568  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
569  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
570  END IF
571  IF ( n_err_bnds .GE. 3 ) THEN
572  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0d+0
573  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0d+0
574  END IF
575  END DO
576 *
577 * Compute the norm of A and the reciprocal of the condition
578 * number of A.
579 *
580  norm = 'I'
581  anorm = zlanhe( norm, uplo, n, a, lda, rwork )
582  CALL zpocon( uplo, n, af, ldaf, anorm, rcond, work, rwork,
583  $ info )
584 *
585 * Perform refinement on each right-hand side
586 *
587  IF ( ref_type .NE. 0 ) THEN
588 
589  prec_type = ilaprec( 'E' )
590 
591  CALL zla_porfsx_extended( prec_type, uplo, n,
592  $ nrhs, a, lda, af, ldaf, rcequ, s, b,
593  $ ldb, x, ldx, berr, n_norms, err_bnds_norm, err_bnds_comp,
594  $ work, rwork, work(n+1),
595  $ transfer(rwork(1:2*n), (/ (zero, zero) /), n), rcond,
596  $ ithresh, rthresh, unstable_thresh, ignore_cwise,
597  $ info )
598  END IF
599 
600  err_lbnd = max( 10.0d+0, sqrt( dble( n ) ) ) * dlamch( 'Epsilon' )
601  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 1 ) THEN
602 *
603 * Compute scaled normwise condition number cond(A*C).
604 *
605  IF ( rcequ ) THEN
606  rcond_tmp = zla_porcond_c( uplo, n, a, lda, af, ldaf,
607  $ s, .true., info, work, rwork )
608  ELSE
609  rcond_tmp = zla_porcond_c( uplo, n, a, lda, af, ldaf,
610  $ s, .false., info, work, rwork )
611  END IF
612  DO j = 1, nrhs
613 *
614 * Cap the error at 1.0.
615 *
616  IF ( n_err_bnds .GE. la_linrx_err_i
617  $ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0d+0 )
618  $ err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
619 *
620 * Threshold the error (see LAWN).
621 *
622  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
623  err_bnds_norm( j, la_linrx_err_i ) = 1.0d+0
624  err_bnds_norm( j, la_linrx_trust_i ) = 0.0d+0
625  IF ( info .LE. n ) info = n + j
626  ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
627  $ THEN
628  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
629  err_bnds_norm( j, la_linrx_trust_i ) = 1.0d+0
630  END IF
631 *
632 * Save the condition number.
633 *
634  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
635  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
636  END IF
637 
638  END DO
639  END IF
640 
641  IF (n_err_bnds .GE. 1 .AND. n_norms .GE. 2) THEN
642 *
643 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
644 * each right-hand side using the current solution as an estimate of
645 * the true solution. If the componentwise error estimate is too
646 * large, then the solution is a lousy estimate of truth and the
647 * estimated RCOND may be too optimistic. To avoid misleading users,
648 * the inverse condition number is set to 0.0 when the estimated
649 * cwise error is at least CWISE_WRONG.
650 *
651  cwise_wrong = sqrt( dlamch( 'Epsilon' ) )
652  DO j = 1, nrhs
653  IF (err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
654  $ THEN
655  rcond_tmp = zla_porcond_x( uplo, n, a, lda, af, ldaf,
656  $ x(1,j), info, work, rwork )
657  ELSE
658  rcond_tmp = 0.0d+0
659  END IF
660 *
661 * Cap the error at 1.0.
662 *
663  IF ( n_err_bnds .GE. la_linrx_err_i
664  $ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0d+0 )
665  $ err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
666 *
667 * Threshold the error (see LAWN).
668 *
669  IF (rcond_tmp .LT. illrcond_thresh) THEN
670  err_bnds_comp( j, la_linrx_err_i ) = 1.0d+0
671  err_bnds_comp( j, la_linrx_trust_i ) = 0.0d+0
672  IF ( params( la_linrx_cwise_i ) .EQ. 1.0d+0
673  $ .AND. info.LT.n + j ) info = n + j
674  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
675  $ .LT. err_lbnd ) THEN
676  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
677  err_bnds_comp( j, la_linrx_trust_i ) = 1.0d+0
678  END IF
679 *
680 * Save the condition number.
681 *
682  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
683  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
684  END IF
685 
686  END DO
687  END IF
688 *
689  RETURN
690 *
691 * End of ZPORFSX
692 *
subroutine zpocon(UPLO, N, A, LDA, ANORM, RCOND, WORK, RWORK, INFO)
ZPOCON
Definition: zpocon.f:123
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zla_porfsx_extended(PREC_TYPE, UPLO, N, NRHS, A, LDA, AF, LDAF, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
ZLA_PORFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric or H...
double precision function zlanhe(NORM, UPLO, N, A, LDA, WORK)
ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
Definition: zlanhe.f:126
double precision function zla_porcond_c(UPLO, N, A, LDA, AF, LDAF, C, CAPPLY, INFO, WORK, RWORK)
ZLA_PORCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian positiv...
double precision function zla_porcond_x(UPLO, N, A, LDA, AF, LDAF, X, INFO, WORK, RWORK)
ZLA_PORCOND_X computes the infinity norm condition number of op(A)*diag(x) for Hermitian positive-def...
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:60
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
Here is the call graph for this function:
Here is the caller graph for this function: