LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

◆ zunbdb4()

 subroutine zunbdb4 ( integer M, integer P, integer Q, complex*16, dimension(ldx11,*) X11, integer LDX11, complex*16, dimension(ldx21,*) X21, integer LDX21, double precision, dimension(*) THETA, double precision, dimension(*) PHI, complex*16, dimension(*) TAUP1, complex*16, dimension(*) TAUP2, complex*16, dimension(*) TAUQ1, complex*16, dimension(*) PHANTOM, complex*16, dimension(*) WORK, integer LWORK, integer INFO )

ZUNBDB4

Purpose:
``` ZUNBDB4 simultaneously bidiagonalizes the blocks of a tall and skinny
matrix X with orthonomal columns:

[ B11 ]
[ X11 ]   [ P1 |    ] [  0  ]
[-----] = [---------] [-----] Q1**T .
[ X21 ]   [    | P2 ] [ B21 ]
[  0  ]

X11 is P-by-Q, and X21 is (M-P)-by-Q. M-Q must be no larger than P,
M-P, or Q. Routines ZUNBDB1, ZUNBDB2, and ZUNBDB3 handle cases in
which M-Q is not the minimum dimension.

The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
Householder vectors.

B11 and B12 are (M-Q)-by-(M-Q) bidiagonal matrices represented
implicitly by angles THETA, PHI.```
Parameters
 [in] M ``` M is INTEGER The number of rows X11 plus the number of rows in X21.``` [in] P ``` P is INTEGER The number of rows in X11. 0 <= P <= M.``` [in] Q ``` Q is INTEGER The number of columns in X11 and X21. 0 <= Q <= M and M-Q <= min(P,M-P,Q).``` [in,out] X11 ``` X11 is COMPLEX*16 array, dimension (LDX11,Q) On entry, the top block of the matrix X to be reduced. On exit, the columns of tril(X11) specify reflectors for P1 and the rows of triu(X11,1) specify reflectors for Q1.``` [in] LDX11 ``` LDX11 is INTEGER The leading dimension of X11. LDX11 >= P.``` [in,out] X21 ``` X21 is COMPLEX*16 array, dimension (LDX21,Q) On entry, the bottom block of the matrix X to be reduced. On exit, the columns of tril(X21) specify reflectors for P2.``` [in] LDX21 ``` LDX21 is INTEGER The leading dimension of X21. LDX21 >= M-P.``` [out] THETA ``` THETA is DOUBLE PRECISION array, dimension (Q) The entries of the bidiagonal blocks B11, B21 are defined by THETA and PHI. See Further Details.``` [out] PHI ``` PHI is DOUBLE PRECISION array, dimension (Q-1) The entries of the bidiagonal blocks B11, B21 are defined by THETA and PHI. See Further Details.``` [out] TAUP1 ``` TAUP1 is COMPLEX*16 array, dimension (P) The scalar factors of the elementary reflectors that define P1.``` [out] TAUP2 ``` TAUP2 is COMPLEX*16 array, dimension (M-P) The scalar factors of the elementary reflectors that define P2.``` [out] TAUQ1 ``` TAUQ1 is COMPLEX*16 array, dimension (Q) The scalar factors of the elementary reflectors that define Q1.``` [out] PHANTOM ``` PHANTOM is COMPLEX*16 array, dimension (M) The routine computes an M-by-1 column vector Y that is orthogonal to the columns of [ X11; X21 ]. PHANTOM(1:P) and PHANTOM(P+1:M) contain Householder vectors for Y(1:P) and Y(P+1:M), respectively.``` [out] WORK ` WORK is COMPLEX*16 array, dimension (LWORK)` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. LWORK >= M-Q. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value.```
Date
July 2012
Further Details:
```  The upper-bidiagonal blocks B11, B21 are represented implicitly by
angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
in each bidiagonal band is a product of a sine or cosine of a THETA
with a sine or cosine of a PHI. See [1] or ZUNCSD for details.

P1, P2, and Q1 are represented as products of elementary reflectors.
See ZUNCSD2BY1 for details on generating P1, P2, and Q1 using ZUNGQR
and ZUNGLQ.```
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 215 of file zunbdb4.f.

215 *
216 * -- LAPACK computational routine (version 3.8.0) --
217 * -- LAPACK is a software package provided by Univ. of Tennessee, --
218 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
219 * July 2012
220 *
221 * .. Scalar Arguments ..
222  INTEGER info, lwork, m, p, q, ldx11, ldx21
223 * ..
224 * .. Array Arguments ..
225  DOUBLE PRECISION phi(*), theta(*)
226  COMPLEX*16 phantom(*), taup1(*), taup2(*), tauq1(*),
227  \$ work(*), x11(ldx11,*), x21(ldx21,*)
228 * ..
229 *
230 * ====================================================================
231 *
232 * .. Parameters ..
233  COMPLEX*16 negone, one, zero
234  parameter( negone = (-1.0d0,0.0d0), one = (1.0d0,0.0d0),
235  \$ zero = (0.0d0,0.0d0) )
236 * ..
237 * .. Local Scalars ..
238  DOUBLE PRECISION c, s
239  INTEGER childinfo, i, ilarf, iorbdb5, j, llarf,
240  \$ lorbdb5, lworkmin, lworkopt
241  LOGICAL lquery
242 * ..
243 * .. External Subroutines ..
244  EXTERNAL zlarf, zlarfgp, zunbdb5, zdrot, zscal, zlacgv,
245  \$ xerbla
246 * ..
247 * .. External Functions ..
248  DOUBLE PRECISION dznrm2
249  EXTERNAL dznrm2
250 * ..
251 * .. Intrinsic Function ..
252  INTRINSIC atan2, cos, max, sin, sqrt
253 * ..
254 * .. Executable Statements ..
255 *
256 * Test input arguments
257 *
258  info = 0
259  lquery = lwork .EQ. -1
260 *
261  IF( m .LT. 0 ) THEN
262  info = -1
263  ELSE IF( p .LT. m-q .OR. m-p .LT. m-q ) THEN
264  info = -2
265  ELSE IF( q .LT. m-q .OR. q .GT. m ) THEN
266  info = -3
267  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
268  info = -5
269  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
270  info = -7
271  END IF
272 *
273 * Compute workspace
274 *
275  IF( info .EQ. 0 ) THEN
276  ilarf = 2
277  llarf = max( q-1, p-1, m-p-1 )
278  iorbdb5 = 2
279  lorbdb5 = q
280  lworkopt = ilarf + llarf - 1
281  lworkopt = max( lworkopt, iorbdb5 + lorbdb5 - 1 )
282  lworkmin = lworkopt
283  work(1) = lworkopt
284  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
285  info = -14
286  END IF
287  END IF
288  IF( info .NE. 0 ) THEN
289  CALL xerbla( 'ZUNBDB4', -info )
290  RETURN
291  ELSE IF( lquery ) THEN
292  RETURN
293  END IF
294 *
295 * Reduce columns 1, ..., M-Q of X11 and X21
296 *
297  DO i = 1, m-q
298 *
299  IF( i .EQ. 1 ) THEN
300  DO j = 1, m
301  phantom(j) = zero
302  END DO
303  CALL zunbdb5( p, m-p, q, phantom(1), 1, phantom(p+1), 1,
304  \$ x11, ldx11, x21, ldx21, work(iorbdb5),
305  \$ lorbdb5, childinfo )
306  CALL zscal( p, negone, phantom(1), 1 )
307  CALL zlarfgp( p, phantom(1), phantom(2), 1, taup1(1) )
308  CALL zlarfgp( m-p, phantom(p+1), phantom(p+2), 1, taup2(1) )
309  theta(i) = atan2( dble( phantom(1) ), dble( phantom(p+1) ) )
310  c = cos( theta(i) )
311  s = sin( theta(i) )
312  phantom(1) = one
313  phantom(p+1) = one
314  CALL zlarf( 'L', p, q, phantom(1), 1, dconjg(taup1(1)), x11,
315  \$ ldx11, work(ilarf) )
316  CALL zlarf( 'L', m-p, q, phantom(p+1), 1, dconjg(taup2(1)),
317  \$ x21, ldx21, work(ilarf) )
318  ELSE
319  CALL zunbdb5( p-i+1, m-p-i+1, q-i+1, x11(i,i-1), 1,
320  \$ x21(i,i-1), 1, x11(i,i), ldx11, x21(i,i),
321  \$ ldx21, work(iorbdb5), lorbdb5, childinfo )
322  CALL zscal( p-i+1, negone, x11(i,i-1), 1 )
323  CALL zlarfgp( p-i+1, x11(i,i-1), x11(i+1,i-1), 1, taup1(i) )
324  CALL zlarfgp( m-p-i+1, x21(i,i-1), x21(i+1,i-1), 1,
325  \$ taup2(i) )
326  theta(i) = atan2( dble( x11(i,i-1) ), dble( x21(i,i-1) ) )
327  c = cos( theta(i) )
328  s = sin( theta(i) )
329  x11(i,i-1) = one
330  x21(i,i-1) = one
331  CALL zlarf( 'L', p-i+1, q-i+1, x11(i,i-1), 1,
332  \$ dconjg(taup1(i)), x11(i,i), ldx11, work(ilarf) )
333  CALL zlarf( 'L', m-p-i+1, q-i+1, x21(i,i-1), 1,
334  \$ dconjg(taup2(i)), x21(i,i), ldx21, work(ilarf) )
335  END IF
336 *
337  CALL zdrot( q-i+1, x11(i,i), ldx11, x21(i,i), ldx21, s, -c )
338  CALL zlacgv( q-i+1, x21(i,i), ldx21 )
339  CALL zlarfgp( q-i+1, x21(i,i), x21(i,i+1), ldx21, tauq1(i) )
340  c = dble( x21(i,i) )
341  x21(i,i) = one
342  CALL zlarf( 'R', p-i, q-i+1, x21(i,i), ldx21, tauq1(i),
343  \$ x11(i+1,i), ldx11, work(ilarf) )
344  CALL zlarf( 'R', m-p-i, q-i+1, x21(i,i), ldx21, tauq1(i),
345  \$ x21(i+1,i), ldx21, work(ilarf) )
346  CALL zlacgv( q-i+1, x21(i,i), ldx21 )
347  IF( i .LT. m-q ) THEN
348  s = sqrt( dznrm2( p-i, x11(i+1,i), 1 )**2
349  \$ + dznrm2( m-p-i, x21(i+1,i), 1 )**2 )
350  phi(i) = atan2( s, c )
351  END IF
352 *
353  END DO
354 *
355 * Reduce the bottom-right portion of X11 to [ I 0 ]
356 *
357  DO i = m - q + 1, p
358  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
359  CALL zlarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
360  x11(i,i) = one
361  CALL zlarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
362  \$ x11(i+1,i), ldx11, work(ilarf) )
363  CALL zlarf( 'R', q-p, q-i+1, x11(i,i), ldx11, tauq1(i),
364  \$ x21(m-q+1,i), ldx21, work(ilarf) )
365  CALL zlacgv( q-i+1, x11(i,i), ldx11 )
366  END DO
367 *
368 * Reduce the bottom-right portion of X21 to [ 0 I ]
369 *
370  DO i = p + 1, q
371  CALL zlacgv( q-i+1, x21(m-q+i-p,i), ldx21 )
372  CALL zlarfgp( q-i+1, x21(m-q+i-p,i), x21(m-q+i-p,i+1), ldx21,
373  \$ tauq1(i) )
374  x21(m-q+i-p,i) = one
375  CALL zlarf( 'R', q-i, q-i+1, x21(m-q+i-p,i), ldx21, tauq1(i),
376  \$ x21(m-q+i-p+1,i), ldx21, work(ilarf) )
377  CALL zlacgv( q-i+1, x21(m-q+i-p,i), ldx21 )
378  END DO
379 *
380  RETURN
381 *
382 * End of ZUNBDB4
383 *
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine zdrot(N, CX, INCX, CY, INCY, C, S)
ZDROT
Definition: zdrot.f:100
double precision function dznrm2(N, X, INCX)
DZNRM2
Definition: dznrm2.f:77
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
subroutine zunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
ZUNBDB5
Definition: zunbdb5.f:158
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:106
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:80
Here is the call graph for this function:
Here is the caller graph for this function: