LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zunbdb2()

subroutine zunbdb2 ( integer  M,
integer  P,
integer  Q,
complex*16, dimension(ldx11,*)  X11,
integer  LDX11,
complex*16, dimension(ldx21,*)  X21,
integer  LDX21,
double precision, dimension(*)  THETA,
double precision, dimension(*)  PHI,
complex*16, dimension(*)  TAUP1,
complex*16, dimension(*)  TAUP2,
complex*16, dimension(*)  TAUQ1,
complex*16, dimension(*)  WORK,
integer  LWORK,
integer  INFO 
)

ZUNBDB2

Download ZUNBDB2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZUNBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
 matrix X with orthonomal columns:

                            [ B11 ]
      [ X11 ]   [ P1 |    ] [  0  ]
      [-----] = [---------] [-----] Q1**T .
      [ X21 ]   [    | P2 ] [ B21 ]
                            [  0  ]

 X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
 Q, or M-Q. Routines ZUNBDB1, ZUNBDB3, and ZUNBDB4 handle cases in
 which P is not the minimum dimension.

 The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
 and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
 Householder vectors.

 B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
 angles THETA, PHI.
Parameters
[in]M
          M is INTEGER
           The number of rows X11 plus the number of rows in X21.
[in]P
          P is INTEGER
           The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
[in]Q
          Q is INTEGER
           The number of columns in X11 and X21. 0 <= Q <= M.
[in,out]X11
          X11 is COMPLEX*16 array, dimension (LDX11,Q)
           On entry, the top block of the matrix X to be reduced. On
           exit, the columns of tril(X11) specify reflectors for P1 and
           the rows of triu(X11,1) specify reflectors for Q1.
[in]LDX11
          LDX11 is INTEGER
           The leading dimension of X11. LDX11 >= P.
[in,out]X21
          X21 is COMPLEX*16 array, dimension (LDX21,Q)
           On entry, the bottom block of the matrix X to be reduced. On
           exit, the columns of tril(X21) specify reflectors for P2.
[in]LDX21
          LDX21 is INTEGER
           The leading dimension of X21. LDX21 >= M-P.
[out]THETA
          THETA is DOUBLE PRECISION array, dimension (Q)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]PHI
          PHI is DOUBLE PRECISION array, dimension (Q-1)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]TAUP1
          TAUP1 is COMPLEX*16 array, dimension (P)
           The scalar factors of the elementary reflectors that define
           P1.
[out]TAUP2
          TAUP2 is COMPLEX*16 array, dimension (M-P)
           The scalar factors of the elementary reflectors that define
           P2.
[out]TAUQ1
          TAUQ1 is COMPLEX*16 array, dimension (Q)
           The scalar factors of the elementary reflectors that define
           Q1.
[out]WORK
          WORK is COMPLEX*16 array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK. LWORK >= M-Q.

           If LWORK = -1, then a workspace query is assumed; the routine
           only calculates the optimal size of the WORK array, returns
           this value as the first entry of the WORK array, and no error
           message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
           = 0:  successful exit.
           < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
July 2012
Further Details:
  The upper-bidiagonal blocks B11, B21 are represented implicitly by
  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
  in each bidiagonal band is a product of a sine or cosine of a THETA
  with a sine or cosine of a PHI. See [1] or ZUNCSD for details.

  P1, P2, and Q1 are represented as products of elementary reflectors.
  See ZUNCSD2BY1 for details on generating P1, P2, and Q1 using ZUNGQR
  and ZUNGLQ.
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 203 of file zunbdb2.f.

203 *
204 * -- LAPACK computational routine (version 3.8.0) --
205 * -- LAPACK is a software package provided by Univ. of Tennessee, --
206 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
207 * July 2012
208 *
209 * .. Scalar Arguments ..
210  INTEGER info, lwork, m, p, q, ldx11, ldx21
211 * ..
212 * .. Array Arguments ..
213  DOUBLE PRECISION phi(*), theta(*)
214  COMPLEX*16 taup1(*), taup2(*), tauq1(*), work(*),
215  $ x11(ldx11,*), x21(ldx21,*)
216 * ..
217 *
218 * ====================================================================
219 *
220 * .. Parameters ..
221  COMPLEX*16 negone, one
222  parameter( negone = (-1.0d0,0.0d0),
223  $ one = (1.0d0,0.0d0) )
224 * ..
225 * .. Local Scalars ..
226  DOUBLE PRECISION c, s
227  INTEGER childinfo, i, ilarf, iorbdb5, llarf, lorbdb5,
228  $ lworkmin, lworkopt
229  LOGICAL lquery
230 * ..
231 * .. External Subroutines ..
232  EXTERNAL zlarf, zlarfgp, zunbdb5, zdrot, zscal, zlacgv,
233  $ xerbla
234 * ..
235 * .. External Functions ..
236  DOUBLE PRECISION dznrm2
237  EXTERNAL dznrm2
238 * ..
239 * .. Intrinsic Function ..
240  INTRINSIC atan2, cos, max, sin, sqrt
241 * ..
242 * .. Executable Statements ..
243 *
244 * Test input arguments
245 *
246  info = 0
247  lquery = lwork .EQ. -1
248 *
249  IF( m .LT. 0 ) THEN
250  info = -1
251  ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
252  info = -2
253  ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
254  info = -3
255  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
256  info = -5
257  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
258  info = -7
259  END IF
260 *
261 * Compute workspace
262 *
263  IF( info .EQ. 0 ) THEN
264  ilarf = 2
265  llarf = max( p-1, m-p, q-1 )
266  iorbdb5 = 2
267  lorbdb5 = q-1
268  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
269  lworkmin = lworkopt
270  work(1) = lworkopt
271  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
272  info = -14
273  END IF
274  END IF
275  IF( info .NE. 0 ) THEN
276  CALL xerbla( 'ZUNBDB2', -info )
277  RETURN
278  ELSE IF( lquery ) THEN
279  RETURN
280  END IF
281 *
282 * Reduce rows 1, ..., P of X11 and X21
283 *
284  DO i = 1, p
285 *
286  IF( i .GT. 1 ) THEN
287  CALL zdrot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c,
288  $ s )
289  END IF
290  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
291  CALL zlarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
292  c = dble( x11(i,i) )
293  x11(i,i) = one
294  CALL zlarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
295  $ x11(i+1,i), ldx11, work(ilarf) )
296  CALL zlarf( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11, tauq1(i),
297  $ x21(i,i), ldx21, work(ilarf) )
298  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
299  s = sqrt( dznrm2( p-i, x11(i+1,i), 1 )**2
300  $ + dznrm2( m-p-i+1, x21(i,i), 1 )**2 )
301  theta(i) = atan2( s, c )
302 *
303  CALL zunbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
304  $ x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
305  $ work(iorbdb5), lorbdb5, childinfo )
306  CALL zscal( p-i, negone, x11(i+1,i), 1 )
307  CALL zlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
308  IF( i .LT. p ) THEN
309  CALL zlarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
310  phi(i) = atan2( dble( x11(i+1,i) ), dble( x21(i,i) ) )
311  c = cos( phi(i) )
312  s = sin( phi(i) )
313  x11(i+1,i) = one
314  CALL zlarf( 'L', p-i, q-i, x11(i+1,i), 1, dconjg(taup1(i)),
315  $ x11(i+1,i+1), ldx11, work(ilarf) )
316  END IF
317  x21(i,i) = one
318  CALL zlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, dconjg(taup2(i)),
319  $ x21(i,i+1), ldx21, work(ilarf) )
320 *
321  END DO
322 *
323 * Reduce the bottom-right portion of X21 to the identity matrix
324 *
325  DO i = p + 1, q
326  CALL zlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
327  x21(i,i) = one
328  CALL zlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, dconjg(taup2(i)),
329  $ x21(i,i+1), ldx21, work(ilarf) )
330  END DO
331 *
332  RETURN
333 *
334 * End of ZUNBDB2
335 *
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine zdrot(N, CX, INCX, CY, INCY, C, S)
ZDROT
Definition: zdrot.f:100
double precision function dznrm2(N, X, INCX)
DZNRM2
Definition: dznrm2.f:77
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
subroutine zunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
ZUNBDB5
Definition: zunbdb5.f:158
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:106
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:80
Here is the call graph for this function:
Here is the caller graph for this function: