LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
slansb.f
Go to the documentation of this file.
1 *> \brief \b SLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric band matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLANSB + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slansb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slansb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slansb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION SLANSB( NORM, UPLO, N, K, AB, LDAB,
22 * WORK )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER NORM, UPLO
26 * INTEGER K, LDAB, N
27 * ..
28 * .. Array Arguments ..
29 * REAL AB( LDAB, * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> SLANSB returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of an
40 *> n by n symmetric band matrix A, with k super-diagonals.
41 *> \endverbatim
42 *>
43 *> \return SLANSB
44 *> \verbatim
45 *>
46 *> SLANSB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in SLANSB as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> band matrix A is supplied.
75 *> = 'U': Upper triangular part is supplied
76 *> = 'L': Lower triangular part is supplied
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, SLANSB is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] K
87 *> \verbatim
88 *> K is INTEGER
89 *> The number of super-diagonals or sub-diagonals of the
90 *> band matrix A. K >= 0.
91 *> \endverbatim
92 *>
93 *> \param[in] AB
94 *> \verbatim
95 *> AB is REAL array, dimension (LDAB,N)
96 *> The upper or lower triangle of the symmetric band matrix A,
97 *> stored in the first K+1 rows of AB. The j-th column of A is
98 *> stored in the j-th column of the array AB as follows:
99 *> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
100 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
101 *> \endverbatim
102 *>
103 *> \param[in] LDAB
104 *> \verbatim
105 *> LDAB is INTEGER
106 *> The leading dimension of the array AB. LDAB >= K+1.
107 *> \endverbatim
108 *>
109 *> \param[out] WORK
110 *> \verbatim
111 *> WORK is REAL array, dimension (MAX(1,LWORK)),
112 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
113 *> WORK is not referenced.
114 *> \endverbatim
115 *
116 * Authors:
117 * ========
118 *
119 *> \author Univ. of Tennessee
120 *> \author Univ. of California Berkeley
121 *> \author Univ. of Colorado Denver
122 *> \author NAG Ltd.
123 *
124 *> \ingroup realOTHERauxiliary
125 *
126 * =====================================================================
127  REAL function slansb( norm, uplo, n, k, ab, ldab,
128  $ work )
129 *
130 * -- LAPACK auxiliary routine --
131 * -- LAPACK is a software package provided by Univ. of Tennessee, --
132 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
133 *
134 * .. Scalar Arguments ..
135  CHARACTER norm, uplo
136  INTEGER k, ldab, n
137 * ..
138 * .. Array Arguments ..
139  REAL ab( ldab, * ), work( * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  REAL one, zero
146  parameter( one = 1.0e+0, zero = 0.0e+0 )
147 * ..
148 * .. Local Scalars ..
149  INTEGER i, j, l
150  REAL absa, scale, sum, value
151 * ..
152 * .. External Subroutines ..
153  EXTERNAL slassq
154 * ..
155 * .. External Functions ..
156  LOGICAL lsame, sisnan
157  EXTERNAL lsame, sisnan
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC abs, max, min, sqrt
161 * ..
162 * .. Executable Statements ..
163 *
164  IF( n.EQ.0 ) THEN
165  VALUE = zero
166  ELSE IF( lsame( norm, 'M' ) ) THEN
167 *
168 * Find max(abs(A(i,j))).
169 *
170  VALUE = zero
171  IF( lsame( uplo, 'U' ) ) THEN
172  DO 20 j = 1, n
173  DO 10 i = max( k+2-j, 1 ), k + 1
174  sum = abs( ab( i, j ) )
175  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
176  10 CONTINUE
177  20 CONTINUE
178  ELSE
179  DO 40 j = 1, n
180  DO 30 i = 1, min( n+1-j, k+1 )
181  sum = abs( ab( i, j ) )
182  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
183  30 CONTINUE
184  40 CONTINUE
185  END IF
186  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
187  $ ( norm.EQ.'1' ) ) THEN
188 *
189 * Find normI(A) ( = norm1(A), since A is symmetric).
190 *
191  VALUE = zero
192  IF( lsame( uplo, 'U' ) ) THEN
193  DO 60 j = 1, n
194  sum = zero
195  l = k + 1 - j
196  DO 50 i = max( 1, j-k ), j - 1
197  absa = abs( ab( l+i, j ) )
198  sum = sum + absa
199  work( i ) = work( i ) + absa
200  50 CONTINUE
201  work( j ) = sum + abs( ab( k+1, j ) )
202  60 CONTINUE
203  DO 70 i = 1, n
204  sum = work( i )
205  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
206  70 CONTINUE
207  ELSE
208  DO 80 i = 1, n
209  work( i ) = zero
210  80 CONTINUE
211  DO 100 j = 1, n
212  sum = work( j ) + abs( ab( 1, j ) )
213  l = 1 - j
214  DO 90 i = j + 1, min( n, j+k )
215  absa = abs( ab( l+i, j ) )
216  sum = sum + absa
217  work( i ) = work( i ) + absa
218  90 CONTINUE
219  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
220  100 CONTINUE
221  END IF
222  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
223 *
224 * Find normF(A).
225 *
226  scale = zero
227  sum = one
228  IF( k.GT.0 ) THEN
229  IF( lsame( uplo, 'U' ) ) THEN
230  DO 110 j = 2, n
231  CALL slassq( min( j-1, k ), ab( max( k+2-j, 1 ), j ),
232  $ 1, scale, sum )
233  110 CONTINUE
234  l = k + 1
235  ELSE
236  DO 120 j = 1, n - 1
237  CALL slassq( min( n-j, k ), ab( 2, j ), 1, scale,
238  $ sum )
239  120 CONTINUE
240  l = 1
241  END IF
242  sum = 2*sum
243  ELSE
244  l = 1
245  END IF
246  CALL slassq( n, ab( l, 1 ), ldab, scale, sum )
247  VALUE = scale*sqrt( sum )
248  END IF
249 *
250  slansb = VALUE
251  RETURN
252 *
253 * End of SLANSB
254 *
255  END
subroutine slassq(n, x, incx, scl, sumsq)
SLASSQ updates a sum of squares represented in scaled form.
Definition: slassq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function slansb(NORM, UPLO, N, K, AB, LDAB, WORK)
SLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: slansb.f:129