LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlaed1()

subroutine dlaed1 ( integer  N,
double precision, dimension( * )  D,
double precision, dimension( ldq, * )  Q,
integer  LDQ,
integer, dimension( * )  INDXQ,
double precision  RHO,
integer  CUTPNT,
double precision, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

DLAED1 used by sstedc. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is tridiagonal.

Download DLAED1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLAED1 computes the updated eigensystem of a diagonal
 matrix after modification by a rank-one symmetric matrix.  This
 routine is used only for the eigenproblem which requires all
 eigenvalues and eigenvectors of a tridiagonal matrix.  DLAED7 handles
 the case in which eigenvalues only or eigenvalues and eigenvectors
 of a full symmetric matrix (which was reduced to tridiagonal form)
 are desired.

   T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)

    where Z = Q**T*u, u is a vector of length N with ones in the
    CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.

    The eigenvectors of the original matrix are stored in Q, and the
    eigenvalues are in D.  The algorithm consists of three stages:

       The first stage consists of deflating the size of the problem
       when there are multiple eigenvalues or if there is a zero in
       the Z vector.  For each such occurrence the dimension of the
       secular equation problem is reduced by one.  This stage is
       performed by the routine DLAED2.

       The second stage consists of calculating the updated
       eigenvalues. This is done by finding the roots of the secular
       equation via the routine DLAED4 (as called by DLAED3).
       This routine also calculates the eigenvectors of the current
       problem.

       The final stage consists of computing the updated eigenvectors
       directly using the updated eigenvalues.  The eigenvectors for
       the current problem are multiplied with the eigenvectors from
       the overall problem.
Parameters
[in]N
          N is INTEGER
         The dimension of the symmetric tridiagonal matrix.  N >= 0.
[in,out]D
          D is DOUBLE PRECISION array, dimension (N)
         On entry, the eigenvalues of the rank-1-perturbed matrix.
         On exit, the eigenvalues of the repaired matrix.
[in,out]Q
          Q is DOUBLE PRECISION array, dimension (LDQ,N)
         On entry, the eigenvectors of the rank-1-perturbed matrix.
         On exit, the eigenvectors of the repaired tridiagonal matrix.
[in]LDQ
          LDQ is INTEGER
         The leading dimension of the array Q.  LDQ >= max(1,N).
[in,out]INDXQ
          INDXQ is INTEGER array, dimension (N)
         On entry, the permutation which separately sorts the two
         subproblems in D into ascending order.
         On exit, the permutation which will reintegrate the
         subproblems back into sorted order,
         i.e. D( INDXQ( I = 1, N ) ) will be in ascending order.
[in]RHO
          RHO is DOUBLE PRECISION
         The subdiagonal entry used to create the rank-1 modification.
[in]CUTPNT
          CUTPNT is INTEGER
         The location of the last eigenvalue in the leading sub-matrix.
         min(1,N) <= CUTPNT <= N/2.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (4*N + N**2)
[out]IWORK
          IWORK is INTEGER array, dimension (4*N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
          > 0:  if INFO = 1, an eigenvalue did not converge
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016
Contributors:
Jeff Rutter, Computer Science Division, University of California at Berkeley, USA
Modified by Francoise Tisseur, University of Tennessee

Definition at line 165 of file dlaed1.f.

165 *
166 * -- LAPACK computational routine (version 3.7.0) --
167 * -- LAPACK is a software package provided by Univ. of Tennessee, --
168 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
169 * June 2016
170 *
171 * .. Scalar Arguments ..
172  INTEGER cutpnt, info, ldq, n
173  DOUBLE PRECISION rho
174 * ..
175 * .. Array Arguments ..
176  INTEGER indxq( * ), iwork( * )
177  DOUBLE PRECISION d( * ), q( ldq, * ), work( * )
178 * ..
179 *
180 * =====================================================================
181 *
182 * .. Local Scalars ..
183  INTEGER coltyp, i, idlmda, indx, indxc, indxp, iq2, is,
184  $ iw, iz, k, n1, n2, zpp1
185 * ..
186 * .. External Subroutines ..
187  EXTERNAL dcopy, dlaed2, dlaed3, dlamrg, xerbla
188 * ..
189 * .. Intrinsic Functions ..
190  INTRINSIC max, min
191 * ..
192 * .. Executable Statements ..
193 *
194 * Test the input parameters.
195 *
196  info = 0
197 *
198  IF( n.LT.0 ) THEN
199  info = -1
200  ELSE IF( ldq.LT.max( 1, n ) ) THEN
201  info = -4
202  ELSE IF( min( 1, n / 2 ).GT.cutpnt .OR. ( n / 2 ).LT.cutpnt ) THEN
203  info = -7
204  END IF
205  IF( info.NE.0 ) THEN
206  CALL xerbla( 'DLAED1', -info )
207  RETURN
208  END IF
209 *
210 * Quick return if possible
211 *
212  IF( n.EQ.0 )
213  $ RETURN
214 *
215 * The following values are integer pointers which indicate
216 * the portion of the workspace
217 * used by a particular array in DLAED2 and DLAED3.
218 *
219  iz = 1
220  idlmda = iz + n
221  iw = idlmda + n
222  iq2 = iw + n
223 *
224  indx = 1
225  indxc = indx + n
226  coltyp = indxc + n
227  indxp = coltyp + n
228 *
229 *
230 * Form the z-vector which consists of the last row of Q_1 and the
231 * first row of Q_2.
232 *
233  CALL dcopy( cutpnt, q( cutpnt, 1 ), ldq, work( iz ), 1 )
234  zpp1 = cutpnt + 1
235  CALL dcopy( n-cutpnt, q( zpp1, zpp1 ), ldq, work( iz+cutpnt ), 1 )
236 *
237 * Deflate eigenvalues.
238 *
239  CALL dlaed2( k, n, cutpnt, d, q, ldq, indxq, rho, work( iz ),
240  $ work( idlmda ), work( iw ), work( iq2 ),
241  $ iwork( indx ), iwork( indxc ), iwork( indxp ),
242  $ iwork( coltyp ), info )
243 *
244  IF( info.NE.0 )
245  $ GO TO 20
246 *
247 * Solve Secular Equation.
248 *
249  IF( k.NE.0 ) THEN
250  is = ( iwork( coltyp )+iwork( coltyp+1 ) )*cutpnt +
251  $ ( iwork( coltyp+1 )+iwork( coltyp+2 ) )*( n-cutpnt ) + iq2
252  CALL dlaed3( k, n, cutpnt, d, q, ldq, rho, work( idlmda ),
253  $ work( iq2 ), iwork( indxc ), iwork( coltyp ),
254  $ work( iw ), work( is ), info )
255  IF( info.NE.0 )
256  $ GO TO 20
257 *
258 * Prepare the INDXQ sorting permutation.
259 *
260  n1 = k
261  n2 = n - k
262  CALL dlamrg( n1, n2, d, 1, -1, indxq )
263  ELSE
264  DO 10 i = 1, n
265  indxq( i ) = i
266  10 CONTINUE
267  END IF
268 *
269  20 CONTINUE
270  RETURN
271 *
272 * End of DLAED1
273 *
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:84
subroutine dlaed2(K, N, N1, D, Q, LDQ, INDXQ, RHO, Z, DLAMDA, W, Q2, INDX, INDXC, INDXP, COLTYP, INFO)
DLAED2 used by sstedc. Merges eigenvalues and deflates secular equation. Used when the original matri...
Definition: dlaed2.f:214
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlaed3(K, N, N1, D, Q, LDQ, RHO, DLAMDA, Q2, INDX, CTOT, W, S, INFO)
DLAED3 used by sstedc. Finds the roots of the secular equation and updates the eigenvectors. Used when the original matrix is tridiagonal.
Definition: dlaed3.f:187
subroutine dlamrg(N1, N2, A, DTRD1, DTRD2, INDEX)
DLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: dlamrg.f:101
Here is the call graph for this function:
Here is the caller graph for this function: