LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zgeqr2p()

subroutine zgeqr2p ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZGEQR2P computes the QR factorization of a general rectangular matrix with non-negative diagonal elements using an unblocked algorithm.

Download ZGEQR2P + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZGEQR2P computes a QR factorization of a complex m by n matrix A:
 A = Q * R. The diagonal entries of R are real and nonnegative.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the m by n matrix A.
          On exit, the elements on and above the diagonal of the array
          contain the min(m,n) by n upper trapezoidal matrix R (R is
          upper triangular if m >= n). The diagonal entries of R
          are real and nonnegative; the elements below the diagonal,
          with the array TAU, represent the unitary matrix Q as a
          product of elementary reflectors (see Further Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]TAU
          TAU is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors (see Further
          Details).
[out]WORK
          WORK is COMPLEX*16 array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(k), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
  and tau in TAU(i).

 See Lapack Working Note 203 for details

Definition at line 126 of file zgeqr2p.f.

126 *
127 * -- LAPACK computational routine (version 3.7.0) --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 * December 2016
131 *
132 * .. Scalar Arguments ..
133  INTEGER info, lda, m, n
134 * ..
135 * .. Array Arguments ..
136  COMPLEX*16 a( lda, * ), tau( * ), work( * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  COMPLEX*16 one
143  parameter( one = ( 1.0d+0, 0.0d+0 ) )
144 * ..
145 * .. Local Scalars ..
146  INTEGER i, k
147  COMPLEX*16 alpha
148 * ..
149 * .. External Subroutines ..
150  EXTERNAL xerbla, zlarf, zlarfgp
151 * ..
152 * .. Intrinsic Functions ..
153  INTRINSIC dconjg, max, min
154 * ..
155 * .. Executable Statements ..
156 *
157 * Test the input arguments
158 *
159  info = 0
160  IF( m.LT.0 ) THEN
161  info = -1
162  ELSE IF( n.LT.0 ) THEN
163  info = -2
164  ELSE IF( lda.LT.max( 1, m ) ) THEN
165  info = -4
166  END IF
167  IF( info.NE.0 ) THEN
168  CALL xerbla( 'ZGEQR2P', -info )
169  RETURN
170  END IF
171 *
172  k = min( m, n )
173 *
174  DO 10 i = 1, k
175 *
176 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
177 *
178  CALL zlarfgp( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
179  $ tau( i ) )
180  IF( i.LT.n ) THEN
181 *
182 * Apply H(i)**H to A(i:m,i+1:n) from the left
183 *
184  alpha = a( i, i )
185  a( i, i ) = one
186  CALL zlarf( 'Left', m-i+1, n-i, a( i, i ), 1,
187  $ dconjg( tau( i ) ), a( i, i+1 ), lda, work )
188  a( i, i ) = alpha
189  END IF
190  10 CONTINUE
191  RETURN
192 *
193 * End of ZGEQR2P
194 *
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:106
Here is the call graph for this function:
Here is the caller graph for this function: