LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zqrt01()

subroutine zqrt01 ( integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
complex*16, dimension( lda, * )  AF,
complex*16, dimension( lda, * )  Q,
complex*16, dimension( lda, * )  R,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( lwork )  WORK,
integer  LWORK,
double precision, dimension( * )  RWORK,
double precision, dimension( * )  RESULT 
)

ZQRT01

Purpose:
 ZQRT01 tests ZGEQRF, which computes the QR factorization of an m-by-n
 matrix A, and partially tests ZUNGQR which forms the m-by-m
 orthogonal matrix Q.

 ZQRT01 compares R with Q'*A, and checks that Q is orthogonal.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The m-by-n matrix A.
[out]AF
          AF is COMPLEX*16 array, dimension (LDA,N)
          Details of the QR factorization of A, as returned by ZGEQRF.
          See ZGEQRF for further details.
[out]Q
          Q is COMPLEX*16 array, dimension (LDA,M)
          The m-by-m orthogonal matrix Q.
[out]R
          R is COMPLEX*16 array, dimension (LDA,max(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, Q and R.
          LDA >= max(M,N).
[out]TAU
          TAU is COMPLEX*16 array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by ZGEQRF.
[out]WORK
          WORK is COMPLEX*16 array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (M)
[out]RESULT
          RESULT is DOUBLE PRECISION array, dimension (2)
          The test ratios:
          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 128 of file zqrt01.f.

128 *
129 * -- LAPACK test routine (version 3.7.0) --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 * December 2016
133 *
134 * .. Scalar Arguments ..
135  INTEGER lda, lwork, m, n
136 * ..
137 * .. Array Arguments ..
138  DOUBLE PRECISION result( * ), rwork( * )
139  COMPLEX*16 a( lda, * ), af( lda, * ), q( lda, * ),
140  $ r( lda, * ), tau( * ), work( lwork )
141 * ..
142 *
143 * =====================================================================
144 *
145 * .. Parameters ..
146  DOUBLE PRECISION zero, one
147  parameter( zero = 0.0d+0, one = 1.0d+0 )
148  COMPLEX*16 rogue
149  parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
150 * ..
151 * .. Local Scalars ..
152  INTEGER info, minmn
153  DOUBLE PRECISION anorm, eps, resid
154 * ..
155 * .. External Functions ..
156  DOUBLE PRECISION dlamch, zlange, zlansy
157  EXTERNAL dlamch, zlange, zlansy
158 * ..
159 * .. External Subroutines ..
160  EXTERNAL zgemm, zgeqrf, zherk, zlacpy, zlaset, zungqr
161 * ..
162 * .. Intrinsic Functions ..
163  INTRINSIC dble, dcmplx, max, min
164 * ..
165 * .. Scalars in Common ..
166  CHARACTER*32 srnamt
167 * ..
168 * .. Common blocks ..
169  COMMON / srnamc / srnamt
170 * ..
171 * .. Executable Statements ..
172 *
173  minmn = min( m, n )
174  eps = dlamch( 'Epsilon' )
175 *
176 * Copy the matrix A to the array AF.
177 *
178  CALL zlacpy( 'Full', m, n, a, lda, af, lda )
179 *
180 * Factorize the matrix A in the array AF.
181 *
182  srnamt = 'ZGEQRF'
183  CALL zgeqrf( m, n, af, lda, tau, work, lwork, info )
184 *
185 * Copy details of Q
186 *
187  CALL zlaset( 'Full', m, m, rogue, rogue, q, lda )
188  CALL zlacpy( 'Lower', m-1, n, af( 2, 1 ), lda, q( 2, 1 ), lda )
189 *
190 * Generate the m-by-m matrix Q
191 *
192  srnamt = 'ZUNGQR'
193  CALL zungqr( m, m, minmn, q, lda, tau, work, lwork, info )
194 *
195 * Copy R
196 *
197  CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), r,
198  $ lda )
199  CALL zlacpy( 'Upper', m, n, af, lda, r, lda )
200 *
201 * Compute R - Q'*A
202 *
203  CALL zgemm( 'Conjugate transpose', 'No transpose', m, n, m,
204  $ dcmplx( -one ), q, lda, a, lda, dcmplx( one ), r,
205  $ lda )
206 *
207 * Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
208 *
209  anorm = zlange( '1', m, n, a, lda, rwork )
210  resid = zlange( '1', m, n, r, lda, rwork )
211  IF( anorm.GT.zero ) THEN
212  result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
213  ELSE
214  result( 1 ) = zero
215  END IF
216 *
217 * Compute I - Q'*Q
218 *
219  CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), r, lda )
220  CALL zherk( 'Upper', 'Conjugate transpose', m, m, -one, q, lda,
221  $ one, r, lda )
222 *
223 * Compute norm( I - Q'*Q ) / ( M * EPS ) .
224 *
225  resid = zlansy( '1', 'Upper', m, r, lda, rwork )
226 *
227  result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
228 *
229  RETURN
230 *
231 * End of ZQRT01
232 *
double precision function zlange(NORM, M, N, A, LDA, WORK)
ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlange.f:117
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:189
double precision function zlansy(NORM, UPLO, N, A, LDA, WORK)
ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.
Definition: zlansy.f:125
subroutine zherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
ZHERK
Definition: zherk.f:175
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
subroutine zungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
ZUNGQR
Definition: zungqr.f:130
subroutine zgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
ZGEQRF VARIANT: left-looking Level 3 BLAS of the algorithm.
Definition: zgeqrf.f:151
Here is the call graph for this function:
Here is the caller graph for this function: