LAPACK  3.9.0 LAPACK: Linear Algebra PACKage
clanhp.f
Go to the documentation of this file.
1 *> \brief \b CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhp.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhp.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhp.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANHP( NORM, UPLO, N, AP, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX AP( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANHP returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex hermitian matrix A, supplied in packed form.
41 *> \endverbatim
42 *>
43 *> \return CLANHP
44 *> \verbatim
45 *>
46 *> CLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANHP as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> hermitian matrix A is supplied.
75 *> = 'U': Upper triangular part of A is supplied
76 *> = 'L': Lower triangular part of A is supplied
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, CLANHP is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] AP
87 *> \verbatim
88 *> AP is COMPLEX array, dimension (N*(N+1)/2)
89 *> The upper or lower triangle of the hermitian matrix A, packed
90 *> columnwise in a linear array. The j-th column of A is stored
91 *> in the array AP as follows:
92 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93 *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94 *> Note that the imaginary parts of the diagonal elements need
95 *> not be set and are assumed to be zero.
96 *> \endverbatim
97 *>
98 *> \param[out] WORK
99 *> \verbatim
100 *> WORK is REAL array, dimension (MAX(1,LWORK)),
101 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
102 *> WORK is not referenced.
103 *> \endverbatim
104 *
105 * Authors:
106 * ========
107 *
108 *> \author Univ. of Tennessee
109 *> \author Univ. of California Berkeley
110 *> \author Univ. of Colorado Denver
111 *> \author NAG Ltd.
112 *
113 *> \date December 2016
114 *
115 *> \ingroup complexOTHERauxiliary
116 *
117 * =====================================================================
118  REAL FUNCTION CLANHP( NORM, UPLO, N, AP, WORK )
119 *
120 * -- LAPACK auxiliary routine (version 3.7.0) --
121 * -- LAPACK is a software package provided by Univ. of Tennessee, --
122 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
123 * December 2016
124 *
125  IMPLICIT NONE
126 * .. Scalar Arguments ..
127  CHARACTER norm, uplo
128  INTEGER n
129 * ..
130 * .. Array Arguments ..
131  REAL work( * )
132  COMPLEX ap( * )
133 * ..
134 *
135 * =====================================================================
136 *
137 * .. Parameters ..
138  REAL one, zero
139  parameter( one = 1.0e+0, zero = 0.0e+0 )
140 * ..
141 * .. Local Scalars ..
142  INTEGER i, j, k
143  REAL absa, sum, value
144 * ..
145 * .. Local Arrays ..
146  REAL ssq( 2 ), colssq( 2 )
147 * ..
148 * .. External Functions ..
149  LOGICAL lsame, sisnan
150  EXTERNAL lsame, sisnan
151 * ..
152 * .. External Subroutines ..
153  EXTERNAL classq, scombssq
154 * ..
155 * .. Intrinsic Functions ..
156  INTRINSIC abs, real, sqrt
157 * ..
158 * .. Executable Statements ..
159 *
160  IF( n.EQ.0 ) THEN
161  VALUE = zero
162  ELSE IF( lsame( norm, 'M' ) ) THEN
163 *
164 * Find max(abs(A(i,j))).
165 *
166  VALUE = zero
167  IF( lsame( uplo, 'U' ) ) THEN
168  k = 0
169  DO 20 j = 1, n
170  DO 10 i = k + 1, k + j - 1
171  sum = abs( ap( i ) )
172  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
173  10 CONTINUE
174  k = k + j
175  sum = abs( real( ap( k ) ) )
176  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
177  20 CONTINUE
178  ELSE
179  k = 1
180  DO 40 j = 1, n
181  sum = abs( real( ap( k ) ) )
182  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
183  DO 30 i = k + 1, k + n - j
184  sum = abs( ap( i ) )
185  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
186  30 CONTINUE
187  k = k + n - j + 1
188  40 CONTINUE
189  END IF
190  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
191  \$ ( norm.EQ.'1' ) ) THEN
192 *
193 * Find normI(A) ( = norm1(A), since A is hermitian).
194 *
195  VALUE = zero
196  k = 1
197  IF( lsame( uplo, 'U' ) ) THEN
198  DO 60 j = 1, n
199  sum = zero
200  DO 50 i = 1, j - 1
201  absa = abs( ap( k ) )
202  sum = sum + absa
203  work( i ) = work( i ) + absa
204  k = k + 1
205  50 CONTINUE
206  work( j ) = sum + abs( real( ap( k ) ) )
207  k = k + 1
208  60 CONTINUE
209  DO 70 i = 1, n
210  sum = work( i )
211  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
212  70 CONTINUE
213  ELSE
214  DO 80 i = 1, n
215  work( i ) = zero
216  80 CONTINUE
217  DO 100 j = 1, n
218  sum = work( j ) + abs( real( ap( k ) ) )
219  k = k + 1
220  DO 90 i = j + 1, n
221  absa = abs( ap( k ) )
222  sum = sum + absa
223  work( i ) = work( i ) + absa
224  k = k + 1
225  90 CONTINUE
226  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
227  100 CONTINUE
228  END IF
229  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
230 *
231 * Find normF(A).
232 * SSQ(1) is scale
233 * SSQ(2) is sum-of-squares
234 * For better accuracy, sum each column separately.
235 *
236  ssq( 1 ) = zero
237  ssq( 2 ) = one
238 *
239 * Sum off-diagonals
240 *
241  k = 2
242  IF( lsame( uplo, 'U' ) ) THEN
243  DO 110 j = 2, n
244  colssq( 1 ) = zero
245  colssq( 2 ) = one
246  CALL classq( j-1, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
247  CALL scombssq( ssq, colssq )
248  k = k + j
249  110 CONTINUE
250  ELSE
251  DO 120 j = 1, n - 1
252  colssq( 1 ) = zero
253  colssq( 2 ) = one
254  CALL classq( n-j, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
255  CALL scombssq( ssq, colssq )
256  k = k + n - j + 1
257  120 CONTINUE
258  END IF
259  ssq( 2 ) = 2*ssq( 2 )
260 *
261 * Sum diagonal
262 *
263  k = 1
264  colssq( 1 ) = zero
265  colssq( 2 ) = one
266  DO 130 i = 1, n
267  IF( real( ap( k ) ).NE.zero ) THEN
268  absa = abs( real( ap( k ) ) )
269  IF( colssq( 1 ).LT.absa ) THEN
270  colssq( 2 ) = one + colssq(2)*( colssq(1) / absa )**2
271  colssq( 1 ) = absa
272  ELSE
273  colssq( 2 ) = colssq( 2 ) + ( absa / colssq( 1 ) )**2
274  END IF
275  END IF
276  IF( lsame( uplo, 'U' ) ) THEN
277  k = k + i + 1
278  ELSE
279  k = k + n - i + 1
280  END IF
281  130 CONTINUE
282  CALL scombssq( ssq, colssq )
283  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
284  END IF
285 *
286  clanhp = VALUE
287  RETURN
288 *
289 * End of CLANHP
290 *
291  END
classq
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
sisnan
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:61
clanhp
real function clanhp(NORM, UPLO, N, AP, WORK)
CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhp.f:119
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
scombssq
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:62