LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlatrd()

subroutine dlatrd ( character  UPLO,
integer  N,
integer  NB,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  E,
double precision, dimension( * )  TAU,
double precision, dimension( ldw, * )  W,
integer  LDW 
)

DLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal form by an orthogonal similarity transformation.

Download DLATRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLATRD reduces NB rows and columns of a real symmetric matrix A to
 symmetric tridiagonal form by an orthogonal similarity
 transformation Q**T * A * Q, and returns the matrices V and W which are
 needed to apply the transformation to the unreduced part of A.

 If UPLO = 'U', DLATRD reduces the last NB rows and columns of a
 matrix, of which the upper triangle is supplied;
 if UPLO = 'L', DLATRD reduces the first NB rows and columns of a
 matrix, of which the lower triangle is supplied.

 This is an auxiliary routine called by DSYTRD.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          symmetric matrix A is stored:
          = 'U': Upper triangular
          = 'L': Lower triangular
[in]N
          N is INTEGER
          The order of the matrix A.
[in]NB
          NB is INTEGER
          The number of rows and columns to be reduced.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
          n-by-n upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading n-by-n lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.
          On exit:
          if UPLO = 'U', the last NB columns have been reduced to
            tridiagonal form, with the diagonal elements overwriting
            the diagonal elements of A; the elements above the diagonal
            with the array TAU, represent the orthogonal matrix Q as a
            product of elementary reflectors;
          if UPLO = 'L', the first NB columns have been reduced to
            tridiagonal form, with the diagonal elements overwriting
            the diagonal elements of A; the elements below the diagonal
            with the array TAU, represent the  orthogonal matrix Q as a
            product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= (1,N).
[out]E
          E is DOUBLE PRECISION array, dimension (N-1)
          If UPLO = 'U', E(n-nb:n-1) contains the superdiagonal
          elements of the last NB columns of the reduced matrix;
          if UPLO = 'L', E(1:nb) contains the subdiagonal elements of
          the first NB columns of the reduced matrix.
[out]TAU
          TAU is DOUBLE PRECISION array, dimension (N-1)
          The scalar factors of the elementary reflectors, stored in
          TAU(n-nb:n-1) if UPLO = 'U', and in TAU(1:nb) if UPLO = 'L'.
          See Further Details.
[out]W
          W is DOUBLE PRECISION array, dimension (LDW,NB)
          The n-by-nb matrix W required to update the unreduced part
          of A.
[in]LDW
          LDW is INTEGER
          The leading dimension of the array W. LDW >= max(1,N).
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:
  If UPLO = 'U', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(n) H(n-1) . . . H(n-nb+1).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in A(1:i-1,i),
  and tau in TAU(i-1).

  If UPLO = 'L', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i) = 0 and v(i+1) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
  and tau in TAU(i).

  The elements of the vectors v together form the n-by-nb matrix V
  which is needed, with W, to apply the transformation to the unreduced
  part of the matrix, using a symmetric rank-2k update of the form:
  A := A - V*W**T - W*V**T.

  The contents of A on exit are illustrated by the following examples
  with n = 5 and nb = 2:

  if UPLO = 'U':                       if UPLO = 'L':

    (  a   a   a   v4  v5 )              (  d                  )
    (      a   a   v4  v5 )              (  1   d              )
    (          a   1   v5 )              (  v1  1   a          )
    (              d   1  )              (  v1  v2  a   a      )
    (                  d  )              (  v1  v2  a   a   a  )

  where d denotes a diagonal element of the reduced matrix, a denotes
  an element of the original matrix that is unchanged, and vi denotes
  an element of the vector defining H(i).

Definition at line 200 of file dlatrd.f.

200 *
201 * -- LAPACK auxiliary routine (version 3.7.0) --
202 * -- LAPACK is a software package provided by Univ. of Tennessee, --
203 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
204 * December 2016
205 *
206 * .. Scalar Arguments ..
207  CHARACTER uplo
208  INTEGER lda, ldw, n, nb
209 * ..
210 * .. Array Arguments ..
211  DOUBLE PRECISION a( lda, * ), e( * ), tau( * ), w( ldw, * )
212 * ..
213 *
214 * =====================================================================
215 *
216 * .. Parameters ..
217  DOUBLE PRECISION zero, one, half
218  parameter( zero = 0.0d+0, one = 1.0d+0, half = 0.5d+0 )
219 * ..
220 * .. Local Scalars ..
221  INTEGER i, iw
222  DOUBLE PRECISION alpha
223 * ..
224 * .. External Subroutines ..
225  EXTERNAL daxpy, dgemv, dlarfg, dscal, dsymv
226 * ..
227 * .. External Functions ..
228  LOGICAL lsame
229  DOUBLE PRECISION ddot
230  EXTERNAL lsame, ddot
231 * ..
232 * .. Intrinsic Functions ..
233  INTRINSIC min
234 * ..
235 * .. Executable Statements ..
236 *
237 * Quick return if possible
238 *
239  IF( n.LE.0 )
240  $ RETURN
241 *
242  IF( lsame( uplo, 'U' ) ) THEN
243 *
244 * Reduce last NB columns of upper triangle
245 *
246  DO 10 i = n, n - nb + 1, -1
247  iw = i - n + nb
248  IF( i.LT.n ) THEN
249 *
250 * Update A(1:i,i)
251 *
252  CALL dgemv( 'No transpose', i, n-i, -one, a( 1, i+1 ),
253  $ lda, w( i, iw+1 ), ldw, one, a( 1, i ), 1 )
254  CALL dgemv( 'No transpose', i, n-i, -one, w( 1, iw+1 ),
255  $ ldw, a( i, i+1 ), lda, one, a( 1, i ), 1 )
256  END IF
257  IF( i.GT.1 ) THEN
258 *
259 * Generate elementary reflector H(i) to annihilate
260 * A(1:i-2,i)
261 *
262  CALL dlarfg( i-1, a( i-1, i ), a( 1, i ), 1, tau( i-1 ) )
263  e( i-1 ) = a( i-1, i )
264  a( i-1, i ) = one
265 *
266 * Compute W(1:i-1,i)
267 *
268  CALL dsymv( 'Upper', i-1, one, a, lda, a( 1, i ), 1,
269  $ zero, w( 1, iw ), 1 )
270  IF( i.LT.n ) THEN
271  CALL dgemv( 'Transpose', i-1, n-i, one, w( 1, iw+1 ),
272  $ ldw, a( 1, i ), 1, zero, w( i+1, iw ), 1 )
273  CALL dgemv( 'No transpose', i-1, n-i, -one,
274  $ a( 1, i+1 ), lda, w( i+1, iw ), 1, one,
275  $ w( 1, iw ), 1 )
276  CALL dgemv( 'Transpose', i-1, n-i, one, a( 1, i+1 ),
277  $ lda, a( 1, i ), 1, zero, w( i+1, iw ), 1 )
278  CALL dgemv( 'No transpose', i-1, n-i, -one,
279  $ w( 1, iw+1 ), ldw, w( i+1, iw ), 1, one,
280  $ w( 1, iw ), 1 )
281  END IF
282  CALL dscal( i-1, tau( i-1 ), w( 1, iw ), 1 )
283  alpha = -half*tau( i-1 )*ddot( i-1, w( 1, iw ), 1,
284  $ a( 1, i ), 1 )
285  CALL daxpy( i-1, alpha, a( 1, i ), 1, w( 1, iw ), 1 )
286  END IF
287 *
288  10 CONTINUE
289  ELSE
290 *
291 * Reduce first NB columns of lower triangle
292 *
293  DO 20 i = 1, nb
294 *
295 * Update A(i:n,i)
296 *
297  CALL dgemv( 'No transpose', n-i+1, i-1, -one, a( i, 1 ),
298  $ lda, w( i, 1 ), ldw, one, a( i, i ), 1 )
299  CALL dgemv( 'No transpose', n-i+1, i-1, -one, w( i, 1 ),
300  $ ldw, a( i, 1 ), lda, one, a( i, i ), 1 )
301  IF( i.LT.n ) THEN
302 *
303 * Generate elementary reflector H(i) to annihilate
304 * A(i+2:n,i)
305 *
306  CALL dlarfg( n-i, a( i+1, i ), a( min( i+2, n ), i ), 1,
307  $ tau( i ) )
308  e( i ) = a( i+1, i )
309  a( i+1, i ) = one
310 *
311 * Compute W(i+1:n,i)
312 *
313  CALL dsymv( 'Lower', n-i, one, a( i+1, i+1 ), lda,
314  $ a( i+1, i ), 1, zero, w( i+1, i ), 1 )
315  CALL dgemv( 'Transpose', n-i, i-1, one, w( i+1, 1 ), ldw,
316  $ a( i+1, i ), 1, zero, w( 1, i ), 1 )
317  CALL dgemv( 'No transpose', n-i, i-1, -one, a( i+1, 1 ),
318  $ lda, w( 1, i ), 1, one, w( i+1, i ), 1 )
319  CALL dgemv( 'Transpose', n-i, i-1, one, a( i+1, 1 ), lda,
320  $ a( i+1, i ), 1, zero, w( 1, i ), 1 )
321  CALL dgemv( 'No transpose', n-i, i-1, -one, w( i+1, 1 ),
322  $ ldw, w( 1, i ), 1, one, w( i+1, i ), 1 )
323  CALL dscal( n-i, tau( i ), w( i+1, i ), 1 )
324  alpha = -half*tau( i )*ddot( n-i, w( i+1, i ), 1,
325  $ a( i+1, i ), 1 )
326  CALL daxpy( n-i, alpha, a( i+1, i ), 1, w( i+1, i ), 1 )
327  END IF
328 *
329  20 CONTINUE
330  END IF
331 *
332  RETURN
333 *
334 * End of DLATRD
335 *
subroutine daxpy(N, DA, DX, INCX, DY, INCY)
DAXPY
Definition: daxpy.f:91
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:81
subroutine dsymv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DSYMV
Definition: dsymv.f:154
double precision function ddot(N, DX, INCX, DY, INCY)
DDOT
Definition: ddot.f:84
subroutine dgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGEMV
Definition: dgemv.f:158
subroutine dlarfg(N, ALPHA, X, INCX, TAU)
DLARFG generates an elementary reflector (Householder matrix).
Definition: dlarfg.f:108
Here is the call graph for this function:
Here is the caller graph for this function: