LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ zgetrf2()

recursive subroutine zgetrf2 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
integer, dimension( * )  IPIV,
integer  INFO 
)

ZGETRF2

Purpose:
 ZGETRF2 computes an LU factorization of a general M-by-N matrix A
 using partial pivoting with row interchanges.

 The factorization has the form
    A = P * L * U
 where P is a permutation matrix, L is lower triangular with unit
 diagonal elements (lower trapezoidal if m > n), and U is upper
 triangular (upper trapezoidal if m < n).

 This is the recursive version of the algorithm. It divides
 the matrix into four submatrices:

        [  A11 | A12  ]  where A11 is n1 by n1 and A22 is n2 by n2
    A = [ -----|----- ]  with n1 = min(m,n)/2
        [  A21 | A22  ]       n2 = n-n1

                                       [ A11 ]
 The subroutine calls itself to factor [ --- ],
                                       [ A12 ]
                 [ A12 ]
 do the swaps on [ --- ], solve A12, update A22,
                 [ A22 ]

 then calls itself to factor A22 and do the swaps on A21.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the M-by-N matrix to be factored.
          On exit, the factors L and U from the factorization
          A = P*L*U; the unit diagonal elements of L are not stored.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]IPIV
          IPIV is INTEGER array, dimension (min(M,N))
          The pivot indices; for 1 <= i <= min(M,N), row i of the
          matrix was interchanged with row IPIV(i).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, U(i,i) is exactly zero. The factorization
                has been completed, but the factor U is exactly
                singular, and division by zero will occur if it is used
                to solve a system of equations.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 112 of file zgetrf2.f.

113 *
114 * -- LAPACK computational routine --
115 * -- LAPACK is a software package provided by Univ. of Tennessee, --
116 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
117 *
118 * .. Scalar Arguments ..
119  INTEGER INFO, LDA, M, N
120 * ..
121 * .. Array Arguments ..
122  INTEGER IPIV( * )
123  COMPLEX*16 A( LDA, * )
124 * ..
125 *
126 * =====================================================================
127 *
128 * .. Parameters ..
129  COMPLEX*16 ONE, ZERO
130  parameter( one = ( 1.0d+0, 0.0d+0 ),
131  $ zero = ( 0.0d+0, 0.0d+0 ) )
132 * ..
133 * .. Local Scalars ..
134  DOUBLE PRECISION SFMIN
135  COMPLEX*16 TEMP
136  INTEGER I, IINFO, N1, N2
137 * ..
138 * .. External Functions ..
139  DOUBLE PRECISION DLAMCH
140  INTEGER IZAMAX
141  EXTERNAL dlamch, izamax
142 * ..
143 * .. External Subroutines ..
144  EXTERNAL zgemm, zscal, zlaswp, ztrsm, xerbla
145 * ..
146 * .. Intrinsic Functions ..
147  INTRINSIC max, min
148 * ..
149 * .. Executable Statements ..
150 *
151 * Test the input parameters
152 *
153  info = 0
154  IF( m.LT.0 ) THEN
155  info = -1
156  ELSE IF( n.LT.0 ) THEN
157  info = -2
158  ELSE IF( lda.LT.max( 1, m ) ) THEN
159  info = -4
160  END IF
161  IF( info.NE.0 ) THEN
162  CALL xerbla( 'ZGETRF2', -info )
163  RETURN
164  END IF
165 *
166 * Quick return if possible
167 *
168  IF( m.EQ.0 .OR. n.EQ.0 )
169  $ RETURN
170 
171  IF ( m.EQ.1 ) THEN
172 *
173 * Use unblocked code for one row case
174 * Just need to handle IPIV and INFO
175 *
176  ipiv( 1 ) = 1
177  IF ( a(1,1).EQ.zero )
178  $ info = 1
179 *
180  ELSE IF( n.EQ.1 ) THEN
181 *
182 * Use unblocked code for one column case
183 *
184 *
185 * Compute machine safe minimum
186 *
187  sfmin = dlamch('S')
188 *
189 * Find pivot and test for singularity
190 *
191  i = izamax( m, a( 1, 1 ), 1 )
192  ipiv( 1 ) = i
193  IF( a( i, 1 ).NE.zero ) THEN
194 *
195 * Apply the interchange
196 *
197  IF( i.NE.1 ) THEN
198  temp = a( 1, 1 )
199  a( 1, 1 ) = a( i, 1 )
200  a( i, 1 ) = temp
201  END IF
202 *
203 * Compute elements 2:M of the column
204 *
205  IF( abs(a( 1, 1 )) .GE. sfmin ) THEN
206  CALL zscal( m-1, one / a( 1, 1 ), a( 2, 1 ), 1 )
207  ELSE
208  DO 10 i = 1, m-1
209  a( 1+i, 1 ) = a( 1+i, 1 ) / a( 1, 1 )
210  10 CONTINUE
211  END IF
212 *
213  ELSE
214  info = 1
215  END IF
216 
217  ELSE
218 *
219 * Use recursive code
220 *
221  n1 = min( m, n ) / 2
222  n2 = n-n1
223 *
224 * [ A11 ]
225 * Factor [ --- ]
226 * [ A21 ]
227 *
228  CALL zgetrf2( m, n1, a, lda, ipiv, iinfo )
229 
230  IF ( info.EQ.0 .AND. iinfo.GT.0 )
231  $ info = iinfo
232 *
233 * [ A12 ]
234 * Apply interchanges to [ --- ]
235 * [ A22 ]
236 *
237  CALL zlaswp( n2, a( 1, n1+1 ), lda, 1, n1, ipiv, 1 )
238 *
239 * Solve A12
240 *
241  CALL ztrsm( 'L', 'L', 'N', 'U', n1, n2, one, a, lda,
242  $ a( 1, n1+1 ), lda )
243 *
244 * Update A22
245 *
246  CALL zgemm( 'N', 'N', m-n1, n2, n1, -one, a( n1+1, 1 ), lda,
247  $ a( 1, n1+1 ), lda, one, a( n1+1, n1+1 ), lda )
248 *
249 * Factor A22
250 *
251  CALL zgetrf2( m-n1, n2, a( n1+1, n1+1 ), lda, ipiv( n1+1 ),
252  $ iinfo )
253 *
254 * Adjust INFO and the pivot indices
255 *
256  IF ( info.EQ.0 .AND. iinfo.GT.0 )
257  $ info = iinfo + n1
258  DO 20 i = n1+1, min( m, n )
259  ipiv( i ) = ipiv( i ) + n1
260  20 CONTINUE
261 *
262 * Apply interchanges to A21
263 *
264  CALL zlaswp( n1, a( 1, 1 ), lda, n1+1, min( m, n), ipiv, 1 )
265 *
266  END IF
267  RETURN
268 *
269 * End of ZGETRF2
270 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
integer function izamax(N, ZX, INCX)
IZAMAX
Definition: izamax.f:71
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:78
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:187
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:180
recursive subroutine zgetrf2(M, N, A, LDA, IPIV, INFO)
ZGETRF2
Definition: zgetrf2.f:113
subroutine zlaswp(N, A, LDA, K1, K2, IPIV, INCX)
ZLASWP performs a series of row interchanges on a general rectangular matrix.
Definition: zlaswp.f:115
Here is the call graph for this function:
Here is the caller graph for this function: