LAPACK  3.6.0
LAPACK: Linear Algebra PACKage
Collaboration diagram for real:

Functions

subroutine sgtsv (N, NRHS, DL, D, DU, B, LDB, INFO)
  SGTSV computes the solution to system of linear equations A * X = B for GT matrices More...
 
subroutine sgtsvx (FACT, TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2, IPIV, B, LDB, X, LDX, RCOND, FERR, BERR, WORK, IWORK, INFO)
  SGTSVX computes the solution to system of linear equations A * X = B for GT matrices More...
 

Detailed Description

This is the group of real solve driver functions for GT matrices

Function Documentation

subroutine sgtsv ( integer  N,
integer  NRHS,
real, dimension( * )  DL,
real, dimension( * )  D,
real, dimension( * )  DU,
real, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

SGTSV computes the solution to system of linear equations A * X = B for GT matrices

Download SGTSV + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGTSV  solves the equation

    A*X = B,

 where A is an n by n tridiagonal matrix, by Gaussian elimination with
 partial pivoting.

 Note that the equation  A**T*X = B  may be solved by interchanging the
 order of the arguments DU and DL.
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in,out]DL
          DL is REAL array, dimension (N-1)
          On entry, DL must contain the (n-1) sub-diagonal elements of
          A.

          On exit, DL is overwritten by the (n-2) elements of the
          second super-diagonal of the upper triangular matrix U from
          the LU factorization of A, in DL(1), ..., DL(n-2).
[in,out]D
          D is REAL array, dimension (N)
          On entry, D must contain the diagonal elements of A.

          On exit, D is overwritten by the n diagonal elements of U.
[in,out]DU
          DU is REAL array, dimension (N-1)
          On entry, DU must contain the (n-1) super-diagonal elements
          of A.

          On exit, DU is overwritten by the (n-1) elements of the first
          super-diagonal of U.
[in,out]B
          B is REAL array, dimension (LDB,NRHS)
          On entry, the N by NRHS matrix of right hand side matrix B.
          On exit, if INFO = 0, the N by NRHS solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
          > 0: if INFO = i, U(i,i) is exactly zero, and the solution
               has not been computed.  The factorization has not been
               completed unless i = N.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 129 of file sgtsv.f.

129 *
130 * -- LAPACK driver routine (version 3.4.2) --
131 * -- LAPACK is a software package provided by Univ. of Tennessee, --
132 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
133 * September 2012
134 *
135 * .. Scalar Arguments ..
136  INTEGER info, ldb, n, nrhs
137 * ..
138 * .. Array Arguments ..
139  REAL b( ldb, * ), d( * ), dl( * ), du( * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  REAL zero
146  parameter( zero = 0.0e+0 )
147 * ..
148 * .. Local Scalars ..
149  INTEGER i, j
150  REAL fact, temp
151 * ..
152 * .. Intrinsic Functions ..
153  INTRINSIC abs, max
154 * ..
155 * .. External Subroutines ..
156  EXTERNAL xerbla
157 * ..
158 * .. Executable Statements ..
159 *
160  info = 0
161  IF( n.LT.0 ) THEN
162  info = -1
163  ELSE IF( nrhs.LT.0 ) THEN
164  info = -2
165  ELSE IF( ldb.LT.max( 1, n ) ) THEN
166  info = -7
167  END IF
168  IF( info.NE.0 ) THEN
169  CALL xerbla( 'SGTSV ', -info )
170  RETURN
171  END IF
172 *
173  IF( n.EQ.0 )
174  $ RETURN
175 *
176  IF( nrhs.EQ.1 ) THEN
177  DO 10 i = 1, n - 2
178  IF( abs( d( i ) ).GE.abs( dl( i ) ) ) THEN
179 *
180 * No row interchange required
181 *
182  IF( d( i ).NE.zero ) THEN
183  fact = dl( i ) / d( i )
184  d( i+1 ) = d( i+1 ) - fact*du( i )
185  b( i+1, 1 ) = b( i+1, 1 ) - fact*b( i, 1 )
186  ELSE
187  info = i
188  RETURN
189  END IF
190  dl( i ) = zero
191  ELSE
192 *
193 * Interchange rows I and I+1
194 *
195  fact = d( i ) / dl( i )
196  d( i ) = dl( i )
197  temp = d( i+1 )
198  d( i+1 ) = du( i ) - fact*temp
199  dl( i ) = du( i+1 )
200  du( i+1 ) = -fact*dl( i )
201  du( i ) = temp
202  temp = b( i, 1 )
203  b( i, 1 ) = b( i+1, 1 )
204  b( i+1, 1 ) = temp - fact*b( i+1, 1 )
205  END IF
206  10 CONTINUE
207  IF( n.GT.1 ) THEN
208  i = n - 1
209  IF( abs( d( i ) ).GE.abs( dl( i ) ) ) THEN
210  IF( d( i ).NE.zero ) THEN
211  fact = dl( i ) / d( i )
212  d( i+1 ) = d( i+1 ) - fact*du( i )
213  b( i+1, 1 ) = b( i+1, 1 ) - fact*b( i, 1 )
214  ELSE
215  info = i
216  RETURN
217  END IF
218  ELSE
219  fact = d( i ) / dl( i )
220  d( i ) = dl( i )
221  temp = d( i+1 )
222  d( i+1 ) = du( i ) - fact*temp
223  du( i ) = temp
224  temp = b( i, 1 )
225  b( i, 1 ) = b( i+1, 1 )
226  b( i+1, 1 ) = temp - fact*b( i+1, 1 )
227  END IF
228  END IF
229  IF( d( n ).EQ.zero ) THEN
230  info = n
231  RETURN
232  END IF
233  ELSE
234  DO 40 i = 1, n - 2
235  IF( abs( d( i ) ).GE.abs( dl( i ) ) ) THEN
236 *
237 * No row interchange required
238 *
239  IF( d( i ).NE.zero ) THEN
240  fact = dl( i ) / d( i )
241  d( i+1 ) = d( i+1 ) - fact*du( i )
242  DO 20 j = 1, nrhs
243  b( i+1, j ) = b( i+1, j ) - fact*b( i, j )
244  20 CONTINUE
245  ELSE
246  info = i
247  RETURN
248  END IF
249  dl( i ) = zero
250  ELSE
251 *
252 * Interchange rows I and I+1
253 *
254  fact = d( i ) / dl( i )
255  d( i ) = dl( i )
256  temp = d( i+1 )
257  d( i+1 ) = du( i ) - fact*temp
258  dl( i ) = du( i+1 )
259  du( i+1 ) = -fact*dl( i )
260  du( i ) = temp
261  DO 30 j = 1, nrhs
262  temp = b( i, j )
263  b( i, j ) = b( i+1, j )
264  b( i+1, j ) = temp - fact*b( i+1, j )
265  30 CONTINUE
266  END IF
267  40 CONTINUE
268  IF( n.GT.1 ) THEN
269  i = n - 1
270  IF( abs( d( i ) ).GE.abs( dl( i ) ) ) THEN
271  IF( d( i ).NE.zero ) THEN
272  fact = dl( i ) / d( i )
273  d( i+1 ) = d( i+1 ) - fact*du( i )
274  DO 50 j = 1, nrhs
275  b( i+1, j ) = b( i+1, j ) - fact*b( i, j )
276  50 CONTINUE
277  ELSE
278  info = i
279  RETURN
280  END IF
281  ELSE
282  fact = d( i ) / dl( i )
283  d( i ) = dl( i )
284  temp = d( i+1 )
285  d( i+1 ) = du( i ) - fact*temp
286  du( i ) = temp
287  DO 60 j = 1, nrhs
288  temp = b( i, j )
289  b( i, j ) = b( i+1, j )
290  b( i+1, j ) = temp - fact*b( i+1, j )
291  60 CONTINUE
292  END IF
293  END IF
294  IF( d( n ).EQ.zero ) THEN
295  info = n
296  RETURN
297  END IF
298  END IF
299 *
300 * Back solve with the matrix U from the factorization.
301 *
302  IF( nrhs.LE.2 ) THEN
303  j = 1
304  70 CONTINUE
305  b( n, j ) = b( n, j ) / d( n )
306  IF( n.GT.1 )
307  $ b( n-1, j ) = ( b( n-1, j )-du( n-1 )*b( n, j ) ) / d( n-1 )
308  DO 80 i = n - 2, 1, -1
309  b( i, j ) = ( b( i, j )-du( i )*b( i+1, j )-dl( i )*
310  $ b( i+2, j ) ) / d( i )
311  80 CONTINUE
312  IF( j.LT.nrhs ) THEN
313  j = j + 1
314  GO TO 70
315  END IF
316  ELSE
317  DO 100 j = 1, nrhs
318  b( n, j ) = b( n, j ) / d( n )
319  IF( n.GT.1 )
320  $ b( n-1, j ) = ( b( n-1, j )-du( n-1 )*b( n, j ) ) /
321  $ d( n-1 )
322  DO 90 i = n - 2, 1, -1
323  b( i, j ) = ( b( i, j )-du( i )*b( i+1, j )-dl( i )*
324  $ b( i+2, j ) ) / d( i )
325  90 CONTINUE
326  100 CONTINUE
327  END IF
328 *
329  RETURN
330 *
331 * End of SGTSV
332 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62

Here is the call graph for this function:

Here is the caller graph for this function:

subroutine sgtsvx ( character  FACT,
character  TRANS,
integer  N,
integer  NRHS,
real, dimension( * )  DL,
real, dimension( * )  D,
real, dimension( * )  DU,
real, dimension( * )  DLF,
real, dimension( * )  DF,
real, dimension( * )  DUF,
real, dimension( * )  DU2,
integer, dimension( * )  IPIV,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( ldx, * )  X,
integer  LDX,
real  RCOND,
real, dimension( * )  FERR,
real, dimension( * )  BERR,
real, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

SGTSVX computes the solution to system of linear equations A * X = B for GT matrices

Download SGTSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGTSVX uses the LU factorization to compute the solution to a real
 system of linear equations A * X = B or A**T * X = B,
 where A is a tridiagonal matrix of order N and X and B are N-by-NRHS
 matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed:

 1. If FACT = 'N', the LU decomposition is used to factor the matrix A
    as A = L * U, where L is a product of permutation and unit lower
    bidiagonal matrices and U is upper triangular with nonzeros in
    only the main diagonal and first two superdiagonals.

 2. If some U(i,i)=0, so that U is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 3. The system of equations is solved for X using the factored form
    of A.

 4. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of A has been
          supplied on entry.
          = 'F':  DLF, DF, DUF, DU2, and IPIV contain the factored
                  form of A; DL, D, DU, DLF, DF, DUF, DU2 and IPIV
                  will not be modified.
          = 'N':  The matrix will be copied to DLF, DF, and DUF
                  and factored.
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the form of the system of equations:
          = 'N':  A * X = B     (No transpose)
          = 'T':  A**T * X = B  (Transpose)
          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in]DL
          DL is REAL array, dimension (N-1)
          The (n-1) subdiagonal elements of A.
[in]D
          D is REAL array, dimension (N)
          The n diagonal elements of A.
[in]DU
          DU is REAL array, dimension (N-1)
          The (n-1) superdiagonal elements of A.
[in,out]DLF
          DLF is REAL array, dimension (N-1)
          If FACT = 'F', then DLF is an input argument and on entry
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A as computed by SGTTRF.

          If FACT = 'N', then DLF is an output argument and on exit
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A.
[in,out]DF
          DF is REAL array, dimension (N)
          If FACT = 'F', then DF is an input argument and on entry
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.

          If FACT = 'N', then DF is an output argument and on exit
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.
[in,out]DUF
          DUF is REAL array, dimension (N-1)
          If FACT = 'F', then DUF is an input argument and on entry
          contains the (n-1) elements of the first superdiagonal of U.

          If FACT = 'N', then DUF is an output argument and on exit
          contains the (n-1) elements of the first superdiagonal of U.
[in,out]DU2
          DU2 is REAL array, dimension (N-2)
          If FACT = 'F', then DU2 is an input argument and on entry
          contains the (n-2) elements of the second superdiagonal of
          U.

          If FACT = 'N', then DU2 is an output argument and on exit
          contains the (n-2) elements of the second superdiagonal of
          U.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains the pivot indices from the LU factorization of A as
          computed by SGTTRF.

          If FACT = 'N', then IPIV is an output argument and on exit
          contains the pivot indices from the LU factorization of A;
          row i of the matrix was interchanged with row IPIV(i).
          IPIV(i) will always be either i or i+1; IPIV(i) = i indicates
          a row interchange was not required.
[in]B
          B is REAL array, dimension (LDB,NRHS)
          The N-by-NRHS right hand side matrix B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is REAL array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
          The estimate of the reciprocal condition number of the matrix
          A.  If RCOND is less than the machine precision (in
          particular, if RCOND = 0), the matrix is singular to working
          precision.  This condition is indicated by a return code of
          INFO > 0.
[out]FERR
          FERR is REAL array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is REAL array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is REAL array, dimension (3*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, and i is
                <= N:  U(i,i) is exactly zero.  The factorization
                       has not been completed unless i = N, but the
                       factor U is exactly singular, so the solution
                       and error bounds could not be computed.
                       RCOND = 0 is returned.
                = N+1: U is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
                       value of RCOND would suggest.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 295 of file sgtsvx.f.

295 *
296 * -- LAPACK driver routine (version 3.4.2) --
297 * -- LAPACK is a software package provided by Univ. of Tennessee, --
298 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
299 * September 2012
300 *
301 * .. Scalar Arguments ..
302  CHARACTER fact, trans
303  INTEGER info, ldb, ldx, n, nrhs
304  REAL rcond
305 * ..
306 * .. Array Arguments ..
307  INTEGER ipiv( * ), iwork( * )
308  REAL b( ldb, * ), berr( * ), d( * ), df( * ),
309  $ dl( * ), dlf( * ), du( * ), du2( * ), duf( * ),
310  $ ferr( * ), work( * ), x( ldx, * )
311 * ..
312 *
313 * =====================================================================
314 *
315 * .. Parameters ..
316  REAL zero
317  parameter( zero = 0.0e+0 )
318 * ..
319 * .. Local Scalars ..
320  LOGICAL nofact, notran
321  CHARACTER norm
322  REAL anorm
323 * ..
324 * .. External Functions ..
325  LOGICAL lsame
326  REAL slamch, slangt
327  EXTERNAL lsame, slamch, slangt
328 * ..
329 * .. External Subroutines ..
330  EXTERNAL scopy, sgtcon, sgtrfs, sgttrf, sgttrs, slacpy,
331  $ xerbla
332 * ..
333 * .. Intrinsic Functions ..
334  INTRINSIC max
335 * ..
336 * .. Executable Statements ..
337 *
338  info = 0
339  nofact = lsame( fact, 'N' )
340  notran = lsame( trans, 'N' )
341  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
342  info = -1
343  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
344  $ lsame( trans, 'C' ) ) THEN
345  info = -2
346  ELSE IF( n.LT.0 ) THEN
347  info = -3
348  ELSE IF( nrhs.LT.0 ) THEN
349  info = -4
350  ELSE IF( ldb.LT.max( 1, n ) ) THEN
351  info = -14
352  ELSE IF( ldx.LT.max( 1, n ) ) THEN
353  info = -16
354  END IF
355  IF( info.NE.0 ) THEN
356  CALL xerbla( 'SGTSVX', -info )
357  RETURN
358  END IF
359 *
360  IF( nofact ) THEN
361 *
362 * Compute the LU factorization of A.
363 *
364  CALL scopy( n, d, 1, df, 1 )
365  IF( n.GT.1 ) THEN
366  CALL scopy( n-1, dl, 1, dlf, 1 )
367  CALL scopy( n-1, du, 1, duf, 1 )
368  END IF
369  CALL sgttrf( n, dlf, df, duf, du2, ipiv, info )
370 *
371 * Return if INFO is non-zero.
372 *
373  IF( info.GT.0 )THEN
374  rcond = zero
375  RETURN
376  END IF
377  END IF
378 *
379 * Compute the norm of the matrix A.
380 *
381  IF( notran ) THEN
382  norm = '1'
383  ELSE
384  norm = 'I'
385  END IF
386  anorm = slangt( norm, n, dl, d, du )
387 *
388 * Compute the reciprocal of the condition number of A.
389 *
390  CALL sgtcon( norm, n, dlf, df, duf, du2, ipiv, anorm, rcond, work,
391  $ iwork, info )
392 *
393 * Compute the solution vectors X.
394 *
395  CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
396  CALL sgttrs( trans, n, nrhs, dlf, df, duf, du2, ipiv, x, ldx,
397  $ info )
398 *
399 * Use iterative refinement to improve the computed solutions and
400 * compute error bounds and backward error estimates for them.
401 *
402  CALL sgtrfs( trans, n, nrhs, dl, d, du, dlf, df, duf, du2, ipiv,
403  $ b, ldb, x, ldx, ferr, berr, work, iwork, info )
404 *
405 * Set INFO = N+1 if the matrix is singular to working precision.
406 *
407  IF( rcond.LT.slamch( 'Epsilon' ) )
408  $ info = n + 1
409 *
410  RETURN
411 *
412 * End of SGTSVX
413 *
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:53
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sgtrfs(TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO)
SGTRFS
Definition: sgtrfs.f:211
real function slangt(NORM, N, DL, D, DU)
SLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slangt.f:108
subroutine sgttrf(N, DL, D, DU, DU2, IPIV, INFO)
SGTTRF
Definition: sgttrf.f:126
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine sgtcon(NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
SGTCON
Definition: sgtcon.f:148
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:105
subroutine sgttrs(TRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB, INFO)
SGTTRS
Definition: sgttrs.f:140

Here is the call graph for this function:

Here is the caller graph for this function: