LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zunm2l.f
Go to the documentation of this file.
1*> \brief \b ZUNM2L multiplies a general matrix by the unitary matrix from a QL factorization determined by cgeqlf (unblocked algorithm).
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download ZUNM2L + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunm2l.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunm2l.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunm2l.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE ZUNM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22* WORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER SIDE, TRANS
26* INTEGER INFO, K, LDA, LDC, M, N
27* ..
28* .. Array Arguments ..
29* COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> ZUNM2L overwrites the general complex m-by-n matrix C with
39*>
40*> Q * C if SIDE = 'L' and TRANS = 'N', or
41*>
42*> Q**H* C if SIDE = 'L' and TRANS = 'C', or
43*>
44*> C * Q if SIDE = 'R' and TRANS = 'N', or
45*>
46*> C * Q**H if SIDE = 'R' and TRANS = 'C',
47*>
48*> where Q is a complex unitary matrix defined as the product of k
49*> elementary reflectors
50*>
51*> Q = H(k) . . . H(2) H(1)
52*>
53*> as returned by ZGEQLF. Q is of order m if SIDE = 'L' and of order n
54*> if SIDE = 'R'.
55*> \endverbatim
56*
57* Arguments:
58* ==========
59*
60*> \param[in] SIDE
61*> \verbatim
62*> SIDE is CHARACTER*1
63*> = 'L': apply Q or Q**H from the Left
64*> = 'R': apply Q or Q**H from the Right
65*> \endverbatim
66*>
67*> \param[in] TRANS
68*> \verbatim
69*> TRANS is CHARACTER*1
70*> = 'N': apply Q (No transpose)
71*> = 'C': apply Q**H (Conjugate transpose)
72*> \endverbatim
73*>
74*> \param[in] M
75*> \verbatim
76*> M is INTEGER
77*> The number of rows of the matrix C. M >= 0.
78*> \endverbatim
79*>
80*> \param[in] N
81*> \verbatim
82*> N is INTEGER
83*> The number of columns of the matrix C. N >= 0.
84*> \endverbatim
85*>
86*> \param[in] K
87*> \verbatim
88*> K is INTEGER
89*> The number of elementary reflectors whose product defines
90*> the matrix Q.
91*> If SIDE = 'L', M >= K >= 0;
92*> if SIDE = 'R', N >= K >= 0.
93*> \endverbatim
94*>
95*> \param[in] A
96*> \verbatim
97*> A is COMPLEX*16 array, dimension (LDA,K)
98*> The i-th column must contain the vector which defines the
99*> elementary reflector H(i), for i = 1,2,...,k, as returned by
100*> ZGEQLF in the last k columns of its array argument A.
101*> A is modified by the routine but restored on exit.
102*> \endverbatim
103*>
104*> \param[in] LDA
105*> \verbatim
106*> LDA is INTEGER
107*> The leading dimension of the array A.
108*> If SIDE = 'L', LDA >= max(1,M);
109*> if SIDE = 'R', LDA >= max(1,N).
110*> \endverbatim
111*>
112*> \param[in] TAU
113*> \verbatim
114*> TAU is COMPLEX*16 array, dimension (K)
115*> TAU(i) must contain the scalar factor of the elementary
116*> reflector H(i), as returned by ZGEQLF.
117*> \endverbatim
118*>
119*> \param[in,out] C
120*> \verbatim
121*> C is COMPLEX*16 array, dimension (LDC,N)
122*> On entry, the m-by-n matrix C.
123*> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
124*> \endverbatim
125*>
126*> \param[in] LDC
127*> \verbatim
128*> LDC is INTEGER
129*> The leading dimension of the array C. LDC >= max(1,M).
130*> \endverbatim
131*>
132*> \param[out] WORK
133*> \verbatim
134*> WORK is COMPLEX*16 array, dimension
135*> (N) if SIDE = 'L',
136*> (M) if SIDE = 'R'
137*> \endverbatim
138*>
139*> \param[out] INFO
140*> \verbatim
141*> INFO is INTEGER
142*> = 0: successful exit
143*> < 0: if INFO = -i, the i-th argument had an illegal value
144*> \endverbatim
145*
146* Authors:
147* ========
148*
149*> \author Univ. of Tennessee
150*> \author Univ. of California Berkeley
151*> \author Univ. of Colorado Denver
152*> \author NAG Ltd.
153*
154*> \ingroup unm2l
155*
156* =====================================================================
157 SUBROUTINE zunm2l( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
158 $ WORK, INFO )
159*
160* -- LAPACK computational routine --
161* -- LAPACK is a software package provided by Univ. of Tennessee, --
162* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
163*
164* .. Scalar Arguments ..
165 CHARACTER SIDE, TRANS
166 INTEGER INFO, K, LDA, LDC, M, N
167* ..
168* .. Array Arguments ..
169 COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
170* ..
171*
172* =====================================================================
173*
174* .. Parameters ..
175 COMPLEX*16 ONE
176 parameter( one = ( 1.0d+0, 0.0d+0 ) )
177* ..
178* .. Local Scalars ..
179 LOGICAL LEFT, NOTRAN
180 INTEGER I, I1, I2, I3, MI, NI, NQ
181 COMPLEX*16 AII, TAUI
182* ..
183* .. External Functions ..
184 LOGICAL LSAME
185 EXTERNAL lsame
186* ..
187* .. External Subroutines ..
188 EXTERNAL xerbla, zlarf
189* ..
190* .. Intrinsic Functions ..
191 INTRINSIC dconjg, max
192* ..
193* .. Executable Statements ..
194*
195* Test the input arguments
196*
197 info = 0
198 left = lsame( side, 'L' )
199 notran = lsame( trans, 'N' )
200*
201* NQ is the order of Q
202*
203 IF( left ) THEN
204 nq = m
205 ELSE
206 nq = n
207 END IF
208 IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
209 info = -1
210 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
211 info = -2
212 ELSE IF( m.LT.0 ) THEN
213 info = -3
214 ELSE IF( n.LT.0 ) THEN
215 info = -4
216 ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
217 info = -5
218 ELSE IF( lda.LT.max( 1, nq ) ) THEN
219 info = -7
220 ELSE IF( ldc.LT.max( 1, m ) ) THEN
221 info = -10
222 END IF
223 IF( info.NE.0 ) THEN
224 CALL xerbla( 'ZUNM2L', -info )
225 RETURN
226 END IF
227*
228* Quick return if possible
229*
230 IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
231 $ RETURN
232*
233 IF( ( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) ) THEN
234 i1 = 1
235 i2 = k
236 i3 = 1
237 ELSE
238 i1 = k
239 i2 = 1
240 i3 = -1
241 END IF
242*
243 IF( left ) THEN
244 ni = n
245 ELSE
246 mi = m
247 END IF
248*
249 DO 10 i = i1, i2, i3
250 IF( left ) THEN
251*
252* H(i) or H(i)**H is applied to C(1:m-k+i,1:n)
253*
254 mi = m - k + i
255 ELSE
256*
257* H(i) or H(i)**H is applied to C(1:m,1:n-k+i)
258*
259 ni = n - k + i
260 END IF
261*
262* Apply H(i) or H(i)**H
263*
264 IF( notran ) THEN
265 taui = tau( i )
266 ELSE
267 taui = dconjg( tau( i ) )
268 END IF
269 aii = a( nq-k+i, i )
270 a( nq-k+i, i ) = one
271 CALL zlarf( side, mi, ni, a( 1, i ), 1, taui, c, ldc, work )
272 a( nq-k+i, i ) = aii
273 10 CONTINUE
274 RETURN
275*
276* End of ZUNM2L
277*
278 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zlarf(side, m, n, v, incv, tau, c, ldc, work)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition zlarf.f:128
subroutine zunm2l(side, trans, m, n, k, a, lda, tau, c, ldc, work, info)
ZUNM2L multiplies a general matrix by the unitary matrix from a QL factorization determined by cgeqlf...
Definition zunm2l.f:159