dpbt01()

subroutine dpbt01	(	character	uplo,
		integer	n,
		integer	kd,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldafac, * )	afac,
		integer	ldafac,
		double precision, dimension( * )	rwork,
		double precision	resid
	)

DPBT01

Purpose:

 DPBT01 reconstructs a symmetric positive definite band matrix A from
 its L*L' or U'*U factorization and computes the residual
    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
    norm( U'*U - A ) / ( N * norm(A) * EPS ),
 where EPS is the machine epsilon, L' is the conjugate transpose of
 L, and U' is the conjugate transpose of U.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of super-diagonals of the matrix A if UPLO = 'U', or the number of sub-diagonals if UPLO = 'L'. KD >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The original symmetric band matrix A. If UPLO = 'U', the upper triangular part of A is stored as a band matrix; if UPLO = 'L', the lower triangular part of A is stored. The columns of the appropriate triangle are stored in the columns of A and the diagonals of the triangle are stored in the rows of A. See DPBTRF for further details.
[in]	LDA	LDA is INTEGER. The leading dimension of the array A. LDA >= max(1,KD+1).
[in]	AFAC	AFAC is DOUBLE PRECISION array, dimension (LDAFAC,N) The factored form of the matrix A. AFAC contains the factor L or U from the L*L' or U'*U factorization in band storage format, as computed by DPBTRF.
[in]	LDAFAC	LDAFAC is INTEGER The leading dimension of the array AFAC. LDAFAC >= max(1,KD+1).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESID	RESID is DOUBLE PRECISION If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 117 of file dpbt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            KD, LDA, LDAFAC, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AFAC( LDAFAC, * ), RWORK( * )
*     ..
*
*  =====================================================================
*
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K, KC, KLEN, ML, MU
      DOUBLE PRECISION   ANORM, EPS, T
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DDOT, DLAMCH, DLANSB
      EXTERNAL           lsame, ddot, dlamch, dlansb
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dsyr, dtrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansb( '1', uplo, n, kd, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 k = n, 1, -1
            kc = max( 1, kd+2-k )
            klen = kd + 1 - kc
*
*           Compute the (K,K) element of the result.
*
            t = ddot( klen+1, afac( kc, k ), 1, afac( kc, k ), 1 )
            afac( kd+1, k ) = t
*
*           Compute the rest of column K.
*
            IF( klen.GT.0 )
     $         CALL dtrmv( 'Upper', 'Transpose', 'Non-unit', klen,
     $                     afac( kd+1, k-klen ), ldafac-1,
     $                     afac( kc, k ), 1 )
*
   10    CONTINUE
*
*     UPLO = 'L':  Compute the product L*L', overwriting L.
*
      ELSE
         DO 20 k = n, 1, -1
            klen = min( kd, n-k )
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( klen.GT.0 )
     $         CALL dsyr( 'Lower', klen, one, afac( 2, k ), 1,
     $                    afac( 1, k+1 ), ldafac-1 )
*
*           Scale column K by the diagonal element.
*
            t = afac( 1, k )
            CALL dscal( klen+1, t, afac( 1, k ), 1 )
*
   20    CONTINUE
      END IF
*
*     Compute the difference  L*L' - A  or  U'*U - A.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 40 j = 1, n
            mu = max( 1, kd+2-j )
            DO 30 i = mu, kd + 1
               afac( i, j ) = afac( i, j ) - a( i, j )
   30       CONTINUE
   40    CONTINUE
      ELSE
         DO 60 j = 1, n
            ml = min( kd+1, n-j+1 )
            DO 50 i = 1, ml
               afac( i, j ) = afac( i, j ) - a( i, j )
   50       CONTINUE
   60    CONTINUE
      END IF
*
*     Compute norm( L*L' - A ) / ( N * norm(A) * EPS )
*
      resid = dlansb( 'I', uplo, n, kd, afac, ldafac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of DPBT01
*

Here is the call graph for this function:

Here is the caller graph for this function: