cqrt02()

subroutine cqrt02	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	q,
		complex, dimension( lda, * )	r,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result
	)

CQRT02

Purpose:

 CQRT02 tests CUNGQR, which generates an m-by-n matrix Q with
 orthonormal columns that is defined as the product of k elementary
 reflectors.

 Given the QR factorization of an m-by-n matrix A, CQRT02 generates
 the orthogonal matrix Q defined by the factorization of the first k
 columns of A; it compares R(1:n,1:k) with Q(1:m,1:n)'*A(1:m,1:k),
 and checks that the columns of Q are orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A which was factorized by CQRT01.
[in]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the QR factorization of A, as returned by CGEQRF. See CGEQRF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N)
[out]	R	R is COMPLEX array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and R. LDA >= M.
[in]	TAU	TAU is COMPLEX array, dimension (N) The scalar factors of the elementary reflectors corresponding to the QR factorization in AF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 133 of file cqrt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clacpy, claset, cungqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k columns of the factorization to the array Q
*
      CALL claset( 'Full', m, n, rogue, rogue, q, lda )
      CALL clacpy( 'Lower', m-1, k, af( 2, 1 ), lda, q( 2, 1 ), lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'CUNGQR'
      CALL cungqr( m, n, k, q, lda, tau, work, lwork, info )
*
*     Copy R(1:n,1:k)
*
      CALL claset( 'Full', n, k, cmplx( zero ), cmplx( zero ), r, lda )
      CALL clacpy( 'Upper', n, k, af, lda, r, lda )
*
*     Compute R(1:n,1:k) - Q(1:m,1:n)' * A(1:m,1:k)
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', n, k, m,
     $            cmplx( -one ), q, lda, a, lda, cmplx( one ), r, lda )
*
*     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = clange( '1', m, k, a, lda, rwork )
      resid = clange( '1', n, k, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), r, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', n, m, -one, q, lda,
     $            one, r, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = clansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of CQRT02
*

Here is the call graph for this function:

Here is the caller graph for this function: