LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlahrd()

subroutine dlahrd ( integer  N,
integer  K,
integer  NB,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( nb )  TAU,
double precision, dimension( ldt, nb )  T,
integer  LDT,
double precision, dimension( ldy, nb )  Y,
integer  LDY 
)

DLAHRD reduces the first nb columns of a general rectangular matrix A so that elements below the k-th subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Download DLAHRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 This routine is deprecated and has been replaced by routine DLAHR2.

 DLAHRD reduces the first NB columns of a real general n-by-(n-k+1)
 matrix A so that elements below the k-th subdiagonal are zero. The
 reduction is performed by an orthogonal similarity transformation
 Q**T * A * Q. The routine returns the matrices V and T which determine
 Q as a block reflector I - V*T*V**T, and also the matrix Y = A * V * T.
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.
[in]K
          K is INTEGER
          The offset for the reduction. Elements below the k-th
          subdiagonal in the first NB columns are reduced to zero.
[in]NB
          NB is INTEGER
          The number of columns to be reduced.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N-K+1)
          On entry, the n-by-(n-k+1) general matrix A.
          On exit, the elements on and above the k-th subdiagonal in
          the first NB columns are overwritten with the corresponding
          elements of the reduced matrix; the elements below the k-th
          subdiagonal, with the array TAU, represent the matrix Q as a
          product of elementary reflectors. The other columns of A are
          unchanged. See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]TAU
          TAU is DOUBLE PRECISION array, dimension (NB)
          The scalar factors of the elementary reflectors. See Further
          Details.
[out]T
          T is DOUBLE PRECISION array, dimension (LDT,NB)
          The upper triangular matrix T.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= NB.
[out]Y
          Y is DOUBLE PRECISION array, dimension (LDY,NB)
          The n-by-nb matrix Y.
[in]LDY
          LDY is INTEGER
          The leading dimension of the array Y. LDY >= N.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:
  The matrix Q is represented as a product of nb elementary reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
  A(i+k+1:n,i), and tau in TAU(i).

  The elements of the vectors v together form the (n-k+1)-by-nb matrix
  V which is needed, with T and Y, to apply the transformation to the
  unreduced part of the matrix, using an update of the form:
  A := (I - V*T*V**T) * (A - Y*V**T).

  The contents of A on exit are illustrated by the following example
  with n = 7, k = 3 and nb = 2:

     ( a   h   a   a   a )
     ( a   h   a   a   a )
     ( a   h   a   a   a )
     ( h   h   a   a   a )
     ( v1  h   a   a   a )
     ( v1  v2  a   a   a )
     ( v1  v2  a   a   a )

  where a denotes an element of the original matrix A, h denotes a
  modified element of the upper Hessenberg matrix H, and vi denotes an
  element of the vector defining H(i).

Definition at line 169 of file dlahrd.f.

169 *
170 * -- LAPACK auxiliary routine (version 3.7.0) --
171 * -- LAPACK is a software package provided by Univ. of Tennessee, --
172 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
173 * December 2016
174 *
175 * .. Scalar Arguments ..
176  INTEGER k, lda, ldt, ldy, n, nb
177 * ..
178 * .. Array Arguments ..
179  DOUBLE PRECISION a( lda, * ), t( ldt, nb ), tau( nb ),
180  $ y( ldy, nb )
181 * ..
182 *
183 * =====================================================================
184 *
185 * .. Parameters ..
186  DOUBLE PRECISION zero, one
187  parameter( zero = 0.0d+0, one = 1.0d+0 )
188 * ..
189 * .. Local Scalars ..
190  INTEGER i
191  DOUBLE PRECISION ei
192 * ..
193 * .. External Subroutines ..
194  EXTERNAL daxpy, dcopy, dgemv, dlarfg, dscal, dtrmv
195 * ..
196 * .. Intrinsic Functions ..
197  INTRINSIC min
198 * ..
199 * .. Executable Statements ..
200 *
201 * Quick return if possible
202 *
203  IF( n.LE.1 )
204  $ RETURN
205 *
206  DO 10 i = 1, nb
207  IF( i.GT.1 ) THEN
208 *
209 * Update A(1:n,i)
210 *
211 * Compute i-th column of A - Y * V**T
212 *
213  CALL dgemv( 'No transpose', n, i-1, -one, y, ldy,
214  $ a( k+i-1, 1 ), lda, one, a( 1, i ), 1 )
215 *
216 * Apply I - V * T**T * V**T to this column (call it b) from the
217 * left, using the last column of T as workspace
218 *
219 * Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
220 * ( V2 ) ( b2 )
221 *
222 * where V1 is unit lower triangular
223 *
224 * w := V1**T * b1
225 *
226  CALL dcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
227  CALL dtrmv( 'Lower', 'Transpose', 'Unit', i-1, a( k+1, 1 ),
228  $ lda, t( 1, nb ), 1 )
229 *
230 * w := w + V2**T *b2
231 *
232  CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ),
233  $ lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
234 *
235 * w := T**T *w
236 *
237  CALL dtrmv( 'Upper', 'Transpose', 'Non-unit', i-1, t, ldt,
238  $ t( 1, nb ), 1 )
239 *
240 * b2 := b2 - V2*w
241 *
242  CALL dgemv( 'No transpose', n-k-i+1, i-1, -one, a( k+i, 1 ),
243  $ lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
244 *
245 * b1 := b1 - V1*w
246 *
247  CALL dtrmv( 'Lower', 'No transpose', 'Unit', i-1,
248  $ a( k+1, 1 ), lda, t( 1, nb ), 1 )
249  CALL daxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
250 *
251  a( k+i-1, i-1 ) = ei
252  END IF
253 *
254 * Generate the elementary reflector H(i) to annihilate
255 * A(k+i+1:n,i)
256 *
257  CALL dlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
258  $ tau( i ) )
259  ei = a( k+i, i )
260  a( k+i, i ) = one
261 *
262 * Compute Y(1:n,i)
263 *
264  CALL dgemv( 'No transpose', n, n-k-i+1, one, a( 1, i+1 ), lda,
265  $ a( k+i, i ), 1, zero, y( 1, i ), 1 )
266  CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ), lda,
267  $ a( k+i, i ), 1, zero, t( 1, i ), 1 )
268  CALL dgemv( 'No transpose', n, i-1, -one, y, ldy, t( 1, i ), 1,
269  $ one, y( 1, i ), 1 )
270  CALL dscal( n, tau( i ), y( 1, i ), 1 )
271 *
272 * Compute T(1:i,i)
273 *
274  CALL dscal( i-1, -tau( i ), t( 1, i ), 1 )
275  CALL dtrmv( 'Upper', 'No transpose', 'Non-unit', i-1, t, ldt,
276  $ t( 1, i ), 1 )
277  t( i, i ) = tau( i )
278 *
279  10 CONTINUE
280  a( k+nb, nb ) = ei
281 *
282  RETURN
283 *
284 * End of DLAHRD
285 *
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:91
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:81
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:84
subroutine dtrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
DTRMV
Definition: dtrmv.f:149
subroutine dgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGEMV
Definition: dgemv.f:158
subroutine dlarfg(N, ALPHA, X, INCX, TAU)
DLARFG generates an elementary reflector (Householder matrix).
Definition: dlarfg.f:108
Here is the call graph for this function: