LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zungl2()

subroutine zungl2 ( integer  M,
integer  N,
integer  K,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  TAU,
complex*16, dimension( * )  WORK,
integer  INFO 
)

ZUNGL2 generates all or part of the unitary matrix Q from an LQ factorization determined by cgelqf (unblocked algorithm).

Download ZUNGL2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZUNGL2 generates an m-by-n complex matrix Q with orthonormal rows,
 which is defined as the first m rows of a product of k elementary
 reflectors of order n

       Q  =  H(k)**H . . . H(2)**H H(1)**H

 as returned by ZGELQF.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q. M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q. N >= M.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. M >= K >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the i-th row must contain the vector which defines
          the elementary reflector H(i), for i = 1,2,...,k, as returned
          by ZGELQF in the first k rows of its array argument A.
          On exit, the m by n matrix Q.
[in]LDA
          LDA is INTEGER
          The first dimension of the array A. LDA >= max(1,M).
[in]TAU
          TAU is COMPLEX*16 array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i), as returned by ZGELQF.
[out]WORK
          WORK is COMPLEX*16 array, dimension (M)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument has an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 115 of file zungl2.f.

115 *
116 * -- LAPACK computational routine (version 3.7.0) --
117 * -- LAPACK is a software package provided by Univ. of Tennessee, --
118 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119 * December 2016
120 *
121 * .. Scalar Arguments ..
122  INTEGER info, k, lda, m, n
123 * ..
124 * .. Array Arguments ..
125  COMPLEX*16 a( lda, * ), tau( * ), work( * )
126 * ..
127 *
128 * =====================================================================
129 *
130 * .. Parameters ..
131  COMPLEX*16 one, zero
132  parameter( one = ( 1.0d+0, 0.0d+0 ),
133  $ zero = ( 0.0d+0, 0.0d+0 ) )
134 * ..
135 * .. Local Scalars ..
136  INTEGER i, j, l
137 * ..
138 * .. External Subroutines ..
139  EXTERNAL xerbla, zlacgv, zlarf, zscal
140 * ..
141 * .. Intrinsic Functions ..
142  INTRINSIC dconjg, max
143 * ..
144 * .. Executable Statements ..
145 *
146 * Test the input arguments
147 *
148  info = 0
149  IF( m.LT.0 ) THEN
150  info = -1
151  ELSE IF( n.LT.m ) THEN
152  info = -2
153  ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
154  info = -3
155  ELSE IF( lda.LT.max( 1, m ) ) THEN
156  info = -5
157  END IF
158  IF( info.NE.0 ) THEN
159  CALL xerbla( 'ZUNGL2', -info )
160  RETURN
161  END IF
162 *
163 * Quick return if possible
164 *
165  IF( m.LE.0 )
166  $ RETURN
167 *
168  IF( k.LT.m ) THEN
169 *
170 * Initialise rows k+1:m to rows of the unit matrix
171 *
172  DO 20 j = 1, n
173  DO 10 l = k + 1, m
174  a( l, j ) = zero
175  10 CONTINUE
176  IF( j.GT.k .AND. j.LE.m )
177  $ a( j, j ) = one
178  20 CONTINUE
179  END IF
180 *
181  DO 40 i = k, 1, -1
182 *
183 * Apply H(i)**H to A(i:m,i:n) from the right
184 *
185  IF( i.LT.n ) THEN
186  CALL zlacgv( n-i, a( i, i+1 ), lda )
187  IF( i.LT.m ) THEN
188  a( i, i ) = one
189  CALL zlarf( 'Right', m-i, n-i+1, a( i, i ), lda,
190  $ dconjg( tau( i ) ), a( i+1, i ), lda, work )
191  END IF
192  CALL zscal( n-i, -tau( i ), a( i, i+1 ), lda )
193  CALL zlacgv( n-i, a( i, i+1 ), lda )
194  END IF
195  a( i, i ) = one - dconjg( tau( i ) )
196 *
197 * Set A(i,1:i-1) to zero
198 *
199  DO 30 l = 1, i - 1
200  a( i, l ) = zero
201  30 CONTINUE
202  40 CONTINUE
203  RETURN
204 *
205 * End of ZUNGL2
206 *
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:80
Here is the call graph for this function:
Here is the caller graph for this function: