LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zgebd2()

subroutine zgebd2 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  D,
double precision, dimension( * )  E,
complex*16, dimension( * )  TAUQ,
complex*16, dimension( * )  TAUP,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download ZGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZGEBD2 reduces a complex general m by n matrix A to upper or lower
 real bidiagonal form B by a unitary transformation: Q**H * A * P = B.

 If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
Parameters
[in]M
          M is INTEGER
          The number of rows in the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns in the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the m by n general matrix to be reduced.
          On exit,
          if m >= n, the diagonal and the first superdiagonal are
            overwritten with the upper bidiagonal matrix B; the
            elements below the diagonal, with the array TAUQ, represent
            the unitary matrix Q as a product of elementary
            reflectors, and the elements above the first superdiagonal,
            with the array TAUP, represent the unitary matrix P as
            a product of elementary reflectors;
          if m < n, the diagonal and the first subdiagonal are
            overwritten with the lower bidiagonal matrix B; the
            elements below the first subdiagonal, with the array TAUQ,
            represent the unitary matrix Q as a product of
            elementary reflectors, and the elements above the diagonal,
            with the array TAUP, represent the unitary matrix P as
            a product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]D
          D is DOUBLE PRECISION array, dimension (min(M,N))
          The diagonal elements of the bidiagonal matrix B:
          D(i) = A(i,i).
[out]E
          E is DOUBLE PRECISION array, dimension (min(M,N)-1)
          The off-diagonal elements of the bidiagonal matrix B:
          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
[out]TAUQ
          TAUQ is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the unitary matrix Q. See Further Details.
[out]TAUP
          TAUP is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the unitary matrix P. See Further Details.
[out]WORK
          WORK is COMPLEX*16 array, dimension (max(M,N))
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017
Further Details:
  The matrices Q and P are represented as products of elementary
  reflectors:

  If m >= n,

     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H

  where tauq and taup are complex scalars, and v and u are complex
  vectors; v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
  A(i+1:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
  A(i,i+2:n); tauq is stored in TAUQ(i) and taup in TAUP(i).

  If m < n,

     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H

  where tauq and taup are complex scalars, v and u are complex vectors;
  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  The contents of A on exit are illustrated by the following examples:

  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):

    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
    (  v1  v2  v3  v4  v5 )

  where d and e denote diagonal and off-diagonal elements of B, vi
  denotes an element of the vector defining H(i), and ui an element of
  the vector defining G(i).

Definition at line 191 of file zgebd2.f.

191 *
192 * -- LAPACK computational routine (version 3.7.1) --
193 * -- LAPACK is a software package provided by Univ. of Tennessee, --
194 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195 * June 2017
196 *
197 * .. Scalar Arguments ..
198  INTEGER info, lda, m, n
199 * ..
200 * .. Array Arguments ..
201  DOUBLE PRECISION d( * ), e( * )
202  COMPLEX*16 a( lda, * ), taup( * ), tauq( * ), work( * )
203 * ..
204 *
205 * =====================================================================
206 *
207 * .. Parameters ..
208  COMPLEX*16 zero, one
209  parameter( zero = ( 0.0d+0, 0.0d+0 ),
210  $ one = ( 1.0d+0, 0.0d+0 ) )
211 * ..
212 * .. Local Scalars ..
213  INTEGER i
214  COMPLEX*16 alpha
215 * ..
216 * .. External Subroutines ..
217  EXTERNAL xerbla, zlacgv, zlarf, zlarfg
218 * ..
219 * .. Intrinsic Functions ..
220  INTRINSIC dconjg, max, min
221 * ..
222 * .. Executable Statements ..
223 *
224 * Test the input parameters
225 *
226  info = 0
227  IF( m.LT.0 ) THEN
228  info = -1
229  ELSE IF( n.LT.0 ) THEN
230  info = -2
231  ELSE IF( lda.LT.max( 1, m ) ) THEN
232  info = -4
233  END IF
234  IF( info.LT.0 ) THEN
235  CALL xerbla( 'ZGEBD2', -info )
236  RETURN
237  END IF
238 *
239  IF( m.GE.n ) THEN
240 *
241 * Reduce to upper bidiagonal form
242 *
243  DO 10 i = 1, n
244 *
245 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
246 *
247  alpha = a( i, i )
248  CALL zlarfg( m-i+1, alpha, a( min( i+1, m ), i ), 1,
249  $ tauq( i ) )
250  d( i ) = alpha
251  a( i, i ) = one
252 *
253 * Apply H(i)**H to A(i:m,i+1:n) from the left
254 *
255  IF( i.LT.n )
256  $ CALL zlarf( 'Left', m-i+1, n-i, a( i, i ), 1,
257  $ dconjg( tauq( i ) ), a( i, i+1 ), lda, work )
258  a( i, i ) = d( i )
259 *
260  IF( i.LT.n ) THEN
261 *
262 * Generate elementary reflector G(i) to annihilate
263 * A(i,i+2:n)
264 *
265  CALL zlacgv( n-i, a( i, i+1 ), lda )
266  alpha = a( i, i+1 )
267  CALL zlarfg( n-i, alpha, a( i, min( i+2, n ) ), lda,
268  $ taup( i ) )
269  e( i ) = alpha
270  a( i, i+1 ) = one
271 *
272 * Apply G(i) to A(i+1:m,i+1:n) from the right
273 *
274  CALL zlarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
275  $ taup( i ), a( i+1, i+1 ), lda, work )
276  CALL zlacgv( n-i, a( i, i+1 ), lda )
277  a( i, i+1 ) = e( i )
278  ELSE
279  taup( i ) = zero
280  END IF
281  10 CONTINUE
282  ELSE
283 *
284 * Reduce to lower bidiagonal form
285 *
286  DO 20 i = 1, m
287 *
288 * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
289 *
290  CALL zlacgv( n-i+1, a( i, i ), lda )
291  alpha = a( i, i )
292  CALL zlarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
293  $ taup( i ) )
294  d( i ) = alpha
295  a( i, i ) = one
296 *
297 * Apply G(i) to A(i+1:m,i:n) from the right
298 *
299  IF( i.LT.m )
300  $ CALL zlarf( 'Right', m-i, n-i+1, a( i, i ), lda,
301  $ taup( i ), a( i+1, i ), lda, work )
302  CALL zlacgv( n-i+1, a( i, i ), lda )
303  a( i, i ) = d( i )
304 *
305  IF( i.LT.m ) THEN
306 *
307 * Generate elementary reflector H(i) to annihilate
308 * A(i+2:m,i)
309 *
310  alpha = a( i+1, i )
311  CALL zlarfg( m-i, alpha, a( min( i+2, m ), i ), 1,
312  $ tauq( i ) )
313  e( i ) = alpha
314  a( i+1, i ) = one
315 *
316 * Apply H(i)**H to A(i+1:m,i+1:n) from the left
317 *
318  CALL zlarf( 'Left', m-i, n-i, a( i+1, i ), 1,
319  $ dconjg( tauq( i ) ), a( i+1, i+1 ), lda,
320  $ work )
321  a( i+1, i ) = e( i )
322  ELSE
323  tauq( i ) = zero
324  END IF
325  20 CONTINUE
326  END IF
327  RETURN
328 *
329 * End of ZGEBD2
330 *
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
subroutine zlarfg(N, ALPHA, X, INCX, TAU)
ZLARFG generates an elementary reflector (Householder matrix).
Definition: zlarfg.f:108
Here is the call graph for this function:
Here is the caller graph for this function: