LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zhet01_aa()

subroutine zhet01_aa ( character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldafac, * )  AFAC,
integer  LDAFAC,
integer, dimension( * )  IPIV,
complex*16, dimension( ldc, * )  C,
integer  LDC,
double precision, dimension( * )  RWORK,
double precision  RESID 
)

ZHET01_AA

Purpose:
 ZHET01_AA reconstructs a hermitian indefinite matrix A from its
 block L*D*L' or U*D*U' factorization and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix and EPS is the machine epsilon.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is stored:
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]N
          N is INTEGER
          The number of rows and columns of the matrix A.  N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The original hermitian matrix A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N)
[in]AFAC
          AFAC is COMPLEX*16 array, dimension (LDAFAC,N)
          The factored form of the matrix A.  AFAC contains the block
          diagonal matrix D and the multipliers used to obtain the
          factor L or U from the block L*D*L' or U*D*U' factorization
          as computed by ZHETRF.
[in]LDAFAC
          LDAFAC is INTEGER
          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
          The pivot indices from ZHETRF.
[out]C
          C is COMPLEX*16 array, dimension (LDC,N)
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C.  LDC >= max(1,N).
[out]RWORK
          RWORK is COMPLEX*16 array, dimension (N)
[out]RESID
          RESID is COMPLEX*16
          If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
          If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 127 of file zhet01_aa.f.

127 *
128 * -- LAPACK test routine (version 3.7.0) --
129 * -- LAPACK is a software package provided by Univ. of Tennessee, --
130 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131 * December 2016
132 *
133 * .. Scalar Arguments ..
134  CHARACTER uplo
135  INTEGER lda, ldafac, ldc, n
136  DOUBLE PRECISION resid
137 * ..
138 * .. Array Arguments ..
139  INTEGER ipiv( * )
140  DOUBLE PRECISION rwork( * )
141  COMPLEX*16 a( lda, * ), afac( ldafac, * ), c( ldc, * )
142 * ..
143 *
144 * =====================================================================
145 *
146 * .. Parameters ..
147  COMPLEX*16 czero, cone
148  parameter( czero = ( 0.0d+0, 0.0d+0 ),
149  $ cone = ( 1.0d+0, 0.0d+0 ) )
150  DOUBLE PRECISION zero, one
151  parameter( zero = 0.0d+0, one = 1.0d+0 )
152 * ..
153 * .. Local Scalars ..
154  INTEGER i, j
155  DOUBLE PRECISION anorm, eps
156 * ..
157 * .. External Functions ..
158  LOGICAL lsame
159  DOUBLE PRECISION dlamch, zlanhe
160  EXTERNAL lsame, dlamch, zlanhe
161 * ..
162 * .. External Subroutines ..
163  EXTERNAL zlaset, zlavhe
164 * ..
165 * .. Intrinsic Functions ..
166  INTRINSIC dble
167 * ..
168 * .. Executable Statements ..
169 *
170 * Quick exit if N = 0.
171 *
172  IF( n.LE.0 ) THEN
173  resid = zero
174  RETURN
175  END IF
176 *
177 * Determine EPS and the norm of A.
178 *
179  eps = dlamch( 'Epsilon' )
180  anorm = zlanhe( '1', uplo, n, a, lda, rwork )
181 *
182 * Initialize C to the tridiagonal matrix T.
183 *
184  CALL zlaset( 'Full', n, n, czero, czero, c, ldc )
185  CALL zlacpy( 'F', 1, n, afac( 1, 1 ), ldafac+1, c( 1, 1 ), ldc+1 )
186  IF( n.GT.1 ) THEN
187  IF( lsame( uplo, 'U' ) ) THEN
188  CALL zlacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 1, 2 ),
189  $ ldc+1 )
190  CALL zlacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 2, 1 ),
191  $ ldc+1 )
192  CALL zlacgv( n-1, c( 2, 1 ), ldc+1 )
193  ELSE
194  CALL zlacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 1, 2 ),
195  $ ldc+1 )
196  CALL zlacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 2, 1 ),
197  $ ldc+1 )
198  CALL zlacgv( n-1, c( 1, 2 ), ldc+1 )
199  ENDIF
200 *
201 * Call ZTRMM to form the product U' * D (or L * D ).
202 *
203  IF( lsame( uplo, 'U' ) ) THEN
204  CALL ztrmm( 'Left', uplo, 'Conjugate transpose', 'Unit',
205  $ n-1, n, cone, afac( 1, 2 ), ldafac, c( 2, 1 ),
206  $ ldc )
207  ELSE
208  CALL ztrmm( 'Left', uplo, 'No transpose', 'Unit', n-1, n,
209  $ cone, afac( 2, 1 ), ldafac, c( 2, 1 ), ldc )
210  END IF
211 *
212 * Call ZTRMM again to multiply by U (or L ).
213 *
214  IF( lsame( uplo, 'U' ) ) THEN
215  CALL ztrmm( 'Right', uplo, 'No transpose', 'Unit', n, n-1,
216  $ cone, afac( 1, 2 ), ldafac, c( 1, 2 ), ldc )
217  ELSE
218  CALL ztrmm( 'Right', uplo, 'Conjugate transpose', 'Unit', n,
219  $ n-1, cone, afac( 2, 1 ), ldafac, c( 1, 2 ),
220  $ ldc )
221  END IF
222 *
223 * Apply hermitian pivots
224 *
225  DO j = n, 1, -1
226  i = ipiv( j )
227  IF( i.NE.j )
228  $ CALL zswap( n, c( j, 1 ), ldc, c( i, 1 ), ldc )
229  END DO
230  DO j = n, 1, -1
231  i = ipiv( j )
232  IF( i.NE.j )
233  $ CALL zswap( n, c( 1, j ), 1, c( 1, i ), 1 )
234  END DO
235  ENDIF
236 *
237 *
238 * Compute the difference C - A .
239 *
240  IF( lsame( uplo, 'U' ) ) THEN
241  DO j = 1, n
242  DO i = 1, j
243  c( i, j ) = c( i, j ) - a( i, j )
244  END DO
245  END DO
246  ELSE
247  DO j = 1, n
248  DO i = j, n
249  c( i, j ) = c( i, j ) - a( i, j )
250  END DO
251  END DO
252  END IF
253 *
254 * Compute norm( C - A ) / ( N * norm(A) * EPS )
255 *
256  resid = zlanhe( '1', uplo, n, c, ldc, rwork )
257 *
258  IF( anorm.LE.zero ) THEN
259  IF( resid.NE.zero )
260  $ resid = one / eps
261  ELSE
262  resid = ( ( resid / dble( n ) ) / anorm ) / eps
263  END IF
264 *
265  RETURN
266 *
267 * End of ZHET01_AA
268 *
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
double precision function zlanhe(NORM, UPLO, N, A, LDA, WORK)
ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
Definition: zlanhe.f:126
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine zlavhe(UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
ZLAVHE
Definition: zlavhe.f:155
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
subroutine zswap(N, ZX, INCX, ZY, INCY)
ZSWAP
Definition: zswap.f:83
subroutine ztrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRMM
Definition: ztrmm.f:179
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
Here is the call graph for this function:
Here is the caller graph for this function: