LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
sgges3.f
Go to the documentation of this file.
1*> \brief <b> SGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices (blocked algorithm)</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SGGES3 + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgges3.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgges3.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgges3.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SGGES3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B,
22* $ LDB, SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL,
23* $ VSR, LDVSR, WORK, LWORK, BWORK, INFO )
24*
25* .. Scalar Arguments ..
26* CHARACTER JOBVSL, JOBVSR, SORT
27* INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
28* ..
29* .. Array Arguments ..
30* LOGICAL BWORK( * )
31* REAL A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
32* $ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
33* $ VSR( LDVSR, * ), WORK( * )
34* ..
35* .. Function Arguments ..
36* LOGICAL SELCTG
37* EXTERNAL SELCTG
38* ..
39*
40*
41*> \par Purpose:
42* =============
43*>
44*> \verbatim
45*>
46*> SGGES3 computes for a pair of N-by-N real nonsymmetric matrices (A,B),
47*> the generalized eigenvalues, the generalized real Schur form (S,T),
48*> optionally, the left and/or right matrices of Schur vectors (VSL and
49*> VSR). This gives the generalized Schur factorization
50*>
51*> (A,B) = ( (VSL)*S*(VSR)**T, (VSL)*T*(VSR)**T )
52*>
53*> Optionally, it also orders the eigenvalues so that a selected cluster
54*> of eigenvalues appears in the leading diagonal blocks of the upper
55*> quasi-triangular matrix S and the upper triangular matrix T.The
56*> leading columns of VSL and VSR then form an orthonormal basis for the
57*> corresponding left and right eigenspaces (deflating subspaces).
58*>
59*> (If only the generalized eigenvalues are needed, use the driver
60*> SGGEV instead, which is faster.)
61*>
62*> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
63*> or a ratio alpha/beta = w, such that A - w*B is singular. It is
64*> usually represented as the pair (alpha,beta), as there is a
65*> reasonable interpretation for beta=0 or both being zero.
66*>
67*> A pair of matrices (S,T) is in generalized real Schur form if T is
68*> upper triangular with non-negative diagonal and S is block upper
69*> triangular with 1-by-1 and 2-by-2 blocks. 1-by-1 blocks correspond
70*> to real generalized eigenvalues, while 2-by-2 blocks of S will be
71*> "standardized" by making the corresponding elements of T have the
72*> form:
73*> [ a 0 ]
74*> [ 0 b ]
75*>
76*> and the pair of corresponding 2-by-2 blocks in S and T will have a
77*> complex conjugate pair of generalized eigenvalues.
78*>
79*> \endverbatim
80*
81* Arguments:
82* ==========
83*
84*> \param[in] JOBVSL
85*> \verbatim
86*> JOBVSL is CHARACTER*1
87*> = 'N': do not compute the left Schur vectors;
88*> = 'V': compute the left Schur vectors.
89*> \endverbatim
90*>
91*> \param[in] JOBVSR
92*> \verbatim
93*> JOBVSR is CHARACTER*1
94*> = 'N': do not compute the right Schur vectors;
95*> = 'V': compute the right Schur vectors.
96*> \endverbatim
97*>
98*> \param[in] SORT
99*> \verbatim
100*> SORT is CHARACTER*1
101*> Specifies whether or not to order the eigenvalues on the
102*> diagonal of the generalized Schur form.
103*> = 'N': Eigenvalues are not ordered;
104*> = 'S': Eigenvalues are ordered (see SELCTG);
105*> \endverbatim
106*>
107*> \param[in] SELCTG
108*> \verbatim
109*> SELCTG is a LOGICAL FUNCTION of three REAL arguments
110*> SELCTG must be declared EXTERNAL in the calling subroutine.
111*> If SORT = 'N', SELCTG is not referenced.
112*> If SORT = 'S', SELCTG is used to select eigenvalues to sort
113*> to the top left of the Schur form.
114*> An eigenvalue (ALPHAR(j)+ALPHAI(j))/BETA(j) is selected if
115*> SELCTG(ALPHAR(j),ALPHAI(j),BETA(j)) is true; i.e. if either
116*> one of a complex conjugate pair of eigenvalues is selected,
117*> then both complex eigenvalues are selected.
118*>
119*> Note that in the ill-conditioned case, a selected complex
120*> eigenvalue may no longer satisfy SELCTG(ALPHAR(j),ALPHAI(j),
121*> BETA(j)) = .TRUE. after ordering. INFO is to be set to N+2
122*> in this case.
123*> \endverbatim
124*>
125*> \param[in] N
126*> \verbatim
127*> N is INTEGER
128*> The order of the matrices A, B, VSL, and VSR. N >= 0.
129*> \endverbatim
130*>
131*> \param[in,out] A
132*> \verbatim
133*> A is REAL array, dimension (LDA, N)
134*> On entry, the first of the pair of matrices.
135*> On exit, A has been overwritten by its generalized Schur
136*> form S.
137*> \endverbatim
138*>
139*> \param[in] LDA
140*> \verbatim
141*> LDA is INTEGER
142*> The leading dimension of A. LDA >= max(1,N).
143*> \endverbatim
144*>
145*> \param[in,out] B
146*> \verbatim
147*> B is REAL array, dimension (LDB, N)
148*> On entry, the second of the pair of matrices.
149*> On exit, B has been overwritten by its generalized Schur
150*> form T.
151*> \endverbatim
152*>
153*> \param[in] LDB
154*> \verbatim
155*> LDB is INTEGER
156*> The leading dimension of B. LDB >= max(1,N).
157*> \endverbatim
158*>
159*> \param[out] SDIM
160*> \verbatim
161*> SDIM is INTEGER
162*> If SORT = 'N', SDIM = 0.
163*> If SORT = 'S', SDIM = number of eigenvalues (after sorting)
164*> for which SELCTG is true. (Complex conjugate pairs for which
165*> SELCTG is true for either eigenvalue count as 2.)
166*> \endverbatim
167*>
168*> \param[out] ALPHAR
169*> \verbatim
170*> ALPHAR is REAL array, dimension (N)
171*> \endverbatim
172*>
173*> \param[out] ALPHAI
174*> \verbatim
175*> ALPHAI is REAL array, dimension (N)
176*> \endverbatim
177*>
178*> \param[out] BETA
179*> \verbatim
180*> BETA is REAL array, dimension (N)
181*> On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will
182*> be the generalized eigenvalues. ALPHAR(j) + ALPHAI(j)*i,
183*> and BETA(j),j=1,...,N are the diagonals of the complex Schur
184*> form (S,T) that would result if the 2-by-2 diagonal blocks of
185*> the real Schur form of (A,B) were further reduced to
186*> triangular form using 2-by-2 complex unitary transformations.
187*> If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
188*> positive, then the j-th and (j+1)-st eigenvalues are a
189*> complex conjugate pair, with ALPHAI(j+1) negative.
190*>
191*> Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j)
192*> may easily over- or underflow, and BETA(j) may even be zero.
193*> Thus, the user should avoid naively computing the ratio.
194*> However, ALPHAR and ALPHAI will be always less than and
195*> usually comparable with norm(A) in magnitude, and BETA always
196*> less than and usually comparable with norm(B).
197*> \endverbatim
198*>
199*> \param[out] VSL
200*> \verbatim
201*> VSL is REAL array, dimension (LDVSL,N)
202*> If JOBVSL = 'V', VSL will contain the left Schur vectors.
203*> Not referenced if JOBVSL = 'N'.
204*> \endverbatim
205*>
206*> \param[in] LDVSL
207*> \verbatim
208*> LDVSL is INTEGER
209*> The leading dimension of the matrix VSL. LDVSL >=1, and
210*> if JOBVSL = 'V', LDVSL >= N.
211*> \endverbatim
212*>
213*> \param[out] VSR
214*> \verbatim
215*> VSR is REAL array, dimension (LDVSR,N)
216*> If JOBVSR = 'V', VSR will contain the right Schur vectors.
217*> Not referenced if JOBVSR = 'N'.
218*> \endverbatim
219*>
220*> \param[in] LDVSR
221*> \verbatim
222*> LDVSR is INTEGER
223*> The leading dimension of the matrix VSR. LDVSR >= 1, and
224*> if JOBVSR = 'V', LDVSR >= N.
225*> \endverbatim
226*>
227*> \param[out] WORK
228*> \verbatim
229*> WORK is REAL array, dimension (MAX(1,LWORK))
230*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
231*> \endverbatim
232*>
233*> \param[in] LWORK
234*> \verbatim
235*> LWORK is INTEGER
236*> The dimension of the array WORK.
237*>
238*> If LWORK = -1, then a workspace query is assumed; the routine
239*> only calculates the optimal size of the WORK array, returns
240*> this value as the first entry of the WORK array, and no error
241*> message related to LWORK is issued by XERBLA.
242*> \endverbatim
243*>
244*> \param[out] BWORK
245*> \verbatim
246*> BWORK is LOGICAL array, dimension (N)
247*> Not referenced if SORT = 'N'.
248*> \endverbatim
249*>
250*> \param[out] INFO
251*> \verbatim
252*> INFO is INTEGER
253*> = 0: successful exit
254*> < 0: if INFO = -i, the i-th argument had an illegal value.
255*> = 1,...,N:
256*> The QZ iteration failed. (A,B) are not in Schur
257*> form, but ALPHAR(j), ALPHAI(j), and BETA(j) should
258*> be correct for j=INFO+1,...,N.
259*> > N: =N+1: other than QZ iteration failed in SLAQZ0.
260*> =N+2: after reordering, roundoff changed values of
261*> some complex eigenvalues so that leading
262*> eigenvalues in the Generalized Schur form no
263*> longer satisfy SELCTG=.TRUE. This could also
264*> be caused due to scaling.
265*> =N+3: reordering failed in STGSEN.
266*> \endverbatim
267*
268* Authors:
269* ========
270*
271*> \author Univ. of Tennessee
272*> \author Univ. of California Berkeley
273*> \author Univ. of Colorado Denver
274*> \author NAG Ltd.
275*
276*> \ingroup gges3
277*
278* =====================================================================
279 SUBROUTINE sgges3( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B,
280 $ LDB, SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL,
281 $ VSR, LDVSR, WORK, LWORK, BWORK, INFO )
282*
283* -- LAPACK driver routine --
284* -- LAPACK is a software package provided by Univ. of Tennessee, --
285* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
286*
287* .. Scalar Arguments ..
288 CHARACTER JOBVSL, JOBVSR, SORT
289 INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
290* ..
291* .. Array Arguments ..
292 LOGICAL BWORK( * )
293 REAL A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
294 $ b( ldb, * ), beta( * ), vsl( ldvsl, * ),
295 $ vsr( ldvsr, * ), work( * )
296* ..
297* .. Function Arguments ..
298 LOGICAL SELCTG
299 EXTERNAL SELCTG
300* ..
301*
302* =====================================================================
303*
304* .. Parameters ..
305 REAL ZERO, ONE
306 PARAMETER ( ZERO = 0.0e+0, one = 1.0e+0 )
307* ..
308* .. Local Scalars ..
309 LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
310 $ LQUERY, LST2SL, WANTST
311 INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
312 $ ILO, IP, IRIGHT, IROWS, ITAU, IWRK, LWKOPT
313 REAL ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
314 $ PVSR, SAFMAX, SAFMIN, SMLNUM
315* ..
316* .. Local Arrays ..
317 INTEGER IDUM( 1 )
318 REAL DIF( 2 )
319* ..
320* .. External Subroutines ..
321 EXTERNAL sgeqrf, sggbak, sggbal, sgghd3, slaqz0, slacpy,
323* ..
324* .. External Functions ..
325 LOGICAL LSAME
326 REAL SLAMCH, SLANGE, SROUNDUP_LWORK
327 EXTERNAL lsame, slamch, slange, sroundup_lwork
328* ..
329* .. Intrinsic Functions ..
330 INTRINSIC abs, max, sqrt
331* ..
332* .. Executable Statements ..
333*
334* Decode the input arguments
335*
336 IF( lsame( jobvsl, 'N' ) ) THEN
337 ijobvl = 1
338 ilvsl = .false.
339 ELSE IF( lsame( jobvsl, 'V' ) ) THEN
340 ijobvl = 2
341 ilvsl = .true.
342 ELSE
343 ijobvl = -1
344 ilvsl = .false.
345 END IF
346*
347 IF( lsame( jobvsr, 'N' ) ) THEN
348 ijobvr = 1
349 ilvsr = .false.
350 ELSE IF( lsame( jobvsr, 'V' ) ) THEN
351 ijobvr = 2
352 ilvsr = .true.
353 ELSE
354 ijobvr = -1
355 ilvsr = .false.
356 END IF
357*
358 wantst = lsame( sort, 'S' )
359*
360* Test the input arguments
361*
362 info = 0
363 lquery = ( lwork.EQ.-1 )
364 IF( ijobvl.LE.0 ) THEN
365 info = -1
366 ELSE IF( ijobvr.LE.0 ) THEN
367 info = -2
368 ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
369 info = -3
370 ELSE IF( n.LT.0 ) THEN
371 info = -5
372 ELSE IF( lda.LT.max( 1, n ) ) THEN
373 info = -7
374 ELSE IF( ldb.LT.max( 1, n ) ) THEN
375 info = -9
376 ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
377 info = -15
378 ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
379 info = -17
380 ELSE IF( lwork.LT.6*n+16 .AND. .NOT.lquery ) THEN
381 info = -19
382 END IF
383*
384* Compute workspace
385*
386 IF( info.EQ.0 ) THEN
387 CALL sgeqrf( n, n, b, ldb, work, work, -1, ierr )
388 lwkopt = max( 6*n+16, 3*n+int( work( 1 ) ) )
389 CALL sormqr( 'L', 'T', n, n, n, b, ldb, work, a, lda, work,
390 $ -1, ierr )
391 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
392 IF( ilvsl ) THEN
393 CALL sorgqr( n, n, n, vsl, ldvsl, work, work, -1, ierr )
394 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
395 END IF
396 CALL sgghd3( jobvsl, jobvsr, n, 1, n, a, lda, b, ldb, vsl,
397 $ ldvsl, vsr, ldvsr, work, -1, ierr )
398 lwkopt = max( lwkopt, 3*n+int( work( 1 ) ) )
399 CALL slaqz0( 'S', jobvsl, jobvsr, n, 1, n, a, lda, b, ldb,
400 $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
401 $ work, -1, 0, ierr )
402 lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
403 IF( wantst ) THEN
404 CALL stgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb,
405 $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
406 $ sdim, pvsl, pvsr, dif, work, -1, idum, 1,
407 $ ierr )
408 lwkopt = max( lwkopt, 2*n+int( work( 1 ) ) )
409 END IF
410 work( 1 ) = sroundup_lwork(lwkopt)
411 END IF
412*
413 IF( info.NE.0 ) THEN
414 CALL xerbla( 'SGGES3 ', -info )
415 RETURN
416 ELSE IF( lquery ) THEN
417 RETURN
418 END IF
419*
420* Quick return if possible
421*
422 IF( n.EQ.0 ) THEN
423 sdim = 0
424 RETURN
425 END IF
426*
427* Get machine constants
428*
429 eps = slamch( 'P' )
430 safmin = slamch( 'S' )
431 safmax = one / safmin
432 smlnum = sqrt( safmin ) / eps
433 bignum = one / smlnum
434*
435* Scale A if max element outside range [SMLNUM,BIGNUM]
436*
437 anrm = slange( 'M', n, n, a, lda, work )
438 ilascl = .false.
439 IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
440 anrmto = smlnum
441 ilascl = .true.
442 ELSE IF( anrm.GT.bignum ) THEN
443 anrmto = bignum
444 ilascl = .true.
445 END IF
446 IF( ilascl )
447 $ CALL slascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
448*
449* Scale B if max element outside range [SMLNUM,BIGNUM]
450*
451 bnrm = slange( 'M', n, n, b, ldb, work )
452 ilbscl = .false.
453 IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
454 bnrmto = smlnum
455 ilbscl = .true.
456 ELSE IF( bnrm.GT.bignum ) THEN
457 bnrmto = bignum
458 ilbscl = .true.
459 END IF
460 IF( ilbscl )
461 $ CALL slascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
462*
463* Permute the matrix to make it more nearly triangular
464*
465 ileft = 1
466 iright = n + 1
467 iwrk = iright + n
468 CALL sggbal( 'P', n, a, lda, b, ldb, ilo, ihi, work( ileft ),
469 $ work( iright ), work( iwrk ), ierr )
470*
471* Reduce B to triangular form (QR decomposition of B)
472*
473 irows = ihi + 1 - ilo
474 icols = n + 1 - ilo
475 itau = iwrk
476 iwrk = itau + irows
477 CALL sgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
478 $ work( iwrk ), lwork+1-iwrk, ierr )
479*
480* Apply the orthogonal transformation to matrix A
481*
482 CALL sormqr( 'L', 'T', irows, icols, irows, b( ilo, ilo ), ldb,
483 $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
484 $ lwork+1-iwrk, ierr )
485*
486* Initialize VSL
487*
488 IF( ilvsl ) THEN
489 CALL slaset( 'Full', n, n, zero, one, vsl, ldvsl )
490 IF( irows.GT.1 ) THEN
491 CALL slacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
492 $ vsl( ilo+1, ilo ), ldvsl )
493 END IF
494 CALL sorgqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
495 $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
496 END IF
497*
498* Initialize VSR
499*
500 IF( ilvsr )
501 $ CALL slaset( 'Full', n, n, zero, one, vsr, ldvsr )
502*
503* Reduce to generalized Hessenberg form
504*
505 CALL sgghd3( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
506 $ ldvsl, vsr, ldvsr, work( iwrk ), lwork+1-iwrk, ierr )
507*
508* Perform QZ algorithm, computing Schur vectors if desired
509*
510 iwrk = itau
511 CALL slaqz0( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
512 $ alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr,
513 $ work( iwrk ), lwork+1-iwrk, 0, ierr )
514 IF( ierr.NE.0 ) THEN
515 IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
516 info = ierr
517 ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
518 info = ierr - n
519 ELSE
520 info = n + 1
521 END IF
522 GO TO 40
523 END IF
524*
525* Sort eigenvalues ALPHA/BETA if desired
526*
527 sdim = 0
528 IF( wantst ) THEN
529*
530* Undo scaling on eigenvalues before SELCTGing
531*
532 IF( ilascl ) THEN
533 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n,
534 $ ierr )
535 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n,
536 $ ierr )
537 END IF
538 IF( ilbscl )
539 $ CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
540*
541* Select eigenvalues
542*
543 DO 10 i = 1, n
544 bwork( i ) = selctg( alphar( i ), alphai( i ), beta( i ) )
545 10 CONTINUE
546*
547 CALL stgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alphar,
548 $ alphai, beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl,
549 $ pvsr, dif, work( iwrk ), lwork-iwrk+1, idum, 1,
550 $ ierr )
551 IF( ierr.EQ.1 )
552 $ info = n + 3
553*
554 END IF
555*
556* Apply back-permutation to VSL and VSR
557*
558 IF( ilvsl )
559 $ CALL sggbak( 'P', 'L', n, ilo, ihi, work( ileft ),
560 $ work( iright ), n, vsl, ldvsl, ierr )
561*
562 IF( ilvsr )
563 $ CALL sggbak( 'P', 'R', n, ilo, ihi, work( ileft ),
564 $ work( iright ), n, vsr, ldvsr, ierr )
565*
566* Check if unscaling would cause over/underflow, if so, rescale
567* (ALPHAR(I),ALPHAI(I),BETA(I)) so BETA(I) is on the order of
568* B(I,I) and ALPHAR(I) and ALPHAI(I) are on the order of A(I,I)
569*
570 IF( ilascl )THEN
571 DO 50 i = 1, n
572 IF( alphai( i ).NE.zero ) THEN
573 IF( ( alphar( i )/safmax ).GT.( anrmto/anrm ) .OR.
574 $ ( safmin/alphar( i ) ).GT.( anrm/anrmto ) ) THEN
575 work( 1 ) = abs( a( i, i )/alphar( i ) )
576 beta( i ) = beta( i )*work( 1 )
577 alphar( i ) = alphar( i )*work( 1 )
578 alphai( i ) = alphai( i )*work( 1 )
579 ELSE IF( ( alphai( i )/safmax ).GT.( anrmto/anrm ) .OR.
580 $ ( safmin/alphai( i ) ).GT.( anrm/anrmto ) ) THEN
581 work( 1 ) = abs( a( i, i+1 )/alphai( i ) )
582 beta( i ) = beta( i )*work( 1 )
583 alphar( i ) = alphar( i )*work( 1 )
584 alphai( i ) = alphai( i )*work( 1 )
585 END IF
586 END IF
587 50 CONTINUE
588 END IF
589*
590 IF( ilbscl )THEN
591 DO 60 i = 1, n
592 IF( alphai( i ).NE.zero ) THEN
593 IF( ( beta( i )/safmax ).GT.( bnrmto/bnrm ) .OR.
594 $ ( safmin/beta( i ) ).GT.( bnrm/bnrmto ) ) THEN
595 work( 1 ) = abs(b( i, i )/beta( i ))
596 beta( i ) = beta( i )*work( 1 )
597 alphar( i ) = alphar( i )*work( 1 )
598 alphai( i ) = alphai( i )*work( 1 )
599 END IF
600 END IF
601 60 CONTINUE
602 END IF
603*
604* Undo scaling
605*
606 IF( ilascl ) THEN
607 CALL slascl( 'H', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
608 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n, ierr )
609 CALL slascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n, ierr )
610 END IF
611*
612 IF( ilbscl ) THEN
613 CALL slascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
614 CALL slascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
615 END IF
616*
617 IF( wantst ) THEN
618*
619* Check if reordering is correct
620*
621 lastsl = .true.
622 lst2sl = .true.
623 sdim = 0
624 ip = 0
625 DO 30 i = 1, n
626 cursl = selctg( alphar( i ), alphai( i ), beta( i ) )
627 IF( alphai( i ).EQ.zero ) THEN
628 IF( cursl )
629 $ sdim = sdim + 1
630 ip = 0
631 IF( cursl .AND. .NOT.lastsl )
632 $ info = n + 2
633 ELSE
634 IF( ip.EQ.1 ) THEN
635*
636* Last eigenvalue of conjugate pair
637*
638 cursl = cursl .OR. lastsl
639 lastsl = cursl
640 IF( cursl )
641 $ sdim = sdim + 2
642 ip = -1
643 IF( cursl .AND. .NOT.lst2sl )
644 $ info = n + 2
645 ELSE
646*
647* First eigenvalue of conjugate pair
648*
649 ip = 1
650 END IF
651 END IF
652 lst2sl = lastsl
653 lastsl = cursl
654 30 CONTINUE
655*
656 END IF
657*
658 40 CONTINUE
659*
660 work( 1 ) = sroundup_lwork(lwkopt)
661*
662 RETURN
663*
664* End of SGGES3
665*
666 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine sgeqrf(m, n, a, lda, tau, work, lwork, info)
SGEQRF
Definition sgeqrf.f:146
subroutine sggbak(job, side, n, ilo, ihi, lscale, rscale, m, v, ldv, info)
SGGBAK
Definition sggbak.f:147
subroutine sggbal(job, n, a, lda, b, ldb, ilo, ihi, lscale, rscale, work, info)
SGGBAL
Definition sggbal.f:177
subroutine sgges3(jobvsl, jobvsr, sort, selctg, n, a, lda, b, ldb, sdim, alphar, alphai, beta, vsl, ldvsl, vsr, ldvsr, work, lwork, bwork, info)
SGGES3 computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE ...
Definition sgges3.f:282
subroutine sgghd3(compq, compz, n, ilo, ihi, a, lda, b, ldb, q, ldq, z, ldz, work, lwork, info)
SGGHD3
Definition sgghd3.f:230
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:103
recursive subroutine slaqz0(wants, wantq, wantz, n, ilo, ihi, a, lda, b, ldb, alphar, alphai, beta, q, ldq, z, ldz, work, lwork, rec, info)
SLAQZ0
Definition slaqz0.f:304
subroutine slascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
SLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition slascl.f:143
subroutine slaset(uplo, m, n, alpha, beta, a, lda)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition slaset.f:110
subroutine stgsen(ijob, wantq, wantz, select, n, a, lda, b, ldb, alphar, alphai, beta, q, ldq, z, ldz, m, pl, pr, dif, work, lwork, iwork, liwork, info)
STGSEN
Definition stgsen.f:451
subroutine sorgqr(m, n, k, a, lda, tau, work, lwork, info)
SORGQR
Definition sorgqr.f:128
subroutine sormqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
SORMQR
Definition sormqr.f:168