LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ sggrqf()

subroutine sggrqf ( integer  M,
integer  P,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAUA,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( * )  TAUB,
real, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

SGGRQF

Download SGGRQF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGGRQF computes a generalized RQ factorization of an M-by-N matrix A
 and a P-by-N matrix B:

             A = R*Q,        B = Z*T*Q,

 where Q is an N-by-N orthogonal matrix, Z is a P-by-P orthogonal
 matrix, and R and T assume one of the forms:

 if M <= N,  R = ( 0  R12 ) M,   or if M > N,  R = ( R11 ) M-N,
                  N-M  M                           ( R21 ) N
                                                      N

 where R12 or R21 is upper triangular, and

 if P >= N,  T = ( T11 ) N  ,   or if P < N,  T = ( T11  T12 ) P,
                 (  0  ) P-N                         P   N-P
                    N

 where T11 is upper triangular.

 In particular, if B is square and nonsingular, the GRQ factorization
 of A and B implicitly gives the RQ factorization of A*inv(B):

              A*inv(B) = (R*inv(T))*Z**T

 where inv(B) denotes the inverse of the matrix B, and Z**T denotes the
 transpose of the matrix Z.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]P
          P is INTEGER
          The number of rows of the matrix B.  P >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrices A and B. N >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the M-by-N matrix A.
          On exit, if M <= N, the upper triangle of the subarray
          A(1:M,N-M+1:N) contains the M-by-M upper triangular matrix R;
          if M > N, the elements on and above the (M-N)-th subdiagonal
          contain the M-by-N upper trapezoidal matrix R; the remaining
          elements, with the array TAUA, represent the orthogonal
          matrix Q as a product of elementary reflectors (see Further
          Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,M).
[out]TAUA
          TAUA is REAL array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Q (see Further Details).
[in,out]B
          B is REAL array, dimension (LDB,N)
          On entry, the P-by-N matrix B.
          On exit, the elements on and above the diagonal of the array
          contain the min(P,N)-by-N upper trapezoidal matrix T (T is
          upper triangular if P >= N); the elements below the diagonal,
          with the array TAUB, represent the orthogonal matrix Z as a
          product of elementary reflectors (see Further Details).
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B. LDB >= max(1,P).
[out]TAUB
          TAUB is REAL array, dimension (min(P,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Z (see Further Details).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK >= max(1,N,M,P).
          For optimum performance LWORK >= max(N,M,P)*max(NB1,NB2,NB3),
          where NB1 is the optimal blocksize for the RQ factorization
          of an M-by-N matrix, NB2 is the optimal blocksize for the
          QR factorization of a P-by-N matrix, and NB3 is the optimal
          blocksize for a call of SORMRQ.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INF0= -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(k), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - taua * v * v**T

  where taua is a real scalar, and v is a real vector with
  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; v(1:n-k+i-1) is stored on exit in
  A(m-k+i,1:n-k+i-1), and taua in TAUA(i).
  To form Q explicitly, use LAPACK subroutine SORGRQ.
  To use Q to update another matrix, use LAPACK subroutine SORMRQ.

  The matrix Z is represented as a product of elementary reflectors

     Z = H(1) H(2) . . . H(k), where k = min(p,n).

  Each H(i) has the form

     H(i) = I - taub * v * v**T

  where taub is a real scalar, and v is a real vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:p) is stored on exit in B(i+1:p,i),
  and taub in TAUB(i).
  To form Z explicitly, use LAPACK subroutine SORGQR.
  To use Z to update another matrix, use LAPACK subroutine SORMQR.

Definition at line 216 of file sggrqf.f.

216 *
217 * -- LAPACK computational routine (version 3.7.0) --
218 * -- LAPACK is a software package provided by Univ. of Tennessee, --
219 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
220 * December 2016
221 *
222 * .. Scalar Arguments ..
223  INTEGER info, lda, ldb, lwork, m, n, p
224 * ..
225 * .. Array Arguments ..
226  REAL a( lda, * ), b( ldb, * ), taua( * ), taub( * ),
227  $ work( * )
228 * ..
229 *
230 * =====================================================================
231 *
232 * .. Local Scalars ..
233  LOGICAL lquery
234  INTEGER lopt, lwkopt, nb, nb1, nb2, nb3
235 * ..
236 * .. External Subroutines ..
237  EXTERNAL sgeqrf, sgerqf, sormrq, xerbla
238 * ..
239 * .. External Functions ..
240  INTEGER ilaenv
241  EXTERNAL ilaenv
242 * ..
243 * .. Intrinsic Functions ..
244  INTRINSIC int, max, min
245 * ..
246 * .. Executable Statements ..
247 *
248 * Test the input parameters
249 *
250  info = 0
251  nb1 = ilaenv( 1, 'SGERQF', ' ', m, n, -1, -1 )
252  nb2 = ilaenv( 1, 'SGEQRF', ' ', p, n, -1, -1 )
253  nb3 = ilaenv( 1, 'SORMRQ', ' ', m, n, p, -1 )
254  nb = max( nb1, nb2, nb3 )
255  lwkopt = max( n, m, p)*nb
256  work( 1 ) = lwkopt
257  lquery = ( lwork.EQ.-1 )
258  IF( m.LT.0 ) THEN
259  info = -1
260  ELSE IF( p.LT.0 ) THEN
261  info = -2
262  ELSE IF( n.LT.0 ) THEN
263  info = -3
264  ELSE IF( lda.LT.max( 1, m ) ) THEN
265  info = -5
266  ELSE IF( ldb.LT.max( 1, p ) ) THEN
267  info = -8
268  ELSE IF( lwork.LT.max( 1, m, p, n ) .AND. .NOT.lquery ) THEN
269  info = -11
270  END IF
271  IF( info.NE.0 ) THEN
272  CALL xerbla( 'SGGRQF', -info )
273  RETURN
274  ELSE IF( lquery ) THEN
275  RETURN
276  END IF
277 *
278 * RQ factorization of M-by-N matrix A: A = R*Q
279 *
280  CALL sgerqf( m, n, a, lda, taua, work, lwork, info )
281  lopt = work( 1 )
282 *
283 * Update B := B*Q**T
284 *
285  CALL sormrq( 'Right', 'Transpose', p, n, min( m, n ),
286  $ a( max( 1, m-n+1 ), 1 ), lda, taua, b, ldb, work,
287  $ lwork, info )
288  lopt = max( lopt, int( work( 1 ) ) )
289 *
290 * QR factorization of P-by-N matrix B: B = Z*T
291 *
292  CALL sgeqrf( p, n, b, ldb, taub, work, lwork, info )
293  work( 1 ) = max( lopt, int( work( 1 ) ) )
294 *
295  RETURN
296 *
297 * End of SGGRQF
298 *
subroutine sormrq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMRQ
Definition: sormrq.f:170
subroutine sgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRF
Definition: sgeqrf.f:138
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: tstiee.f:83
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sgerqf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGERQF
Definition: sgerqf.f:140
Here is the call graph for this function:
Here is the caller graph for this function: