LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

## ◆ dlauum()

 subroutine dlauum ( character UPLO, integer N, double precision, dimension( lda, * ) A, integer LDA, integer INFO )

DLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).

Purpose:
DLAUUM computes the product U * U**T or L**T * L, where the triangular
factor U or L is stored in the upper or lower triangular part of
the array A.

If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
overwriting the factor U in A.
If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
overwriting the factor L in A.

This is the blocked form of the algorithm, calling Level 3 BLAS.
Parameters
 [in] UPLO UPLO is CHARACTER*1 Specifies whether the triangular factor stored in the array A is upper or lower triangular: = 'U': Upper triangular = 'L': Lower triangular [in] N N is INTEGER The order of the triangular factor U or L. N >= 0. [in,out] A A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the triangular factor U or L. On exit, if UPLO = 'U', the upper triangle of A is overwritten with the upper triangle of the product U * U**T; if UPLO = 'L', the lower triangle of A is overwritten with the lower triangle of the product L**T * L. [in] LDA LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N). [out] INFO INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value
Date
December 2016

Definition at line 104 of file dlauum.f.

104 *
105 * -- LAPACK auxiliary routine (version 3.7.0) --
106 * -- LAPACK is a software package provided by Univ. of Tennessee, --
107 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
108 * December 2016
109 *
110 * .. Scalar Arguments ..
111  CHARACTER uplo
112  INTEGER info, lda, n
113 * ..
114 * .. Array Arguments ..
115  DOUBLE PRECISION a( lda, * )
116 * ..
117 *
118 * =====================================================================
119 *
120 * .. Parameters ..
121  DOUBLE PRECISION one
122  parameter( one = 1.0d+0 )
123 * ..
124 * .. Local Scalars ..
125  LOGICAL upper
126  INTEGER i, ib, nb
127 * ..
128 * .. External Functions ..
129  LOGICAL lsame
130  INTEGER ilaenv
131  EXTERNAL lsame, ilaenv
132 * ..
133 * .. External Subroutines ..
134  EXTERNAL dgemm, dlauu2, dsyrk, dtrmm, xerbla
135 * ..
136 * .. Intrinsic Functions ..
137  INTRINSIC max, min
138 * ..
139 * .. Executable Statements ..
140 *
141 * Test the input parameters.
142 *
143  info = 0
144  upper = lsame( uplo, 'U' )
145  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
146  info = -1
147  ELSE IF( n.LT.0 ) THEN
148  info = -2
149  ELSE IF( lda.LT.max( 1, n ) ) THEN
150  info = -4
151  END IF
152  IF( info.NE.0 ) THEN
153  CALL xerbla( 'DLAUUM', -info )
154  RETURN
155  END IF
156 *
157 * Quick return if possible
158 *
159  IF( n.EQ.0 )
160  \$ RETURN
161 *
162 * Determine the block size for this environment.
163 *
164  nb = ilaenv( 1, 'DLAUUM', uplo, n, -1, -1, -1 )
165 *
166  IF( nb.LE.1 .OR. nb.GE.n ) THEN
167 *
168 * Use unblocked code
169 *
170  CALL dlauu2( uplo, n, a, lda, info )
171  ELSE
172 *
173 * Use blocked code
174 *
175  IF( upper ) THEN
176 *
177 * Compute the product U * U**T.
178 *
179  DO 10 i = 1, n, nb
180  ib = min( nb, n-i+1 )
181  CALL dtrmm( 'Right', 'Upper', 'Transpose', 'Non-unit',
182  \$ i-1, ib, one, a( i, i ), lda, a( 1, i ),
183  \$ lda )
184  CALL dlauu2( 'Upper', ib, a( i, i ), lda, info )
185  IF( i+ib.LE.n ) THEN
186  CALL dgemm( 'No transpose', 'Transpose', i-1, ib,
187  \$ n-i-ib+1, one, a( 1, i+ib ), lda,
188  \$ a( i, i+ib ), lda, one, a( 1, i ), lda )
189  CALL dsyrk( 'Upper', 'No transpose', ib, n-i-ib+1,
190  \$ one, a( i, i+ib ), lda, one, a( i, i ),
191  \$ lda )
192  END IF
193  10 CONTINUE
194  ELSE
195 *
196 * Compute the product L**T * L.
197 *
198  DO 20 i = 1, n, nb
199  ib = min( nb, n-i+1 )
200  CALL dtrmm( 'Left', 'Lower', 'Transpose', 'Non-unit', ib,
201  \$ i-1, one, a( i, i ), lda, a( i, 1 ), lda )
202  CALL dlauu2( 'Lower', ib, a( i, i ), lda, info )
203  IF( i+ib.LE.n ) THEN
204  CALL dgemm( 'Transpose', 'No transpose', ib, i-1,
205  \$ n-i-ib+1, one, a( i+ib, i ), lda,
206  \$ a( i+ib, 1 ), lda, one, a( i, 1 ), lda )
207  CALL dsyrk( 'Lower', 'Transpose', ib, n-i-ib+1, one,
208  \$ a( i+ib, i ), lda, one, a( i, i ), lda )
209  END IF
210  20 CONTINUE
211  END IF
212  END IF
213 *
214  RETURN
215 *
216 * End of DLAUUM
217 *
subroutine dlauu2(UPLO, N, A, LDA, INFO)
DLAUU2 computes the product UUH or LHL, where U and L are upper or lower triangular matrices (unblock...
Definition: dlauu2.f:104
subroutine dtrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRMM
Definition: dtrmm.f:179
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:189
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: tstiee.f:83
subroutine dsyrk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
DSYRK
Definition: dsyrk.f:171
Here is the call graph for this function:
Here is the caller graph for this function: