LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zlansp()

double precision function zlansp ( character  NORM,
character  UPLO,
integer  N,
complex*16, dimension( * )  AP,
double precision, dimension( * )  WORK 
)

ZLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric matrix supplied in packed form.

Download ZLANSP + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANSP  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex symmetric matrix A,  supplied in packed form.
Returns
ZLANSP
    ZLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANSP as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          symmetric matrix A is supplied.
          = 'U':  Upper triangular part of A is supplied
          = 'L':  Lower triangular part of A is supplied
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, ZLANSP is
          set to zero.
[in]AP
          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
          The upper or lower triangle of the symmetric matrix A, packed
          columnwise in a linear array.  The j-th column of A is stored
          in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 117 of file zlansp.f.

117 *
118 * -- LAPACK auxiliary routine (version 3.7.0) --
119 * -- LAPACK is a software package provided by Univ. of Tennessee, --
120 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121 * December 2016
122 *
123 * .. Scalar Arguments ..
124  CHARACTER norm, uplo
125  INTEGER n
126 * ..
127 * .. Array Arguments ..
128  DOUBLE PRECISION work( * )
129  COMPLEX*16 ap( * )
130 * ..
131 *
132 * =====================================================================
133 *
134 * .. Parameters ..
135  DOUBLE PRECISION one, zero
136  parameter( one = 1.0d+0, zero = 0.0d+0 )
137 * ..
138 * .. Local Scalars ..
139  INTEGER i, j, k
140  DOUBLE PRECISION absa, scale, sum, value
141 * ..
142 * .. External Functions ..
143  LOGICAL lsame, disnan
144  EXTERNAL lsame, disnan
145 * ..
146 * .. External Subroutines ..
147  EXTERNAL zlassq
148 * ..
149 * .. Intrinsic Functions ..
150  INTRINSIC abs, dble, dimag, sqrt
151 * ..
152 * .. Executable Statements ..
153 *
154  IF( n.EQ.0 ) THEN
155  VALUE = zero
156  ELSE IF( lsame( norm, 'M' ) ) THEN
157 *
158 * Find max(abs(A(i,j))).
159 *
160  VALUE = zero
161  IF( lsame( uplo, 'U' ) ) THEN
162  k = 1
163  DO 20 j = 1, n
164  DO 10 i = k, k + j - 1
165  sum = abs( ap( i ) )
166  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
167  10 CONTINUE
168  k = k + j
169  20 CONTINUE
170  ELSE
171  k = 1
172  DO 40 j = 1, n
173  DO 30 i = k, k + n - j
174  sum = abs( ap( i ) )
175  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
176  30 CONTINUE
177  k = k + n - j + 1
178  40 CONTINUE
179  END IF
180  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
181  $ ( norm.EQ.'1' ) ) THEN
182 *
183 * Find normI(A) ( = norm1(A), since A is symmetric).
184 *
185  VALUE = zero
186  k = 1
187  IF( lsame( uplo, 'U' ) ) THEN
188  DO 60 j = 1, n
189  sum = zero
190  DO 50 i = 1, j - 1
191  absa = abs( ap( k ) )
192  sum = sum + absa
193  work( i ) = work( i ) + absa
194  k = k + 1
195  50 CONTINUE
196  work( j ) = sum + abs( ap( k ) )
197  k = k + 1
198  60 CONTINUE
199  DO 70 i = 1, n
200  sum = work( i )
201  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
202  70 CONTINUE
203  ELSE
204  DO 80 i = 1, n
205  work( i ) = zero
206  80 CONTINUE
207  DO 100 j = 1, n
208  sum = work( j ) + abs( ap( k ) )
209  k = k + 1
210  DO 90 i = j + 1, n
211  absa = abs( ap( k ) )
212  sum = sum + absa
213  work( i ) = work( i ) + absa
214  k = k + 1
215  90 CONTINUE
216  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
217  100 CONTINUE
218  END IF
219  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
220 *
221 * Find normF(A).
222 *
223  scale = zero
224  sum = one
225  k = 2
226  IF( lsame( uplo, 'U' ) ) THEN
227  DO 110 j = 2, n
228  CALL zlassq( j-1, ap( k ), 1, scale, sum )
229  k = k + j
230  110 CONTINUE
231  ELSE
232  DO 120 j = 1, n - 1
233  CALL zlassq( n-j, ap( k ), 1, scale, sum )
234  k = k + n - j + 1
235  120 CONTINUE
236  END IF
237  sum = 2*sum
238  k = 1
239  DO 130 i = 1, n
240  IF( dble( ap( k ) ).NE.zero ) THEN
241  absa = abs( dble( ap( k ) ) )
242  IF( scale.LT.absa ) THEN
243  sum = one + sum*( scale / absa )**2
244  scale = absa
245  ELSE
246  sum = sum + ( absa / scale )**2
247  END IF
248  END IF
249  IF( dimag( ap( k ) ).NE.zero ) THEN
250  absa = abs( dimag( ap( k ) ) )
251  IF( scale.LT.absa ) THEN
252  sum = one + sum*( scale / absa )**2
253  scale = absa
254  ELSE
255  sum = sum + ( absa / scale )**2
256  END IF
257  END IF
258  IF( lsame( uplo, 'U' ) ) THEN
259  k = k + i + 1
260  ELSE
261  k = k + n - i + 1
262  END IF
263  130 CONTINUE
264  VALUE = scale*sqrt( sum )
265  END IF
266 *
267  zlansp = VALUE
268  RETURN
269 *
270 * End of ZLANSP
271 *
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
double precision function zlansp(NORM, UPLO, N, AP, WORK)
ZLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric matrix supplied in packed form.
Definition: zlansp.f:117
Here is the call graph for this function: