LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zlarft()

subroutine zlarft ( character  DIRECT,
character  STOREV,
integer  N,
integer  K,
complex*16, dimension( ldv, * )  V,
integer  LDV,
complex*16, dimension( * )  TAU,
complex*16, dimension( ldt, * )  T,
integer  LDT 
)

ZLARFT forms the triangular factor T of a block reflector H = I - vtvH

Download ZLARFT + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLARFT forms the triangular factor T of a complex block reflector H
 of order n, which is defined as a product of k elementary reflectors.

 If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;

 If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.

 If STOREV = 'C', the vector which defines the elementary reflector
 H(i) is stored in the i-th column of the array V, and

    H  =  I - V * T * V**H

 If STOREV = 'R', the vector which defines the elementary reflector
 H(i) is stored in the i-th row of the array V, and

    H  =  I - V**H * T * V
Parameters
[in]DIRECT
          DIRECT is CHARACTER*1
          Specifies the order in which the elementary reflectors are
          multiplied to form the block reflector:
          = 'F': H = H(1) H(2) . . . H(k) (Forward)
          = 'B': H = H(k) . . . H(2) H(1) (Backward)
[in]STOREV
          STOREV is CHARACTER*1
          Specifies how the vectors which define the elementary
          reflectors are stored (see also Further Details):
          = 'C': columnwise
          = 'R': rowwise
[in]N
          N is INTEGER
          The order of the block reflector H. N >= 0.
[in]K
          K is INTEGER
          The order of the triangular factor T (= the number of
          elementary reflectors). K >= 1.
[in]V
          V is COMPLEX*16 array, dimension
                               (LDV,K) if STOREV = 'C'
                               (LDV,N) if STOREV = 'R'
          The matrix V. See further details.
[in]LDV
          LDV is INTEGER
          The leading dimension of the array V.
          If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
[in]TAU
          TAU is COMPLEX*16 array, dimension (K)
          TAU(i) must contain the scalar factor of the elementary
          reflector H(i).
[out]T
          T is COMPLEX*16 array, dimension (LDT,K)
          The k by k triangular factor T of the block reflector.
          If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
          lower triangular. The rest of the array is not used.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T. LDT >= K.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016
Further Details:
  The shape of the matrix V and the storage of the vectors which define
  the H(i) is best illustrated by the following example with n = 5 and
  k = 3. The elements equal to 1 are not stored.

  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':

               V = (  1       )                 V = (  1 v1 v1 v1 v1 )
                   ( v1  1    )                     (     1 v2 v2 v2 )
                   ( v1 v2  1 )                     (        1 v3 v3 )
                   ( v1 v2 v3 )
                   ( v1 v2 v3 )

  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':

               V = ( v1 v2 v3 )                 V = ( v1 v1  1       )
                   ( v1 v2 v3 )                     ( v2 v2 v2  1    )
                   (  1 v2 v3 )                     ( v3 v3 v3 v3  1 )
                   (     1 v3 )
                   (        1 )

Definition at line 165 of file zlarft.f.

165 *
166 * -- LAPACK auxiliary routine (version 3.7.0) --
167 * -- LAPACK is a software package provided by Univ. of Tennessee, --
168 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
169 * June 2016
170 *
171 * .. Scalar Arguments ..
172  CHARACTER direct, storev
173  INTEGER k, ldt, ldv, n
174 * ..
175 * .. Array Arguments ..
176  COMPLEX*16 t( ldt, * ), tau( * ), v( ldv, * )
177 * ..
178 *
179 * =====================================================================
180 *
181 * .. Parameters ..
182  COMPLEX*16 one, zero
183  parameter( one = ( 1.0d+0, 0.0d+0 ),
184  $ zero = ( 0.0d+0, 0.0d+0 ) )
185 * ..
186 * .. Local Scalars ..
187  INTEGER i, j, prevlastv, lastv
188 * ..
189 * .. External Subroutines ..
190  EXTERNAL zgemv, ztrmv, zgemm
191 * ..
192 * .. External Functions ..
193  LOGICAL lsame
194  EXTERNAL lsame
195 * ..
196 * .. Executable Statements ..
197 *
198 * Quick return if possible
199 *
200  IF( n.EQ.0 )
201  $ RETURN
202 *
203  IF( lsame( direct, 'F' ) ) THEN
204  prevlastv = n
205  DO i = 1, k
206  prevlastv = max( prevlastv, i )
207  IF( tau( i ).EQ.zero ) THEN
208 *
209 * H(i) = I
210 *
211  DO j = 1, i
212  t( j, i ) = zero
213  END DO
214  ELSE
215 *
216 * general case
217 *
218  IF( lsame( storev, 'C' ) ) THEN
219 * Skip any trailing zeros.
220  DO lastv = n, i+1, -1
221  IF( v( lastv, i ).NE.zero ) EXIT
222  END DO
223  DO j = 1, i-1
224  t( j, i ) = -tau( i ) * conjg( v( i , j ) )
225  END DO
226  j = min( lastv, prevlastv )
227 *
228 * T(1:i-1,i) := - tau(i) * V(i:j,1:i-1)**H * V(i:j,i)
229 *
230  CALL zgemv( 'Conjugate transpose', j-i, i-1,
231  $ -tau( i ), v( i+1, 1 ), ldv,
232  $ v( i+1, i ), 1, one, t( 1, i ), 1 )
233  ELSE
234 * Skip any trailing zeros.
235  DO lastv = n, i+1, -1
236  IF( v( i, lastv ).NE.zero ) EXIT
237  END DO
238  DO j = 1, i-1
239  t( j, i ) = -tau( i ) * v( j , i )
240  END DO
241  j = min( lastv, prevlastv )
242 *
243 * T(1:i-1,i) := - tau(i) * V(1:i-1,i:j) * V(i,i:j)**H
244 *
245  CALL zgemm( 'N', 'C', i-1, 1, j-i, -tau( i ),
246  $ v( 1, i+1 ), ldv, v( i, i+1 ), ldv,
247  $ one, t( 1, i ), ldt )
248  END IF
249 *
250 * T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
251 *
252  CALL ztrmv( 'Upper', 'No transpose', 'Non-unit', i-1, t,
253  $ ldt, t( 1, i ), 1 )
254  t( i, i ) = tau( i )
255  IF( i.GT.1 ) THEN
256  prevlastv = max( prevlastv, lastv )
257  ELSE
258  prevlastv = lastv
259  END IF
260  END IF
261  END DO
262  ELSE
263  prevlastv = 1
264  DO i = k, 1, -1
265  IF( tau( i ).EQ.zero ) THEN
266 *
267 * H(i) = I
268 *
269  DO j = i, k
270  t( j, i ) = zero
271  END DO
272  ELSE
273 *
274 * general case
275 *
276  IF( i.LT.k ) THEN
277  IF( lsame( storev, 'C' ) ) THEN
278 * Skip any leading zeros.
279  DO lastv = 1, i-1
280  IF( v( lastv, i ).NE.zero ) EXIT
281  END DO
282  DO j = i+1, k
283  t( j, i ) = -tau( i ) * conjg( v( n-k+i , j ) )
284  END DO
285  j = max( lastv, prevlastv )
286 *
287 * T(i+1:k,i) = -tau(i) * V(j:n-k+i,i+1:k)**H * V(j:n-k+i,i)
288 *
289  CALL zgemv( 'Conjugate transpose', n-k+i-j, k-i,
290  $ -tau( i ), v( j, i+1 ), ldv, v( j, i ),
291  $ 1, one, t( i+1, i ), 1 )
292  ELSE
293 * Skip any leading zeros.
294  DO lastv = 1, i-1
295  IF( v( i, lastv ).NE.zero ) EXIT
296  END DO
297  DO j = i+1, k
298  t( j, i ) = -tau( i ) * v( j, n-k+i )
299  END DO
300  j = max( lastv, prevlastv )
301 *
302 * T(i+1:k,i) = -tau(i) * V(i+1:k,j:n-k+i) * V(i,j:n-k+i)**H
303 *
304  CALL zgemm( 'N', 'C', k-i, 1, n-k+i-j, -tau( i ),
305  $ v( i+1, j ), ldv, v( i, j ), ldv,
306  $ one, t( i+1, i ), ldt )
307  END IF
308 *
309 * T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
310 *
311  CALL ztrmv( 'Lower', 'No transpose', 'Non-unit', k-i,
312  $ t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
313  IF( i.GT.1 ) THEN
314  prevlastv = min( prevlastv, lastv )
315  ELSE
316  prevlastv = lastv
317  END IF
318  END IF
319  t( i, i ) = tau( i )
320  END IF
321  END DO
322  END IF
323  RETURN
324 *
325 * End of ZLARFT
326 *
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:160
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:189
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine ztrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRMV
Definition: ztrmv.f:149
Here is the call graph for this function:
Here is the caller graph for this function: