LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zrqt01()

subroutine zrqt01 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
complex*16, dimension( lda, * )  AF,
complex*16, dimension( lda, * )  Q,
complex*16, dimension( lda, * )  R,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( lwork )  WORK,
integer  LWORK,
double precision, dimension( * )  RWORK,
double precision, dimension( * )  RESULT 
)

ZRQT01

Purpose:
 ZRQT01 tests ZGERQF, which computes the RQ factorization of an m-by-n
 matrix A, and partially tests ZUNGRQ which forms the n-by-n
 orthogonal matrix Q.

 ZRQT01 compares R with A*Q', and checks that Q is orthogonal.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The m-by-n matrix A.
[out]AF
          AF is COMPLEX*16 array, dimension (LDA,N)
          Details of the RQ factorization of A, as returned by ZGERQF.
          See ZGERQF for further details.
[out]Q
          Q is COMPLEX*16 array, dimension (LDA,N)
          The n-by-n orthogonal matrix Q.
[out]R
          R is COMPLEX*16 array, dimension (LDA,max(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, Q and L.
          LDA >= max(M,N).
[out]TAU
          TAU is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by ZGERQF.
[out]WORK
          WORK is COMPLEX*16 array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (max(M,N))
[out]RESULT
          RESULT is DOUBLE PRECISION array, dimension (2)
          The test ratios:
          RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 128 of file zrqt01.f.

128 *
129 * -- LAPACK test routine (version 3.7.0) --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 * December 2016
133 *
134 * .. Scalar Arguments ..
135  INTEGER lda, lwork, m, n
136 * ..
137 * .. Array Arguments ..
138  DOUBLE PRECISION result( * ), rwork( * )
139  COMPLEX*16 a( lda, * ), af( lda, * ), q( lda, * ),
140  $ r( lda, * ), tau( * ), work( lwork )
141 * ..
142 *
143 * =====================================================================
144 *
145 * .. Parameters ..
146  DOUBLE PRECISION zero, one
147  parameter( zero = 0.0d+0, one = 1.0d+0 )
148  COMPLEX*16 rogue
149  parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
150 * ..
151 * .. Local Scalars ..
152  INTEGER info, minmn
153  DOUBLE PRECISION anorm, eps, resid
154 * ..
155 * .. External Functions ..
156  DOUBLE PRECISION dlamch, zlange, zlansy
157  EXTERNAL dlamch, zlange, zlansy
158 * ..
159 * .. External Subroutines ..
160  EXTERNAL zgemm, zgerqf, zherk, zlacpy, zlaset, zungrq
161 * ..
162 * .. Intrinsic Functions ..
163  INTRINSIC dble, dcmplx, max, min
164 * ..
165 * .. Scalars in Common ..
166  CHARACTER*32 srnamt
167 * ..
168 * .. Common blocks ..
169  COMMON / srnamc / srnamt
170 * ..
171 * .. Executable Statements ..
172 *
173  minmn = min( m, n )
174  eps = dlamch( 'Epsilon' )
175 *
176 * Copy the matrix A to the array AF.
177 *
178  CALL zlacpy( 'Full', m, n, a, lda, af, lda )
179 *
180 * Factorize the matrix A in the array AF.
181 *
182  srnamt = 'ZGERQF'
183  CALL zgerqf( m, n, af, lda, tau, work, lwork, info )
184 *
185 * Copy details of Q
186 *
187  CALL zlaset( 'Full', n, n, rogue, rogue, q, lda )
188  IF( m.LE.n ) THEN
189  IF( m.GT.0 .AND. m.LT.n )
190  $ CALL zlacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
191  IF( m.GT.1 )
192  $ CALL zlacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
193  $ q( n-m+2, n-m+1 ), lda )
194  ELSE
195  IF( n.GT.1 )
196  $ CALL zlacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
197  $ q( 2, 1 ), lda )
198  END IF
199 *
200 * Generate the n-by-n matrix Q
201 *
202  srnamt = 'ZUNGRQ'
203  CALL zungrq( n, n, minmn, q, lda, tau, work, lwork, info )
204 *
205 * Copy R
206 *
207  CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), r,
208  $ lda )
209  IF( m.LE.n ) THEN
210  IF( m.GT.0 )
211  $ CALL zlacpy( 'Upper', m, m, af( 1, n-m+1 ), lda,
212  $ r( 1, n-m+1 ), lda )
213  ELSE
214  IF( m.GT.n .AND. n.GT.0 )
215  $ CALL zlacpy( 'Full', m-n, n, af, lda, r, lda )
216  IF( n.GT.0 )
217  $ CALL zlacpy( 'Upper', n, n, af( m-n+1, 1 ), lda,
218  $ r( m-n+1, 1 ), lda )
219  END IF
220 *
221 * Compute R - A*Q'
222 *
223  CALL zgemm( 'No transpose', 'Conjugate transpose', m, n, n,
224  $ dcmplx( -one ), a, lda, q, lda, dcmplx( one ), r,
225  $ lda )
226 *
227 * Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
228 *
229  anorm = zlange( '1', m, n, a, lda, rwork )
230  resid = zlange( '1', m, n, r, lda, rwork )
231  IF( anorm.GT.zero ) THEN
232  result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
233  ELSE
234  result( 1 ) = zero
235  END IF
236 *
237 * Compute I - Q*Q'
238 *
239  CALL zlaset( 'Full', n, n, dcmplx( zero ), dcmplx( one ), r, lda )
240  CALL zherk( 'Upper', 'No transpose', n, n, -one, q, lda, one, r,
241  $ lda )
242 *
243 * Compute norm( I - Q*Q' ) / ( N * EPS ) .
244 *
245  resid = zlansy( '1', 'Upper', n, r, lda, rwork )
246 *
247  result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
248 *
249  RETURN
250 *
251 * End of ZRQT01
252 *
double precision function zlange(NORM, M, N, A, LDA, WORK)
ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlange.f:117
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:189
double precision function zlansy(NORM, UPLO, N, A, LDA, WORK)
ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.
Definition: zlansy.f:125
subroutine zungrq(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
ZUNGRQ
Definition: zungrq.f:130
subroutine zherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
ZHERK
Definition: zherk.f:175
subroutine zgerqf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
ZGERQF
Definition: zgerqf.f:140
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
Here is the call graph for this function:
Here is the caller graph for this function: