LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dla_gbrfsx_extended()

subroutine dla_gbrfsx_extended ( integer  PREC_TYPE,
integer  TRANS_TYPE,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
double precision, dimension( ldab, * )  AB,
integer  LDAB,
double precision, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
double precision, dimension( ldb, * )  B,
integer  LDB,
double precision, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension(*)  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
double precision, dimension(*)  RES,
double precision, dimension(*)  AYB,
double precision, dimension(*)  DY,
double precision, dimension(*)  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

DLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download DLA_GBRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLA_GBRFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by DGBRFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and
     P    = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X', 'E':  Extra
[in]TRANS_TYPE
          TRANS_TYPE is INTEGER
     Specifies the transposition operation on A.
     The value is defined by ILATRANS(T) where T is a CHARACTER and
     T    = 'N':  No transpose
          = 'T':  Transpose
          = 'C':  Conjugate transpose
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]KL
          KL is INTEGER
     The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
     The number of superdiagonals within the band of A.  KU >= 0
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]AB
          AB is DOUBLE PRECISION array, dimension (LDAB,N)
          On entry, the N-by-N matrix AB.
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDBA >= max(1,N).
[in]AFB
          AFB is DOUBLE PRECISION array, dimension (LDAFB,N)
     The factors L and U from the factorization
     A = P*L*U as computed by DGBTRF.
[in]LDAFB
          LDAFB is INTEGER
     The leading dimension of the array AF.  LDAFB >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     The pivot indices from the factorization A = P*L*U
     as computed by DGBTRF; row i of the matrix was interchanged
     with row IPIV(i).
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is DOUBLE PRECISION array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by DGBTRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by DLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace. This can be the same workspace passed for Y_TAIL.
[in]DY
          DY is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is DOUBLE PRECISION array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we definte as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to DGBTRS had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017

Definition at line 413 of file dla_gbrfsx_extended.f.

413 *
414 * -- LAPACK computational routine (version 3.7.1) --
415 * -- LAPACK is a software package provided by Univ. of Tennessee, --
416 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
417 * June 2017
418 *
419 * .. Scalar Arguments ..
420  INTEGER info, ldab, ldafb, ldb, ldy, n, kl, ku, nrhs,
421  $ prec_type, trans_type, n_norms, ithresh
422  LOGICAL colequ, ignore_cwise
423  DOUBLE PRECISION rthresh, dz_ub
424 * ..
425 * .. Array Arguments ..
426  INTEGER ipiv( * )
427  DOUBLE PRECISION ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
428  $ y( ldy, * ), res(*), dy(*), y_tail(*)
429  DOUBLE PRECISION c( * ), ayb(*), rcond, berr_out(*),
430  $ err_bnds_norm( nrhs, * ),
431  $ err_bnds_comp( nrhs, * )
432 * ..
433 *
434 * =====================================================================
435 *
436 * .. Local Scalars ..
437  CHARACTER trans
438  INTEGER cnt, i, j, m, x_state, z_state, y_prec_state
439  DOUBLE PRECISION yk, dyk, ymin, normy, normx, normdx, dxrat,
440  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
441  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
442  $ eps, hugeval, incr_thresh
443  LOGICAL incr_prec
444 * ..
445 * .. Parameters ..
446  INTEGER unstable_state, working_state, conv_state,
447  $ noprog_state, base_residual, extra_residual,
448  $ extra_y
449  parameter( unstable_state = 0, working_state = 1,
450  $ conv_state = 2, noprog_state = 3 )
451  parameter( base_residual = 0, extra_residual = 1,
452  $ extra_y = 2 )
453  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
454  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
455  INTEGER cmp_err_i, piv_growth_i
456  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
457  $ berr_i = 3 )
458  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
459  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
460  $ piv_growth_i = 9 )
461  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
462  $ la_linrx_cwise_i
463  parameter( la_linrx_itref_i = 1,
464  $ la_linrx_ithresh_i = 2 )
465  parameter( la_linrx_cwise_i = 3 )
466  INTEGER la_linrx_trust_i, la_linrx_err_i,
467  $ la_linrx_rcond_i
468  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
469  parameter( la_linrx_rcond_i = 3 )
470 * ..
471 * .. External Subroutines ..
472  EXTERNAL daxpy, dcopy, dgbtrs, dgbmv, blas_dgbmv_x,
473  $ blas_dgbmv2_x, dla_gbamv, dla_wwaddw, dlamch,
475  DOUBLE PRECISION dlamch
476  CHARACTER chla_transtype
477 * ..
478 * .. Intrinsic Functions ..
479  INTRINSIC abs, max, min
480 * ..
481 * .. Executable Statements ..
482 *
483  IF (info.NE.0) RETURN
484  trans = chla_transtype(trans_type)
485  eps = dlamch( 'Epsilon' )
486  hugeval = dlamch( 'Overflow' )
487 * Force HUGEVAL to Inf
488  hugeval = hugeval * hugeval
489 * Using HUGEVAL may lead to spurious underflows.
490  incr_thresh = dble( n ) * eps
491  m = kl+ku+1
492 
493  DO j = 1, nrhs
494  y_prec_state = extra_residual
495  IF ( y_prec_state .EQ. extra_y ) THEN
496  DO i = 1, n
497  y_tail( i ) = 0.0d+0
498  END DO
499  END IF
500 
501  dxrat = 0.0d+0
502  dxratmax = 0.0d+0
503  dzrat = 0.0d+0
504  dzratmax = 0.0d+0
505  final_dx_x = hugeval
506  final_dz_z = hugeval
507  prevnormdx = hugeval
508  prev_dz_z = hugeval
509  dz_z = hugeval
510  dx_x = hugeval
511 
512  x_state = working_state
513  z_state = unstable_state
514  incr_prec = .false.
515 
516  DO cnt = 1, ithresh
517 *
518 * Compute residual RES = B_s - op(A_s) * Y,
519 * op(A) = A, A**T, or A**H depending on TRANS (and type).
520 *
521  CALL dcopy( n, b( 1, j ), 1, res, 1 )
522  IF ( y_prec_state .EQ. base_residual ) THEN
523  CALL dgbmv( trans, m, n, kl, ku, -1.0d+0, ab, ldab,
524  $ y( 1, j ), 1, 1.0d+0, res, 1 )
525  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
526  CALL blas_dgbmv_x( trans_type, n, n, kl, ku,
527  $ -1.0d+0, ab, ldab, y( 1, j ), 1, 1.0d+0, res, 1,
528  $ prec_type )
529  ELSE
530  CALL blas_dgbmv2_x( trans_type, n, n, kl, ku, -1.0d+0,
531  $ ab, ldab, y( 1, j ), y_tail, 1, 1.0d+0, res, 1,
532  $ prec_type )
533  END IF
534 
535 ! XXX: RES is no longer needed.
536  CALL dcopy( n, res, 1, dy, 1 )
537  CALL dgbtrs( trans, n, kl, ku, 1, afb, ldafb, ipiv, dy, n,
538  $ info )
539 *
540 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
541 *
542  normx = 0.0d+0
543  normy = 0.0d+0
544  normdx = 0.0d+0
545  dz_z = 0.0d+0
546  ymin = hugeval
547 
548  DO i = 1, n
549  yk = abs( y( i, j ) )
550  dyk = abs( dy( i ) )
551 
552  IF ( yk .NE. 0.0d+0 ) THEN
553  dz_z = max( dz_z, dyk / yk )
554  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
555  dz_z = hugeval
556  END IF
557 
558  ymin = min( ymin, yk )
559 
560  normy = max( normy, yk )
561 
562  IF ( colequ ) THEN
563  normx = max( normx, yk * c( i ) )
564  normdx = max( normdx, dyk * c( i ) )
565  ELSE
566  normx = normy
567  normdx = max( normdx, dyk )
568  END IF
569  END DO
570 
571  IF ( normx .NE. 0.0d+0 ) THEN
572  dx_x = normdx / normx
573  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
574  dx_x = 0.0d+0
575  ELSE
576  dx_x = hugeval
577  END IF
578 
579  dxrat = normdx / prevnormdx
580  dzrat = dz_z / prev_dz_z
581 *
582 * Check termination criteria.
583 *
584  IF ( .NOT.ignore_cwise
585  $ .AND. ymin*rcond .LT. incr_thresh*normy
586  $ .AND. y_prec_state .LT. extra_y )
587  $ incr_prec = .true.
588 
589  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
590  $ x_state = working_state
591  IF ( x_state .EQ. working_state ) THEN
592  IF ( dx_x .LE. eps ) THEN
593  x_state = conv_state
594  ELSE IF ( dxrat .GT. rthresh ) THEN
595  IF ( y_prec_state .NE. extra_y ) THEN
596  incr_prec = .true.
597  ELSE
598  x_state = noprog_state
599  END IF
600  ELSE
601  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
602  END IF
603  IF ( x_state .GT. working_state ) final_dx_x = dx_x
604  END IF
605 
606  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
607  $ z_state = working_state
608  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
609  $ z_state = working_state
610  IF ( z_state .EQ. working_state ) THEN
611  IF ( dz_z .LE. eps ) THEN
612  z_state = conv_state
613  ELSE IF ( dz_z .GT. dz_ub ) THEN
614  z_state = unstable_state
615  dzratmax = 0.0d+0
616  final_dz_z = hugeval
617  ELSE IF ( dzrat .GT. rthresh ) THEN
618  IF ( y_prec_state .NE. extra_y ) THEN
619  incr_prec = .true.
620  ELSE
621  z_state = noprog_state
622  END IF
623  ELSE
624  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
625  END IF
626  IF ( z_state .GT. working_state ) final_dz_z = dz_z
627  END IF
628 *
629 * Exit if both normwise and componentwise stopped working,
630 * but if componentwise is unstable, let it go at least two
631 * iterations.
632 *
633  IF ( x_state.NE.working_state ) THEN
634  IF ( ignore_cwise ) GOTO 666
635  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
636  $ GOTO 666
637  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
638  END IF
639 
640  IF ( incr_prec ) THEN
641  incr_prec = .false.
642  y_prec_state = y_prec_state + 1
643  DO i = 1, n
644  y_tail( i ) = 0.0d+0
645  END DO
646  END IF
647 
648  prevnormdx = normdx
649  prev_dz_z = dz_z
650 *
651 * Update soluton.
652 *
653  IF (y_prec_state .LT. extra_y) THEN
654  CALL daxpy( n, 1.0d+0, dy, 1, y(1,j), 1 )
655  ELSE
656  CALL dla_wwaddw( n, y(1,j), y_tail, dy )
657  END IF
658 
659  END DO
660 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
661  666 CONTINUE
662 *
663 * Set final_* when cnt hits ithresh.
664 *
665  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
666  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
667 *
668 * Compute error bounds.
669 *
670  IF ( n_norms .GE. 1 ) THEN
671  err_bnds_norm( j, la_linrx_err_i ) =
672  $ final_dx_x / (1 - dxratmax)
673  END IF
674  IF (n_norms .GE. 2) THEN
675  err_bnds_comp( j, la_linrx_err_i ) =
676  $ final_dz_z / (1 - dzratmax)
677  END IF
678 *
679 * Compute componentwise relative backward error from formula
680 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
681 * where abs(Z) is the componentwise absolute value of the matrix
682 * or vector Z.
683 *
684 * Compute residual RES = B_s - op(A_s) * Y,
685 * op(A) = A, A**T, or A**H depending on TRANS (and type).
686 *
687  CALL dcopy( n, b( 1, j ), 1, res, 1 )
688  CALL dgbmv(trans, n, n, kl, ku, -1.0d+0, ab, ldab, y(1,j),
689  $ 1, 1.0d+0, res, 1 )
690 
691  DO i = 1, n
692  ayb( i ) = abs( b( i, j ) )
693  END DO
694 *
695 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
696 *
697  CALL dla_gbamv( trans_type, n, n, kl, ku, 1.0d+0,
698  $ ab, ldab, y(1, j), 1, 1.0d+0, ayb, 1 )
699 
700  CALL dla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
701 *
702 * End of loop for each RHS
703 *
704  END DO
705 *
706  RETURN
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:84
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:91
subroutine dla_gbamv(TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X, INCX, BETA, Y, INCY)
DLA_GBAMV performs a matrix-vector operation to calculate error bounds.
Definition: dla_gbamv.f:187
subroutine dgbmv(TRANS, M, N, KL, KU, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGBMV
Definition: dgbmv.f:187
subroutine dla_wwaddw(N, X, Y, W)
DLA_WWADDW adds a vector into a doubled-single vector.
Definition: dla_wwaddw.f:83
subroutine dgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
DGBTRS
Definition: dgbtrs.f:140
subroutine dla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
DLA_LIN_BERR computes a component-wise relative backward error.
Definition: dla_lin_berr.f:103
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
Here is the call graph for this function:
Here is the caller graph for this function: