LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dgrqts()

subroutine dgrqts ( integer  M,
integer  P,
integer  N,
double precision, dimension( lda, * )  A,
double precision, dimension( lda, * )  AF,
double precision, dimension( lda, * )  Q,
double precision, dimension( lda, * )  R,
integer  LDA,
double precision, dimension( * )  TAUA,
double precision, dimension( ldb, * )  B,
double precision, dimension( ldb, * )  BF,
double precision, dimension( ldb, * )  Z,
double precision, dimension( ldb, * )  T,
double precision, dimension( ldb, * )  BWK,
integer  LDB,
double precision, dimension( * )  TAUB,
double precision, dimension( lwork )  WORK,
integer  LWORK,
double precision, dimension( * )  RWORK,
double precision, dimension( 4 )  RESULT 
)

DGRQTS

Purpose:
 DGRQTS tests DGGRQF, which computes the GRQ factorization of an
 M-by-N matrix A and a P-by-N matrix B: A = R*Q and B = Z*T*Q.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]P
          P is INTEGER
          The number of rows of the matrix B.  P >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrices A and B.  N >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The M-by-N matrix A.
[out]AF
          AF is DOUBLE PRECISION array, dimension (LDA,N)
          Details of the GRQ factorization of A and B, as returned
          by DGGRQF, see SGGRQF for further details.
[out]Q
          Q is DOUBLE PRECISION array, dimension (LDA,N)
          The N-by-N orthogonal matrix Q.
[out]R
          R is DOUBLE PRECISION array, dimension (LDA,MAX(M,N))
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, R and Q.
          LDA >= max(M,N).
[out]TAUA
          TAUA is DOUBLE PRECISION array, dimension (min(M,N))
          The scalar factors of the elementary reflectors, as returned
          by DGGQRC.
[in]B
          B is DOUBLE PRECISION array, dimension (LDB,N)
          On entry, the P-by-N matrix A.
[out]BF
          BF is DOUBLE PRECISION array, dimension (LDB,N)
          Details of the GQR factorization of A and B, as returned
          by DGGRQF, see SGGRQF for further details.
[out]Z
          Z is DOUBLE PRECISION array, dimension (LDB,P)
          The P-by-P orthogonal matrix Z.
[out]T
          T is DOUBLE PRECISION array, dimension (LDB,max(P,N))
[out]BWK
          BWK is DOUBLE PRECISION array, dimension (LDB,N)
[in]LDB
          LDB is INTEGER
          The leading dimension of the arrays B, BF, Z and T.
          LDB >= max(P,N).
