 LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

## ◆ dlanhs()

 double precision function dlanhs ( character NORM, integer N, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) WORK )

DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.

Download DLANHS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` DLANHS  returns the value of the one norm,  or the Frobenius norm, or
the  infinity norm,  or the  element of  largest absolute value  of a
Hessenberg matrix A.```
Returns
DLANHS
```    DLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
(
( norm1(A),         NORM = '1', 'O' or 'o'
(
( normI(A),         NORM = 'I' or 'i'
(
( normF(A),         NORM = 'F', 'f', 'E' or 'e'

where  norm1  denotes the  one norm of a matrix (maximum column sum),
normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
normF  denotes the  Frobenius norm of a matrix (square root of sum of
squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies the value to be returned in DLANHS as described above.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0. When N = 0, DLANHS is set to zero.``` [in] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) The n by n upper Hessenberg matrix A; the part of A below the first sub-diagonal is not referenced.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(N,1).``` [out] WORK ``` WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), where LWORK >= N when NORM = 'I'; otherwise, WORK is not referenced.```
Date
December 2016

Definition at line 110 of file dlanhs.f.

110 *
111 * -- LAPACK auxiliary routine (version 3.7.0) --
112 * -- LAPACK is a software package provided by Univ. of Tennessee, --
113 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
114 * December 2016
115 *
116 * .. Scalar Arguments ..
117  CHARACTER norm
118  INTEGER lda, n
119 * ..
120 * .. Array Arguments ..
121  DOUBLE PRECISION a( lda, * ), work( * )
122 * ..
123 *
124 * =====================================================================
125 *
126 * .. Parameters ..
127  DOUBLE PRECISION one, zero
128  parameter( one = 1.0d+0, zero = 0.0d+0 )
129 * ..
130 * .. Local Scalars ..
131  INTEGER i, j
132  DOUBLE PRECISION scale, sum, value
133 * ..
134 * .. External Subroutines ..
135  EXTERNAL dlassq
136 * ..
137 * .. External Functions ..
138  LOGICAL lsame, disnan
139  EXTERNAL lsame, disnan
140 * ..
141 * .. Intrinsic Functions ..
142  INTRINSIC abs, min, sqrt
143 * ..
144 * .. Executable Statements ..
145 *
146  IF( n.EQ.0 ) THEN
147  VALUE = zero
148  ELSE IF( lsame( norm, 'M' ) ) THEN
149 *
150 * Find max(abs(A(i,j))).
151 *
152  VALUE = zero
153  DO 20 j = 1, n
154  DO 10 i = 1, min( n, j+1 )
155  sum = abs( a( i, j ) )
156  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
157  10 CONTINUE
158  20 CONTINUE
159  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
160 *
161 * Find norm1(A).
162 *
163  VALUE = zero
164  DO 40 j = 1, n
165  sum = zero
166  DO 30 i = 1, min( n, j+1 )
167  sum = sum + abs( a( i, j ) )
168  30 CONTINUE
169  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
170  40 CONTINUE
171  ELSE IF( lsame( norm, 'I' ) ) THEN
172 *
173 * Find normI(A).
174 *
175  DO 50 i = 1, n
176  work( i ) = zero
177  50 CONTINUE
178  DO 70 j = 1, n
179  DO 60 i = 1, min( n, j+1 )
180  work( i ) = work( i ) + abs( a( i, j ) )
181  60 CONTINUE
182  70 CONTINUE
183  VALUE = zero
184  DO 80 i = 1, n
185  sum = work( i )
186  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
187  80 CONTINUE
188  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
189 *
190 * Find normF(A).
191 *
192  scale = zero
193  sum = one
194  DO 90 j = 1, n
195  CALL dlassq( min( n, j+1 ), a( 1, j ), 1, scale, sum )
196  90 CONTINUE
197  VALUE = scale*sqrt( sum )
198  END IF
199 *
200  dlanhs = VALUE
201  RETURN
202 *
203 * End of DLANHS
204 *
double precision function dlanhs(NORM, N, A, LDA, WORK)
DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlanhs.f:110
subroutine dlassq(N, X, INCX, SCALE, SUMSQ)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f:105
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
Here is the call graph for this function: