sdrves.f

Go to the documentation of this file.

*> \brief \b SDRVES
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SDRVES( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          NOUNIT, A, LDA, H, HT, WR, WI, WRT, WIT, VS,
*                          LDVS, RESULT, WORK, NWORK, IWORK, BWORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDVS, NOUNIT, NSIZES, NTYPES, NWORK
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            BWORK( * ), DOTYPE( * )
*       INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
*       REAL               A( LDA, * ), H( LDA, * ), HT( LDA, * ),
*      $                   RESULT( 13 ), VS( LDVS, * ), WI( * ), WIT( * ),
*      $                   WORK( * ), WR( * ), WRT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    SDRVES checks the nonsymmetric eigenvalue (Schur form) problem
*>    driver SGEES.
*>
*>    When SDRVES is called, a number of matrix "sizes" ("n's") and a
*>    number of matrix "types" are specified.  For each size ("n")
*>    and each type of matrix, one matrix will be generated and used
*>    to test the nonsymmetric eigenroutines.  For each matrix, 13
*>    tests will be performed:
*>
*>    (1)     0 if T is in Schur form, 1/ulp otherwise
*>           (no sorting of eigenvalues)
*>
*>    (2)     | A - VS T VS' | / ( n |A| ulp )
*>
*>      Here VS is the matrix of Schur eigenvectors, and T is in Schur
*>      form  (no sorting of eigenvalues).
*>
*>    (3)     | I - VS VS' | / ( n ulp ) (no sorting of eigenvalues).
*>
*>    (4)     0     if WR+sqrt(-1)*WI are eigenvalues of T
*>            1/ulp otherwise
*>            (no sorting of eigenvalues)
*>
*>    (5)     0     if T(with VS) = T(without VS),
*>            1/ulp otherwise
*>            (no sorting of eigenvalues)
*>
*>    (6)     0     if eigenvalues(with VS) = eigenvalues(without VS),
*>            1/ulp otherwise
*>            (no sorting of eigenvalues)
*>
*>    (7)     0 if T is in Schur form, 1/ulp otherwise
*>            (with sorting of eigenvalues)
*>
*>    (8)     | A - VS T VS' | / ( n |A| ulp )
*>
*>      Here VS is the matrix of Schur eigenvectors, and T is in Schur
*>      form  (with sorting of eigenvalues).
*>
*>    (9)     | I - VS VS' | / ( n ulp ) (with sorting of eigenvalues).
*>
*>    (10)    0     if WR+sqrt(-1)*WI are eigenvalues of T
*>            1/ulp otherwise
*>            (with sorting of eigenvalues)
*>
*>    (11)    0     if T(with VS) = T(without VS),
*>            1/ulp otherwise
*>            (with sorting of eigenvalues)
*>
*>    (12)    0     if eigenvalues(with VS) = eigenvalues(without VS),
*>            1/ulp otherwise
*>            (with sorting of eigenvalues)
*>
*>    (13)    if sorting worked and SDIM is the number of
*>            eigenvalues which were SELECTed
*>
*>    The "sizes" are specified by an array NN(1:NSIZES); the value of
*>    each element NN(j) specifies one size.
*>    The "types" are specified by a logical array DOTYPE( 1:NTYPES );
*>    if DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*>    Currently, the list of possible types is:
*>
*>    (1)  The zero matrix.
*>    (2)  The identity matrix.
*>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
*>
*>    (4)  A diagonal matrix with evenly spaced entries
*>         1, ..., ULP  and random signs.
*>         (ULP = (first number larger than 1) - 1 )
*>    (5)  A diagonal matrix with geometrically spaced entries
*>         1, ..., ULP  and random signs.
*>    (6)  A diagonal matrix with "clustered" entries 1, ULP, ..., ULP
*>         and random signs.
*>
*>    (7)  Same as (4), but multiplied by a constant near
*>         the overflow threshold
*>    (8)  Same as (4), but multiplied by a constant near
*>         the underflow threshold
*>
*>    (9)  A matrix of the form  U' T U, where U is orthogonal and
*>         T has evenly spaced entries 1, ..., ULP with random signs
*>         on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (10) A matrix of the form  U' T U, where U is orthogonal and
*>         T has geometrically spaced entries 1, ..., ULP with random
*>         signs on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (11) A matrix of the form  U' T U, where U is orthogonal and
*>         T has "clustered" entries 1, ULP,..., ULP with random
*>         signs on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (12) A matrix of the form  U' T U, where U is orthogonal and
*>         T has real or complex conjugate paired eigenvalues randomly
*>         chosen from ( ULP, 1 ) and random O(1) entries in the upper
*>         triangle.
*>
*>    (13) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
*>         with random signs on the diagonal and random O(1) entries
*>         in the upper triangle.
*>
*>    (14) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has geometrically spaced entries
*>         1, ..., ULP with random signs on the diagonal and random
*>         O(1) entries in the upper triangle.
*>
*>    (15) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has "clustered" entries 1, ULP,..., ULP
*>         with random signs on the diagonal and random O(1) entries
*>         in the upper triangle.
*>
*>    (16) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has real or complex conjugate paired
*>         eigenvalues randomly chosen from ( ULP, 1 ) and random
*>         O(1) entries in the upper triangle.
*>
*>    (17) Same as (16), but multiplied by a constant
*>         near the overflow threshold
*>    (18) Same as (16), but multiplied by a constant
*>         near the underflow threshold
*>
*>    (19) Nonsymmetric matrix with random entries chosen from (-1,1).
*>         If N is at least 4, all entries in first two rows and last
*>         row, and first column and last two columns are zero.
*>    (20) Same as (19), but multiplied by a constant
*>         near the overflow threshold
*>    (21) Same as (19), but multiplied by a constant
*>         near the underflow threshold
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of sizes of matrices to use.  If it is zero,
*>          SDRVES does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER array, dimension (NSIZES)
*>          An array containing the sizes to be used for the matrices.
*>          Zero values will be skipped.  The values must be at least
*>          zero.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, SDRVES
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated.  If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096.  Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to SDRVES to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error
*>          is scaled to be O(1), so THRESH should be a reasonably
*>          small multiple of 1, e.g., 10 or 100.  In particular,
*>          it should not depend on the precision (single vs. double)
*>          or the size of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns INFO not equal to 0.)
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (LDA, max(NN))
*>          Used to hold the matrix whose eigenvalues are to be
*>          computed.  On exit, A contains the last matrix actually used.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, and H. LDA must be at
*>          least 1 and at least max(NN).
*> \endverbatim
*>
*> \param[out] H
*> \verbatim
*>          H is REAL array, dimension (LDA, max(NN))
*>          Another copy of the test matrix A, modified by SGEES.
*> \endverbatim
*>
*> \param[out] HT
*> \verbatim
*>          HT is REAL array, dimension (LDA, max(NN))
*>          Yet another copy of the test matrix A, modified by SGEES.
*> \endverbatim
*>
*> \param[out] WR
*> \verbatim
*>          WR is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] WI
*> \verbatim
*>          WI is REAL array, dimension (max(NN))
*>
*>          The real and imaginary parts of the eigenvalues of A.
*>          On exit, WR + WI*i are the eigenvalues of the matrix in A.
*> \endverbatim
*>
*> \param[out] WRT
*> \verbatim
*>          WRT is REAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] WIT
*> \verbatim
*>          WIT is REAL array, dimension (max(NN))
*>
*>          Like WR, WI, these arrays contain the eigenvalues of A,
*>          but those computed when SGEES only computes a partial
*>          eigendecomposition, i.e. not Schur vectors
*> \endverbatim
*>
*> \param[out] VS
*> \verbatim
*>          VS is REAL array, dimension (LDVS, max(NN))
*>          VS holds the computed Schur vectors.
*> \endverbatim
*>
*> \param[in] LDVS
*> \verbatim
*>          LDVS is INTEGER
*>          Leading dimension of VS. Must be at least max(1,max(NN)).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (13)
*>          The values computed by the 13 tests described above.
*>          The values are currently limited to 1/ulp, to avoid overflow.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (NWORK)
*> \endverbatim
*>
*> \param[in] NWORK
*> \verbatim
*>          NWORK is INTEGER
*>          The number of entries in WORK.  This must be at least
*>          5*NN(j)+2*NN(j)**2 for all j.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BWORK
*> \verbatim
*>          BWORK is LOGICAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          If 0, then everything ran OK.
*>           -1: NSIZES < 0
*>           -2: Some NN(j) < 0
*>           -3: NTYPES < 0
*>           -6: THRESH < 0
*>           -9: LDA < 1 or LDA < NMAX, where NMAX is max( NN(j) ).
*>          -17: LDVS < 1 or LDVS < NMAX, where NMAX is max( NN(j) ).
*>          -20: NWORK too small.
*>          If  SLATMR, SLATMS, SLATME or SGEES returns an error code,
*>              the absolute value of it is returned.
*>
*>-----------------------------------------------------------------------
*>
*>     Some Local Variables and Parameters:
*>     ---- ----- --------- --- ----------
*>
*>     ZERO, ONE       Real 0 and 1.
*>     MAXTYP          The number of types defined.
*>     NMAX            Largest value in NN.
*>     NERRS           The number of tests which have exceeded THRESH
*>     COND, CONDS,
*>     IMODE           Values to be passed to the matrix generators.
*>     ANORM           Norm of A; passed to matrix generators.
*>
*>     OVFL, UNFL      Overflow and underflow thresholds.
*>     ULP, ULPINV     Finest relative precision and its inverse.
*>     RTULP, RTULPI   Square roots of the previous 4 values.
*>
*>             The following four arrays decode JTYPE:
*>     KTYPE(j)        The general type (1-10) for type "j".
*>     KMODE(j)        The MODE value to be passed to the matrix
*>                     generator for type "j".
*>     KMAGN(j)        The order of magnitude ( O(1),
*>                     O(overflow^(1/2) ), O(underflow^(1/2) )
*>     KCONDS(j)       Selectw whether CONDS is to be 1 or
*>                     1/sqrt(ulp).  (0 means irrelevant.)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE sdrves( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   nounit, a, lda, h, ht, wr, wi, wrt, wit, vs,
     $                   ldvs, result, work, nwork, iwork, bwork, info )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, ldvs, nounit, nsizes, ntypes, nwork
      REAL               thresh
*     ..
*     .. Array Arguments ..
      LOGICAL            bwork( * ), dotype( * )
      INTEGER            iseed( 4 ), iwork( * ), nn( * )
      REAL               a( lda, * ), h( lda, * ), ht( lda, * ),
     $                   result( 13 ), vs( ldvs, * ), wi( * ), wit( * ),
     $                   work( * ), wr( * ), wrt( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e0, one = 1.0e0 )
      INTEGER            maxtyp
      parameter( maxtyp = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            badnn
      CHARACTER          sort
      CHARACTER*3        path
      INTEGER            i, iinfo, imode, isort, itype, iwk, j, jcol,
     $                   jsize, jtype, knteig, lwork, mtypes, n,
     $                   nerrs, nfail, nmax, nnwork, ntest, ntestf,
     $                   ntestt, rsub, sdim
      REAL               anorm, cond, conds, ovfl, rtulp, rtulpi, tmp,
     $                   ulp, ulpinv, unfl
*     ..
*     .. Local Arrays ..
      CHARACTER          adumma( 1 )
      INTEGER            idumma( 1 ), ioldsd( 4 ), kconds( maxtyp ),
     $                   kmagn( maxtyp ), kmode( maxtyp ),
     $                   ktype( maxtyp )
      REAL               res( 2 )
*     ..
*     .. Arrays in Common ..
      LOGICAL            selval( 20 )
      REAL               selwi( 20 ), selwr( 20 )
*     ..
*     .. Scalars in Common ..
      INTEGER            seldim, selopt
*     ..
*     .. Common blocks ..
      COMMON             / sslct / selopt, seldim, selval, selwr, selwi
*     ..
*     .. External Functions ..
      LOGICAL            sslect
      REAL               slamch
      EXTERNAL           sslect, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgees, shst01, slabad, slacpy, slasum, slatme,
     $                   slatmr, slatms, slaset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sign, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'ES'
*
*     Check for errors
*
      ntestt = 0
      ntestf = 0
      info = 0
      selopt = 0
*
*     Important constants
*
      badnn = .false.
      nmax = 0
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( nounit.LE.0 ) THEN
         info = -7
      ELSE IF( lda.LT.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldvs.LT.1 .OR. ldvs.LT.nmax ) THEN
         info = -17
      ELSE IF( 5*nmax+2*nmax**2.GT.nwork ) THEN
         info = -20
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SDRVES', -info )
         RETURN
      END IF
*
*     Quick return if nothing to do
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
*     More Important constants
*
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      CALL slabad( unfl, ovfl )
      ulp = slamch( 'Precision' )
      ulpinv = one / ulp
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
*
      DO 270 jsize = 1, nsizes
         n = nn( jsize )
         mtypes = maxtyp
         IF( nsizes.EQ.1 .AND. ntypes.EQ.maxtyp+1 )
     $      mtypes = mtypes + 1
*
         DO 260 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         go to 260
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   symmetric, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random symmetric
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         go to 90
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            go to( 30, 40, 50 )kmagn( jtype )
*
   30       CONTINUE
            anorm = one
            go to 60
*
   40       CONTINUE
            anorm = ovfl*ulp
            go to 60
*
   50       CONTINUE
            anorm = unfl*ulpinv
            go to 60
*
   60       CONTINUE
*
            CALL slaset( 'Full', lda, n, zero, zero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices -- Identity & Jordan block
*
*              Zero
*
            IF( itype.EQ.1 ) THEN
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 70 jcol = 1, n
                  a( jcol, jcol ) = anorm
   70          CONTINUE
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = anorm
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = one
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL slatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, 0, 0, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL slatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               adumma( 1 ) = ' '
               CALL slatme( n, 'S', iseed, work, imode, cond, one,
     $                      adumma, 'T', 'T', 'T', work( n+1 ), 4,
     $                      conds, n, n, anorm, a, lda, work( 2*n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
               IF( n.GE.4 ) THEN
                  CALL slaset( 'Full', 2, n, zero, zero, a, lda )
                  CALL slaset( 'Full', n-3, 1, zero, zero, a( 3, 1 ),
     $                         lda )
                  CALL slaset( 'Full', n-3, 2, zero, zero, a( 3, n-1 ),
     $                         lda )
                  CALL slaset( 'Full', 1, n, zero, zero, a( n, 1 ),
     $                         lda )
               END IF
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL slatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9992 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
   90       CONTINUE
*
*           Test for minimal and generous workspace
*
            DO 250 iwk = 1, 2
               IF( iwk.EQ.1 ) THEN
                  nnwork = 3*n
               ELSE
                  nnwork = 5*n + 2*n**2
               END IF
               nnwork = max( nnwork, 1 )
*
*              Initialize RESULT
*
               DO 100 j = 1, 13
                  result( j ) = -one
  100          CONTINUE
*
*              Test with and without sorting of eigenvalues
*
               DO 210 isort = 0, 1
                  IF( isort.EQ.0 ) THEN
                     sort = 'N'
                     rsub = 0
                  ELSE
                     sort = 'S'
                     rsub = 6
                  END IF
*
*                 Compute Schur form and Schur vectors, and test them
*
                  CALL slacpy( 'F', n, n, a, lda, h, lda )
                  CALL sgees( 'V', sort, sslect, n, h, lda, sdim, wr,
     $                        wi, vs, ldvs, work, nnwork, bwork, iinfo )
                  IF( iinfo.NE.0 .AND. iinfo.NE.n+2 ) THEN
                     result( 1+rsub ) = ulpinv
                     WRITE( nounit, fmt = 9992 )'SGEES1', iinfo, n,
     $                  jtype, ioldsd
                     info = abs( iinfo )
                     go to 220
                  END IF
*
*                 Do Test (1) or Test (7)
*
                  result( 1+rsub ) = zero
                  DO 120 j = 1, n - 2
                     DO 110 i = j + 2, n
                        IF( h( i, j ).NE.zero )
     $                     result( 1+rsub ) = ulpinv
  110                CONTINUE
  120             CONTINUE
                  DO 130 i = 1, n - 2
                     IF( h( i+1, i ).NE.zero .AND. h( i+2, i+1 ).NE.
     $                   zero )result( 1+rsub ) = ulpinv
  130             CONTINUE
                  DO 140 i = 1, n - 1
                     IF( h( i+1, i ).NE.zero ) THEN
                        IF( h( i, i ).NE.h( i+1, i+1 ) .OR.
     $                      h( i, i+1 ).EQ.zero .OR.
     $                      sign( one, h( i+1, i ) ).EQ.
     $                      sign( one, h( i, i+1 ) ) )result( 1+rsub )
     $                      = ulpinv
                     END IF
  140             CONTINUE
*
*                 Do Tests (2) and (3) or Tests (8) and (9)
*
                  lwork = max( 1, 2*n*n )
                  CALL shst01( n, 1, n, a, lda, h, lda, vs, ldvs, work,
     $                         lwork, res )
                  result( 2+rsub ) = res( 1 )
                  result( 3+rsub ) = res( 2 )
*
*                 Do Test (4) or Test (10)
*
                  result( 4+rsub ) = zero
                  DO 150 i = 1, n
                     IF( h( i, i ).NE.wr( i ) )
     $                  result( 4+rsub ) = ulpinv
  150             CONTINUE
                  IF( n.GT.1 ) THEN
                     IF( h( 2, 1 ).EQ.zero .AND. wi( 1 ).NE.zero )
     $                  result( 4+rsub ) = ulpinv
                     IF( h( n, n-1 ).EQ.zero .AND. wi( n ).NE.zero )
     $                  result( 4+rsub ) = ulpinv
                  END IF
                  DO 160 i = 1, n - 1
                     IF( h( i+1, i ).NE.zero ) THEN
                        tmp = sqrt( abs( h( i+1, i ) ) )*
     $                        sqrt( abs( h( i, i+1 ) ) )
                        result( 4+rsub ) = max( result( 4+rsub ),
     $                                     abs( wi( i )-tmp ) /
     $                                     max( ulp*tmp, unfl ) )
                        result( 4+rsub ) = max( result( 4+rsub ),
     $                                     abs( wi( i+1 )+tmp ) /
     $                                     max( ulp*tmp, unfl ) )
                     ELSE IF( i.GT.1 ) THEN
                        IF( h( i+1, i ).EQ.zero .AND. h( i, i-1 ).EQ.
     $                      zero .AND. wi( i ).NE.zero )result( 4+rsub )
     $                       = ulpinv
                     END IF
  160             CONTINUE
*
*                 Do Test (5) or Test (11)
*
                  CALL slacpy( 'F', n, n, a, lda, ht, lda )
                  CALL sgees( 'N', sort, sslect, n, ht, lda, sdim, wrt,
     $                        wit, vs, ldvs, work, nnwork, bwork,
     $                        iinfo )
                  IF( iinfo.NE.0 .AND. iinfo.NE.n+2 ) THEN
                     result( 5+rsub ) = ulpinv
                     WRITE( nounit, fmt = 9992 )'SGEES2', iinfo, n,
     $                  jtype, ioldsd
                     info = abs( iinfo )
                     go to 220
                  END IF
*
                  result( 5+rsub ) = zero
                  DO 180 j = 1, n
                     DO 170 i = 1, n
                        IF( h( i, j ).NE.ht( i, j ) )
     $                     result( 5+rsub ) = ulpinv
  170                CONTINUE
  180             CONTINUE
*
*                 Do Test (6) or Test (12)
*
                  result( 6+rsub ) = zero
                  DO 190 i = 1, n
                     IF( wr( i ).NE.wrt( i ) .OR. wi( i ).NE.wit( i ) )
     $                  result( 6+rsub ) = ulpinv
  190             CONTINUE
*
*                 Do Test (13)
*
                  IF( isort.EQ.1 ) THEN
                     result( 13 ) = zero
                     knteig = 0
                     DO 200 i = 1, n
                        IF( sslect( wr( i ), wi( i ) ) .OR.
     $                      sslect( wr( i ), -wi( i ) ) )
     $                      knteig = knteig + 1
                        IF( i.LT.n ) THEN
                           IF( ( sslect( wr( i+1 ),
     $                         wi( i+1 ) ) .OR. sslect( wr( i+1 ),
     $                         -wi( i+1 ) ) ) .AND.
     $                         ( .NOT.( sslect( wr( i ),
     $                         wi( i ) ) .OR. sslect( wr( i ),
     $                         -wi( i ) ) ) ) .AND. iinfo.NE.n+2 )
     $                         result( 13 ) = ulpinv
                        END IF
  200                CONTINUE
                     IF( sdim.NE.knteig ) THEN
                        result( 13 ) = ulpinv
                     END IF
                  END IF
*
  210          CONTINUE
*
*              End of Loop -- Check for RESULT(j) > THRESH
*
  220          CONTINUE
*
               ntest = 0
               nfail = 0
               DO 230 j = 1, 13
                  IF( result( j ).GE.zero )
     $               ntest = ntest + 1
                  IF( result( j ).GE.thresh )
     $               nfail = nfail + 1
  230          CONTINUE
*
               IF( nfail.GT.0 )
     $            ntestf = ntestf + 1
               IF( ntestf.EQ.1 ) THEN
                  WRITE( nounit, fmt = 9999 )path
                  WRITE( nounit, fmt = 9998 )
                  WRITE( nounit, fmt = 9997 )
                  WRITE( nounit, fmt = 9996 )
                  WRITE( nounit, fmt = 9995 )thresh
                  WRITE( nounit, fmt = 9994 )
                  ntestf = 2
               END IF
*
               DO 240 j = 1, 13
                  IF( result( j ).GE.thresh ) THEN
                     WRITE( nounit, fmt = 9993 )n, iwk, ioldsd, jtype,
     $                  j, result( j )
                  END IF
  240          CONTINUE
*
               nerrs = nerrs + nfail
               ntestt = ntestt + ntest
*
  250       CONTINUE
  260    CONTINUE
  270 CONTINUE
*
*     Summary
*
      CALL slasum( path, nounit, nerrs, ntestt )
*
 9999 FORMAT( / 1x, a3, ' -- Real Schur Form Decomposition Driver',
     $      / ' Matrix types (see SDRVES for details): ' )
*
 9998 FORMAT( / ' Special Matrices:', / '  1=Zero matrix.             ',
     $      '           ', '  5=Diagonal: geometr. spaced entries.',
     $      / '  2=Identity matrix.                    ', '  6=Diagona',
     $      'l: clustered entries.', / '  3=Transposed Jordan block.  ',
     $      '          ', '  7=Diagonal: large, evenly spaced.', / '  ',
     $      '4=Diagonal: evenly spaced entries.    ', '  8=Diagonal: s',
     $      'mall, evenly spaced.' )
 9997 FORMAT( ' Dense, Non-Symmetric Matrices:', / '  9=Well-cond., ev',
     $      'enly spaced eigenvals.', ' 14=Ill-cond., geomet. spaced e',
     $      'igenals.', / ' 10=Well-cond., geom. spaced eigenvals. ',
     $      ' 15=Ill-conditioned, clustered e.vals.', / ' 11=Well-cond',
     $      'itioned, clustered e.vals. ', ' 16=Ill-cond., random comp',
     $      'lex ', / ' 12=Well-cond., random complex ', 6x, '   ',
     $      ' 17=Ill-cond., large rand. complx ', / ' 13=Ill-condi',
     $      'tioned, evenly spaced.     ', ' 18=Ill-cond., small rand.',
     $      ' complx ' )
 9996 FORMAT( ' 19=Matrix with random O(1) entries.    ', ' 21=Matrix ',
     $      'with small random entries.', / ' 20=Matrix with large ran',
     $      'dom entries.   ', / )
 9995 FORMAT( ' Tests performed with test threshold =', f8.2,
     $      / ' ( A denotes A on input and T denotes A on output)',
     $      / / ' 1 = 0 if T in Schur form (no sort), ',
     $      '  1/ulp otherwise', /
     $      ' 2 = | A - VS T transpose(VS) | / ( n |A| ulp ) (no sort)',
     $      / ' 3 = | I - VS transpose(VS) | / ( n ulp ) (no sort) ', /
     $      ' 4 = 0 if WR+sqrt(-1)*WI are eigenvalues of T (no sort),',
     $      '  1/ulp otherwise', /
     $      ' 5 = 0 if T same no matter if VS computed (no sort),',
     $      '  1/ulp otherwise', /
     $      ' 6 = 0 if WR, WI same no matter if VS computed (no sort)',
     $      ',  1/ulp otherwise' )
 9994 FORMAT( ' 7 = 0 if T in Schur form (sort), ', '  1/ulp otherwise',
     $      / ' 8 = | A - VS T transpose(VS) | / ( n |A| ulp ) (sort)',
     $      / ' 9 = | I - VS transpose(VS) | / ( n ulp ) (sort) ',
     $      / ' 10 = 0 if WR+sqrt(-1)*WI are eigenvalues of T (sort),',
     $      '  1/ulp otherwise', /
     $      ' 11 = 0 if T same no matter if VS computed (sort),',
     $      '  1/ulp otherwise', /
     $      ' 12 = 0 if WR, WI same no matter if VS computed (sort),',
     $      '  1/ulp otherwise', /
     $      ' 13 = 0 if sorting succesful, 1/ulp otherwise', / )
 9993 FORMAT( ' N=', i5, ', IWK=', i2, ', seed=', 4( i4, ',' ),
     $      ' type ', i2, ', test(', i2, ')=', g10.3 )
 9992 FORMAT( ' SDRVES: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
      RETURN
*
*     End of SDRVES
*
      END