zchkpb()

subroutine zchkpb	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		logical	tsterr,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	afac,
		complex*16, dimension( * )	ainv,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer	nout
	)

ZCHKPB

Purpose:

 ZCHKPB tests ZPBTRF, -TRS, -RFS, and -CON.

Parameters

[in]	DOTYPE	DOTYPE is LOGICAL array, dimension (NTYPES) The matrix types to be used for testing. Matrices of type j (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB contained in the vector NBVAL.
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NNS	NNS is INTEGER The number of values of NRHS contained in the vector NSVAL.
[in]	NSVAL	NSVAL is INTEGER array, dimension (NNS) The values of the number of right hand sides NRHS.
[in]	THRESH	THRESH is DOUBLE PRECISION The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for N, used in dimensioning the work arrays.
[out]	A	A is DOUBLE PRECISION array, dimension (NMAX*NMAX)
[out]	AFAC	AFAC is DOUBLE PRECISION array, dimension (NMAX*NMAX)
[out]	AINV	AINV is DOUBLE PRECISION array, dimension (NMAX*NMAX)
[out]	B	B is DOUBLE PRECISION array, dimension (NMAX*NSMAX) where NSMAX is the largest entry in NSVAL.
[out]	X	X is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
[out]	XACT	XACT is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (NMAX*max(3,NSMAX))
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (max(NMAX,2*NSMAX))
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 165 of file zchkpb.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NBVAL( * ), NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES, NTESTS
      parameter( ntypes = 8, ntests = 7 )
      INTEGER            NBW
      parameter( nbw = 4 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, PACKIT, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, I1, I2, IKD, IMAT, IN, INB, INFO, IOFF,
     $                   IRHS, IUPLO, IW, IZERO, K, KD, KL, KOFF, KU,
     $                   LDA, LDAB, MODE, N, NB, NERRS, NFAIL, NIMAT,
     $                   NKD, NRHS, NRUN
      DOUBLE PRECISION   AINVNM, ANORM, CNDNUM, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 ), KDVAL( NBW )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DGET06, ZLANGE, ZLANHB
      EXTERNAL           dget06, zlange, zlanhb
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, xlaenv, zcopy, zerrpo,
     $                   zget04, zlacpy, zlaipd, zlarhs, zlaset, zlatb4,
     $                   zlatms, zpbcon, zpbrfs, zpbt01, zpbt02, zpbt05,
     $                   zpbtrf, zpbtrs, zswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'PB'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrpo( path, nout )
      infot = 0
      kdval( 1 ) = 0
*
*     Do for each value of N in NVAL
*
      DO 90 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
*
*        Set limits on the number of loop iterations.
*
         nkd = max( 1, min( n, 4 ) )
         nimat = ntypes
         IF( n.EQ.0 )
     $      nimat = 1
*
         kdval( 2 ) = n + ( n+1 ) / 4
         kdval( 3 ) = ( 3*n-1 ) / 4
         kdval( 4 ) = ( n+1 ) / 4
*
         DO 80 ikd = 1, nkd
*
*           Do for KD = 0, (5*N+1)/4, (3N-1)/4, and (N+1)/4. This order
*           makes it easier to skip redundant values for small values
*           of N.
*
            kd = kdval( ikd )
            ldab = kd + 1
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 70 iuplo = 1, 2
               koff = 1
               IF( iuplo.EQ.1 ) THEN
                  uplo = 'U'
                  koff = max( 1, kd+2-n )
                  packit = 'Q'
               ELSE
                  uplo = 'L'
                  packit = 'B'
               END IF
*
               DO 60 imat = 1, nimat
*
*                 Do the tests only if DOTYPE( IMAT ) is true.
*
                  IF( .NOT.dotype( imat ) )
     $               GO TO 60
*
*                 Skip types 2, 3, or 4 if the matrix size is too small.
*
                  zerot = imat.GE.2 .AND. imat.LE.4
                  IF( zerot .AND. n.LT.imat-1 )
     $               GO TO 60
*
                  IF( .NOT.zerot .OR. .NOT.dotype( 1 ) ) THEN
*
*                    Set up parameters with ZLATB4 and generate a test
*                    matrix with ZLATMS.
*
                     CALL zlatb4( path, imat, n, n, TYPE, KL, KU, ANORM,
     $                            MODE, CNDNUM, DIST )
*
                     srnamt = 'ZLATMS'
                     CALL zlatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                            CNDNUM, ANORM, KD, KD, PACKIT,
     $                            A( KOFF ), LDAB, WORK, INFO )
*
*                    Check error code from ZLATMS.
*
                     IF( info.NE.0 ) THEN
                        CALL alaerh( path, 'ZLATMS', info, 0, uplo, n,
     $                               n, kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
                        GO TO 60
                     END IF
                  ELSE IF( izero.GT.0 ) THEN
*
*                    Use the same matrix for types 3 and 4 as for type
*                    2 by copying back the zeroed out column,
*
                     iw = 2*lda + 1
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*ldab + kd + 1
                        CALL zcopy( izero-i1, work( iw ), 1,
     $                              a( ioff-izero+i1 ), 1 )
                        iw = iw + izero - i1
                        CALL zcopy( i2-izero+1, work( iw ), 1,
     $                              a( ioff ), max( ldab-1, 1 ) )
                     ELSE
                        ioff = ( i1-1 )*ldab + 1
                        CALL zcopy( izero-i1, work( iw ), 1,
     $                              a( ioff+izero-i1 ),
     $                              max( ldab-1, 1 ) )
                        ioff = ( izero-1 )*ldab + 1
                        iw = iw + izero - i1
                        CALL zcopy( i2-izero+1, work( iw ), 1,
     $                              a( ioff ), 1 )
                     END IF
                  END IF
*
*                 For types 2-4, zero one row and column of the matrix
*                 to test that INFO is returned correctly.
*
                  izero = 0
                  IF( zerot ) THEN
                     IF( imat.EQ.2 ) THEN
                        izero = 1
                     ELSE IF( imat.EQ.3 ) THEN
                        izero = n
                     ELSE
                        izero = n / 2 + 1
                     END IF
*
*                    Save the zeroed out row and column in WORK(*,3)
*
                     iw = 2*lda
                     DO 20 i = 1, min( 2*kd+1, n )
                        work( iw+i ) = zero
   20                CONTINUE
                     iw = iw + 1
                     i1 = max( izero-kd, 1 )
                     i2 = min( izero+kd, n )
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*ldab + kd + 1
                        CALL zswap( izero-i1, a( ioff-izero+i1 ), 1,
     $                              work( iw ), 1 )
                        iw = iw + izero - i1
                        CALL zswap( i2-izero+1, a( ioff ),
     $                              max( ldab-1, 1 ), work( iw ), 1 )
                     ELSE
                        ioff = ( i1-1 )*ldab + 1
                        CALL zswap( izero-i1, a( ioff+izero-i1 ),
     $                              max( ldab-1, 1 ), work( iw ), 1 )
                        ioff = ( izero-1 )*ldab + 1
                        iw = iw + izero - i1
                        CALL zswap( i2-izero+1, a( ioff ), 1,
     $                              work( iw ), 1 )
                     END IF
                  END IF
*
*                 Set the imaginary part of the diagonals.
*
                  IF( iuplo.EQ.1 ) THEN
                     CALL zlaipd( n, a( kd+1 ), ldab, 0 )
                  ELSE
                     CALL zlaipd( n, a( 1 ), ldab, 0 )
                  END IF
*
*                 Do for each value of NB in NBVAL
*
                  DO 50 inb = 1, nnb
                     nb = nbval( inb )
                     CALL xlaenv( 1, nb )
*
*                    Compute the L*L' or U'*U factorization of the band
*                    matrix.
*
                     CALL zlacpy( 'Full', kd+1, n, a, ldab, afac, ldab )
                     srnamt = 'ZPBTRF'
                     CALL zpbtrf( uplo, n, kd, afac, ldab, info )
*
*                    Check error code from ZPBTRF.
*
                     IF( info.NE.izero ) THEN
                        CALL alaerh( path, 'ZPBTRF', info, izero, uplo,
     $                               n, n, kd, kd, nb, imat, nfail,
     $                               nerrs, nout )
                        GO TO 50
                     END IF
*
*                    Skip the tests if INFO is not 0.
*
                     IF( info.NE.0 )
     $                  GO TO 50
*
*+    TEST 1
*                    Reconstruct matrix from factors and compute
*                    residual.
*
                     CALL zlacpy( 'Full', kd+1, n, afac, ldab, ainv,
     $                            ldab )
                     CALL zpbt01( uplo, n, kd, a, ldab, ainv, ldab,
     $                            rwork, result( 1 ) )
*
*                    Print the test ratio if it is .GE. THRESH.
*
                     IF( result( 1 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, kd, nb, imat,
     $                     1, result( 1 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
*
*                    Only do other tests if this is the first blocksize.
*
                     IF( inb.GT.1 )
     $                  GO TO 50
*
*                    Form the inverse of A so we can get a good estimate
*                    of RCONDC = 1/(norm(A) * norm(inv(A))).
*
                     CALL zlaset( 'Full', n, n, dcmplx( zero ),
     $                            dcmplx( one ), ainv, lda )
                     srnamt = 'ZPBTRS'
                     CALL zpbtrs( uplo, n, kd, n, afac, ldab, ainv, lda,
     $                            info )
*
*                    Compute RCONDC = 1/(norm(A) * norm(inv(A))).
*
                     anorm = zlanhb( '1', uplo, n, kd, a, ldab, rwork )
                     ainvnm = zlange( '1', n, n, ainv, lda, rwork )
                     IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                        rcondc = one
                     ELSE
                        rcondc = ( one / anorm ) / ainvnm
                     END IF
*
                     DO 40 irhs = 1, nns
                        nrhs = nsval( irhs )
*
*+    TEST 2
*                    Solve and compute residual for A * X = B.
*
                        srnamt = 'ZLARHS'
                        CALL zlarhs( path, xtype, uplo, ' ', n, n, kd,
     $                               kd, nrhs, a, ldab, xact, lda, b,
     $                               lda, iseed, info )
                        CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'ZPBTRS'
                        CALL zpbtrs( uplo, n, kd, nrhs, afac, ldab, x,
     $                               lda, info )
*
*                    Check error code from ZPBTRS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZPBTRS', info, 0, uplo,
     $                                  n, n, kd, kd, nrhs, imat, nfail,
     $                                  nerrs, nout )
*
                        CALL zlacpy( 'Full', n, nrhs, b, lda, work,
     $                               lda )
                        CALL zpbt02( uplo, n, kd, nrhs, a, ldab, x, lda,
     $                               work, lda, rwork, result( 2 ) )
*
*+    TEST 3
*                    Check solution from generated exact solution.
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
*
*+    TESTS 4, 5, and 6
*                    Use iterative refinement to improve the solution.
*
                        srnamt = 'ZPBRFS'
                        CALL zpbrfs( uplo, n, kd, nrhs, a, ldab, afac,
     $                               ldab, b, lda, x, lda, rwork,
     $                               rwork( nrhs+1 ), work,
     $                               rwork( 2*nrhs+1 ), info )
*
*                    Check error code from ZPBRFS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZPBRFS', info, 0, uplo,
     $                                  n, n, kd, kd, nrhs, imat, nfail,
     $                                  nerrs, nout )
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 4 ) )
                        CALL zpbt05( uplo, n, kd, nrhs, a, ldab, b, lda,
     $                               x, lda, xact, lda, rwork,
     $                               rwork( nrhs+1 ), result( 5 ) )
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 30 k = 2, 6
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9998 )uplo, n, kd,
     $                           nrhs, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   30                   CONTINUE
                        nrun = nrun + 5
   40                CONTINUE
*
*+    TEST 7
*                    Get an estimate of RCOND = 1/CNDNUM.
*
                     srnamt = 'ZPBCON'
                     CALL zpbcon( uplo, n, kd, afac, ldab, anorm, rcond,
     $                            work, rwork, info )
*
*                    Check error code from ZPBCON.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZPBCON', info, 0, uplo, n,
     $                               n, kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
*
                     result( 7 ) = dget06( rcond, rcondc )
*
*                    Print the test ratio if it is .GE. THRESH.
*
                     IF( result( 7 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )uplo, n, kd, imat, 7,
     $                     result( 7 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
   50             CONTINUE
   60          CONTINUE
   70       CONTINUE
   80    CONTINUE
   90 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', N=', i5, ', KD=', i5, ', NB=', i4,
     $      ', type ', i2, ', test ', i2, ', ratio= ', g12.5 )
 9998 FORMAT( ' UPLO=''', a1, ''', N=', i5, ', KD=', i5, ', NRHS=', i3,
     $      ', type ', i2, ', test(', i2, ') = ', g12.5 )
 9997 FORMAT( ' UPLO=''', a1, ''', N=', i5, ', KD=', i5, ',', 10x,
     $      ' type ', i2, ', test(', i2, ') = ', g12.5 )
      RETURN
*
*     End of ZCHKPB
*

Here is the call graph for this function:

Here is the caller graph for this function: