 LAPACK  3.9.0 LAPACK: Linear Algebra PACKage

## ◆ slaqp2()

 subroutine slaqp2 ( integer M, integer N, integer OFFSET, real, dimension( lda, * ) A, integer LDA, integer, dimension( * ) JPVT, real, dimension( * ) TAU, real, dimension( * ) VN1, real, dimension( * ) VN2, real, dimension( * ) WORK )

SLAQP2 computes a QR factorization with column pivoting of the matrix block.

Purpose:
``` SLAQP2 computes a QR factorization with column pivoting of
the block A(OFFSET+1:M,1:N).
The block A(1:OFFSET,1:N) is accordingly pivoted, but not factorized.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0.``` [in] OFFSET ``` OFFSET is INTEGER The number of rows of the matrix A that must be pivoted but no factorized. OFFSET >= 0.``` [in,out] A ``` A is REAL array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, the upper triangle of block A(OFFSET+1:M,1:N) is the triangular factor obtained; the elements in block A(OFFSET+1:M,1:N) below the diagonal, together with the array TAU, represent the orthogonal matrix Q as a product of elementary reflectors. Block A(1:OFFSET,1:N) has been accordingly pivoted, but no factorized.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [in,out] JPVT ``` JPVT is INTEGER array, dimension (N) On entry, if JPVT(i) .ne. 0, the i-th column of A is permuted to the front of A*P (a leading column); if JPVT(i) = 0, the i-th column of A is a free column. On exit, if JPVT(i) = k, then the i-th column of A*P was the k-th column of A.``` [out] TAU ``` TAU is REAL array, dimension (min(M,N)) The scalar factors of the elementary reflectors.``` [in,out] VN1 ``` VN1 is REAL array, dimension (N) The vector with the partial column norms.``` [in,out] VN2 ``` VN2 is REAL array, dimension (N) The vector with the exact column norms.``` [out] WORK ` WORK is REAL array, dimension (N)`
Date
December 2016
Contributors:
G. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain X. Sun, Computer Science Dept., Duke University, USA
Partial column norm updating strategy modified on April 2011 Z. Drmac and Z. Bujanovic, Dept. of Mathematics, University of Zagreb, Croatia.
References:
LAPACK Working Note 176 [PDF]

Definition at line 151 of file slaqp2.f.

151 *
152 * -- LAPACK auxiliary routine (version 3.7.0) --
153 * -- LAPACK is a software package provided by Univ. of Tennessee, --
154 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
155 * December 2016
156 *
157 * .. Scalar Arguments ..
158  INTEGER LDA, M, N, OFFSET
159 * ..
160 * .. Array Arguments ..
161  INTEGER JPVT( * )
162  REAL A( LDA, * ), TAU( * ), VN1( * ), VN2( * ),
163  \$ WORK( * )
164 * ..
165 *
166 * =====================================================================
167 *
168 * .. Parameters ..
169  REAL ZERO, ONE
170  parameter( zero = 0.0e+0, one = 1.0e+0 )
171 * ..
172 * .. Local Scalars ..
173  INTEGER I, ITEMP, J, MN, OFFPI, PVT
174  REAL AII, TEMP, TEMP2, TOL3Z
175 * ..
176 * .. External Subroutines ..
177  EXTERNAL slarf, slarfg, sswap
178 * ..
179 * .. Intrinsic Functions ..
180  INTRINSIC abs, max, min, sqrt
181 * ..
182 * .. External Functions ..
183  INTEGER ISAMAX
184  REAL SLAMCH, SNRM2
185  EXTERNAL isamax, slamch, snrm2
186 * ..
187 * .. Executable Statements ..
188 *
189  mn = min( m-offset, n )
190  tol3z = sqrt(slamch('Epsilon'))
191 *
192 * Compute factorization.
193 *
194  DO 20 i = 1, mn
195 *
196  offpi = offset + i
197 *
198 * Determine ith pivot column and swap if necessary.
199 *
200  pvt = ( i-1 ) + isamax( n-i+1, vn1( i ), 1 )
201 *
202  IF( pvt.NE.i ) THEN
203  CALL sswap( m, a( 1, pvt ), 1, a( 1, i ), 1 )
204  itemp = jpvt( pvt )
205  jpvt( pvt ) = jpvt( i )
206  jpvt( i ) = itemp
207  vn1( pvt ) = vn1( i )
208  vn2( pvt ) = vn2( i )
209  END IF
210 *
211 * Generate elementary reflector H(i).
212 *
213  IF( offpi.LT.m ) THEN
214  CALL slarfg( m-offpi+1, a( offpi, i ), a( offpi+1, i ), 1,
215  \$ tau( i ) )
216  ELSE
217  CALL slarfg( 1, a( m, i ), a( m, i ), 1, tau( i ) )
218  END IF
219 *
220  IF( i.LT.n ) THEN
221 *
222 * Apply H(i)**T to A(offset+i:m,i+1:n) from the left.
223 *
224  aii = a( offpi, i )
225  a( offpi, i ) = one
226  CALL slarf( 'Left', m-offpi+1, n-i, a( offpi, i ), 1,
227  \$ tau( i ), a( offpi, i+1 ), lda, work( 1 ) )
228  a( offpi, i ) = aii
229  END IF
230 *
231 * Update partial column norms.
232 *
233  DO 10 j = i + 1, n
234  IF( vn1( j ).NE.zero ) THEN
235 *
236 * NOTE: The following 4 lines follow from the analysis in
237 * Lapack Working Note 176.
238 *
239  temp = one - ( abs( a( offpi, j ) ) / vn1( j ) )**2
240  temp = max( temp, zero )
241  temp2 = temp*( vn1( j ) / vn2( j ) )**2
242  IF( temp2 .LE. tol3z ) THEN
243  IF( offpi.LT.m ) THEN
244  vn1( j ) = snrm2( m-offpi, a( offpi+1, j ), 1 )
245  vn2( j ) = vn1( j )
246  ELSE
247  vn1( j ) = zero
248  vn2( j ) = zero
249  END IF
250  ELSE
251  vn1( j ) = vn1( j )*sqrt( temp )
252  END IF
253  END IF
254  10 CONTINUE
255 *
256  20 CONTINUE
257 *
258  RETURN
259 *
260 * End of SLAQP2
261 *
Here is the call graph for this function:
Here is the caller graph for this function:
snrm2
real function snrm2(N, X, INCX)
SNRM2
Definition: snrm2.f:76
sswap
subroutine sswap(N, SX, INCX, SY, INCY)
SSWAP
Definition: sswap.f:84
isamax
integer function isamax(N, SX, INCX)
ISAMAX
Definition: isamax.f:73
slarfg
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:108
slamch
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:70
slarf
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:126