[out]TAUB
          TAUB is DOUBLE PRECISION array, dimension (min(P,N))
          The scalar factors of the elementary reflectors, as returned
          by DGGRQF.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK, LWORK >= max(M,P,N)**2.
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (M)
[out]RESULT
          RESULT is DOUBLE PRECISION array, dimension (4)
          The test ratios:
            RESULT(1) = norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP)
            RESULT(2) = norm( T*Q - Z'*B ) / (MAX(P,N)*norm(B)*ULP)
            RESULT(3) = norm( I - Q'*Q ) / ( N*ULP )
            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 178 of file dgrqts.f.

178 *
179 * -- LAPACK test routine (version 3.7.0) --
180 * -- LAPACK is a software package provided by Univ. of Tennessee, --
181 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
182 * December 2016
183 *
184 * .. Scalar Arguments ..
185  INTEGER lda, ldb, lwork, m, n, p
186 * ..
187 * .. Array Arguments ..
188  DOUBLE PRECISION a( lda, * ), af( lda, * ), b( ldb, * ),
189  $ bf( ldb, * ), bwk( ldb, * ), q( lda, * ),
190  $ r( lda, * ), result( 4 ), rwork( * ),
191  $ t( ldb, * ), taua( * ), taub( * ),
192  $ work( lwork ), z( ldb, * )
193 * ..
194 *
195 * =====================================================================
196 *
197 * .. Parameters ..
198  DOUBLE PRECISION zero, one
199  parameter( zero = 0.0d+0, one = 1.0d+0 )
200  DOUBLE PRECISION rogue
201  parameter( rogue = -1.0d+10 )
202 * ..
203 * .. Local Scalars ..
204  INTEGER info
205  DOUBLE PRECISION anorm, bnorm, resid, ulp, unfl
206 * ..
207 * .. External Functions ..
208  DOUBLE PRECISION dlamch, dlange, dlansy
209  EXTERNAL dlamch, dlange, dlansy
210 * ..
211 * .. External Subroutines ..
212  EXTERNAL dgemm, dggrqf, dlacpy, dlaset, dorgqr, dorgrq,
213  $ dsyrk
214 * ..
215 * .. Intrinsic Functions ..
216  INTRINSIC dble, max, min
217 * ..
218 * .. Executable Statements ..
219 *
220  ulp = dlamch( 'Precision' )
221  unfl = dlamch( 'Safe minimum' )
222 *
223 * Copy the matrix A to the array AF.
224 *
225  CALL dlacpy( 'Full', m, n, a, lda, af, lda )
226  CALL dlacpy( 'Full', p, n, b, ldb, bf, ldb )
227 *
228  anorm = max( dlange( '1', m, n, a, lda, rwork ), unfl )
229  bnorm = max( dlange( '1', p, n, b, ldb, rwork ), unfl )
230 *
231 * Factorize the matrices A and B in the arrays AF and BF.
232 *
233  CALL dggrqf( m, p, n, af, lda, taua, bf, ldb, taub, work, lwork,
234  $ info )
235 *
236 * Generate the N-by-N matrix Q
237 *
238  CALL dlaset( 'Full', n, n, rogue, rogue, q, lda )
239  IF( m.LE.n ) THEN
240  IF( m.GT.0 .AND. m.LT.n )
241  $ CALL dlacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
242  IF( m.GT.1 )
243  $ CALL dlacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
244  $ q( n-m+2, n-m+1 ), lda )
245  ELSE
246  IF( n.GT.1 )
247  $ CALL dlacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
248  $ q( 2, 1 ), lda )
249  END IF
250  CALL dorgrq( n, n, min( m, n ), q, lda, taua, work, lwork, info )
251 *
252 * Generate the P-by-P matrix Z
253 *
254  CALL dlaset( 'Full', p, p, rogue, rogue, z, ldb )
255  IF( p.GT.1 )
256  $ CALL dlacpy( 'Lower', p-1, n, bf( 2, 1 ), ldb, z( 2, 1 ), ldb )
257  CALL dorgqr( p, p, min( p, n ), z, ldb, taub, work, lwork, info )
258 *
259 * Copy R
260 *
261  CALL dlaset( 'Full', m, n, zero, zero, r, lda )
262  IF( m.LE.n ) THEN
263  CALL dlacpy( 'Upper', m, m, af( 1, n-m+1 ), lda, r( 1, n-m+1 ),
264  $ lda )
265  ELSE
266  CALL dlacpy( 'Full', m-n, n, af, lda, r, lda )
267  CALL dlacpy( 'Upper', n, n, af( m-n+1, 1 ), lda, r( m-n+1, 1 ),
268  $ lda )
269  END IF
270 *
271 * Copy T
272 *
273  CALL dlaset( 'Full', p, n, zero, zero, t, ldb )
274  CALL dlacpy( 'Upper', p, n, bf, ldb, t, ldb )
275 *
276 * Compute R - A*Q'
277 *
278  CALL dgemm( 'No transpose', 'Transpose', m, n, n, -one, a, lda, q,
279  $ lda, one, r, lda )
280 *
281 * Compute norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP ) .
282 *
283  resid = dlange( '1', m, n, r, lda, rwork )
284  IF( anorm.GT.zero ) THEN
285  result( 1 ) = ( ( resid / dble( max( 1, m, n ) ) ) / anorm ) /
286  $ ulp
287  ELSE
288  result( 1 ) = zero
289  END IF
290 *
291 * Compute T*Q - Z'*B
292 *
293  CALL dgemm( 'Transpose', 'No transpose', p, n, p, one, z, ldb, b,
294  $ ldb, zero, bwk, ldb )
295  CALL dgemm( 'No transpose', 'No transpose', p, n, n, one, t, ldb,
296  $ q, lda, -one, bwk, ldb )
297 *
298 * Compute norm( T*Q - Z'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
299 *
300  resid = dlange( '1', p, n, bwk, ldb, rwork )
301  IF( bnorm.GT.zero ) THEN
302  result( 2 ) = ( ( resid / dble( max( 1, p, m ) ) ) / bnorm ) /
303  $ ulp
304  ELSE
305  result( 2 ) = zero
306  END IF
307 *
308 * Compute I - Q*Q'
309 *
310  CALL dlaset( 'Full', n, n, zero, one, r, lda )
311  CALL dsyrk( 'Upper', 'No Transpose', n, n, -one, q, lda, one, r,
312  $ lda )
313 *
314 * Compute norm( I - Q'*Q ) / ( N * ULP ) .
315 *
316  resid = dlansy( '1', 'Upper', n, r, lda, rwork )
317  result( 3 ) = ( resid / dble( max( 1, n ) ) ) / ulp
318 *
319 * Compute I - Z'*Z
320 *
321  CALL dlaset( 'Full', p, p, zero, one, t, ldb )
322  CALL dsyrk( 'Upper', 'Transpose', p, p, -one, z, ldb, one, t,
323  $ ldb )
324 *
325 * Compute norm( I - Z'*Z ) / ( P*ULP ) .
326 *
327  resid = dlansy( '1', 'Upper', p, t, ldb, rwork )
328  result( 4 ) = ( resid / dble( max( 1, p ) ) ) / ulp
329 *
330  RETURN
331 *
332 * End of DGRQTS
333 *
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:105
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
double precision function dlansy(NORM, UPLO, N, A, LDA, WORK)
DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.
Definition: dlansy.f:124
subroutine dggrqf(M, P, N, A, LDA, TAUA, B, LDB, TAUB, WORK, LWORK, INFO)
DGGRQF
Definition: dggrqf.f:216
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: dlaset.f:112
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:189
subroutine dsyrk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
DSYRK
Definition: dsyrk.f:171
subroutine dorgqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
DORGQR
Definition: dorgqr.f:130
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:116
subroutine dorgrq(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
DORGRQ
Definition: dorgrq.f:130
Here is the call graph for this function:
Here is the caller graph for this function: